Question

必须有更好的方法来做到这一点！我想将XML文档中找到的所有单位转换为基本单位（例如x值=＆＃39; 1.0＆＃39;单位=＆＃39; Mbps＆＃39; /变成\ x值=＆＃39; 1000000＆＃39;单位=＆＃39; bps＆＃39; /）。我还想保留节点中的其他属性。

我知道我可以使用lxml遍历文档并更改属性，但我认为这是XSLT的完美任务。

此XML：

<generator>
    <enable value="0"/>
    <errorPattern value="Off" units=""/>
    <errorMode value="Off" units=""/>
    <errorRate value="1000000"/>
    <bitRate value="1.638" units="Mbps" blah="foo">
        <subelement value="2" units="Kbps"/>
    </bitRate>
</generator>

变为：

<generator>
    <enable value="0"/>
    <errorPattern value="Off" units=""/>
    <errorMode value="Off" units=""/>
    <errorRate value="1000000"/>
    <bitRate value="1638000" units="bps" blah="foo">
        <subelement value="2000" units="bps"/>
    </bitRate>
</generator>

下面的单元测试会执行此操作，但xsl：stylesheet非常糟糕。我认为我将能够根据单位设置乘数，然后在一些常用代码中使用该乘数。但是，我不得不复制“Mbps”的模板。和＆＃39; Kbps＆＃39;。

必须有更好的方法吗？虽然仍在使用lxml。

import unittest
from lxml import isoschematron
from lxml import etree
from StringIO import StringIO


xml = '''\
<generator>
    <enable value="0"/>
    <errorPattern value="Off" units=""/>
    <errorMode value="Off" units=""/>
    <errorRate value="1000000"/>
    <bitRate value="1.638" units="Mbps" blah='foo'>
        <subelement value='2' units='Kbps'/>
    </bitRate>
</generator>'''

transform_units=etree.XML('''\
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:apply-templates select="node()"/>
        </xsl:copy>
    </xsl:template>

    <!-- Convert Mbps to base units --> 
    <xsl:template match="*[@units='Mbps']">
        <xsl:param name='multiplier'>1000000</xsl:param>
        <xsl:copy>
            <xsl:apply-templates select='@*'/>
            <xsl:attribute name='value'><xsl:value-of select='@value * $multiplier'/></xsl:attribute>
            <xsl:attribute name='units'>bps</xsl:attribute>
            <xsl:apply-templates select='node()'/>
        </xsl:copy>
    </xsl:template>

    <!-- Convert Kbps to base units --> 
    <xsl:template match="*[@units='Kbps']">
        <xsl:param name='multiplier'>1000</xsl:param>
        <xsl:copy>
            <xsl:apply-templates select='@*'/> <!-- copy all attributes -->
            <xsl:attribute name='value'><xsl:value-of select='@value * $multiplier'/></xsl:attribute>
            <xsl:attribute name='units'>bps</xsl:attribute>
            <xsl:apply-templates select='node()'/> <!-- process child nodes -->
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>''')

class Test(unittest.TestCase):


    def setUp(self):
        self.ns = namespaces={'svrl':'http://purl.oclc.org/dsdl/svrl'}
        self.transformUnits = etree.XSLT(transform_units)

    def tearDown(self):
        pass

    def test_transformUnits(self):
        doc = etree.fromstring(xml)
        print etree.tostring(doc)
        res = self.transformUnits(doc)
        print etree.tostring(res)



if __name__ == "__main__":
    #import sys;sys.argv = ['', 'Test.testName']
    unittest.main()

输出：

pydev debugger: starting (pid: 10828)
Finding files... done.
Importing test modules ... done.

<generator>
    <enable value="0"/>
    <errorPattern value="Off" units=""/>
    <errorMode value="Off" units=""/>
    <errorRate value="1000000"/>
    <bitRate value="1.638" units="Mbps" blah="foo">
        <subelement value="2" units="Kbps"/>
    </bitRate>
</generator>
<generator>
    <enable value="0"/>
    <errorPattern value="Off" units=""/>
    <errorMode value="Off" units=""/>
    <errorRate value="1000000"/>
    <bitRate value="1638000" units="bps" blah="foo">
        <subelement value="2000" units="bps"/>
    </bitRate>
</generator>
----------------------------------------------------------------------
Ran 1 test in 0.010s

OK

更新

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"></xsl:apply-templates>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[@units='Kbps'] | *[@units='Mbps']">
    <xsl:variable name="multi">
        <xsl:choose>
            <xsl:when test="@units = 'Mbps'">1000000</xsl:when>
            <xsl:when test="@units = 'Kbps'">1000</xsl:when>
        </xsl:choose>
    </xsl:variable>
    <xsl:copy>
        <xsl:apply-templates select='@*'/> <!-- copy all attributes -->
        <xsl:attribute name="units">bps</xsl:attribute>
        <xsl:attribute name="value"><xsl:value-of select="@value * number($multi)"/></xsl:attribute>
        <xsl:apply-templates select='node()'/> <!-- process child nodes -->
    </xsl:copy>
    <units><xsl:value-of select='$multi'/></units>
</xsl:template>
</xsl:stylesheet>

Answer 1

你可以用这个

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"></xsl:apply-templates>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[matches(@units, '[MK]bps')]">
    <xsl:variable name="multi">
        <xsl:choose>
            <xsl:when test="@units eq 'Mbps'">1000000</xsl:when>
            <xsl:when test="@units eq 'Kbps'">1000</xsl:when>
        </xsl:choose>
    </xsl:variable>
    <xsl:copy>
        <xsl:attribute name="value" select="@value * number($multi)"/>
        <xsl:attribute name="units" select="'bps'"/>
        <xsl:copy-of select="@* except (@value, @units)"></xsl:copy-of>
        <xsl:apply-templates select="node()"></xsl:apply-templates>
    </xsl:copy>
</xsl:template>

Answer 2

我不得不复制模板“Mbps”和“Kbps”。

XSLT（尤其是XSLT 1.0）自然是冗长的，为每个案例都有一个模板没有错。如果您想消除重复的代码，可以使用以下内容：

<xsl:template match="*[contains(@units, 'bps')]">
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:variable name="prefix" select="substring-before(@units, 'bps')" />
        <xsl:attribute name="value">
            <xsl:choose>
                <xsl:when test="$prefix='M'">
                    <xsl:value-of select="@value * 1000000"/>
                </xsl:when>
                <xsl:when test="$prefix='K'">
                    <xsl:value-of select="@value * 1000"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="@value"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
        <xsl:attribute name="units">bps</xsl:attribute>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>

使用XSLT转换属性的更好方法是什么？

2 个答案: