Question

我有一个项目列表，我想“un-zip-flatten”。基本上这意味着如果我有一个项目列表：

[a, b, c, d, e, f, g]

我想把它变成一个列表，如下所示：

[[a, d, g], [b, e], [c, f]]

到目前为止，我的解决方案看起来像这样：

unzipflatten(NumberOfLists, List) ->
    lists:map(fun(Start) ->
                      lists:map(fun(N) ->
                                        lists:nth(N, List)
                                end,
                                lists:seq(Start, length(List), NumberOfLists))
              end,
              lists:seq(1, NumberOfLists)).

我对Erlang很陌生，所以我想知道我是否错过了一些可以做我想做的标准库函数，或者是否有更多“Erlangish”方法来做到这一点，或者我的表现如何以上解决方案会发臭。

Answer 1

我认为这将是一种更“执行”的“Erlangish”方法。基本上，您将创建将成为结果的列表列表，并使用两个列表来管理这些列表（如队列）。 “Heads”列表包含您将在下一个前面添加的列表，“Tails”列表是最近添加的列表。当Heads为空时，你只需反转Tails并将其用作新的Heads。在返回结果之前，您需要反转Tails和Heads中的所有列表，然后将Heads原样附加到反向Tails。请原谅令人困惑的变量名称，我认为在Erlang程序中分解列表的几个好名字是最难的部分;）

unzipflatten(NumberOfLists, List) when NumberOfLists > 0 ->
    unzipflatten(List, lists:duplicate(NumberOfLists, []), []).

unzipflatten([], Heads, Tails) ->
    [lists:reverse(L) || L <- lists:reverse(Tails, Heads)];
unzipflatten(L, [], Tails) ->
    unzipflatten(L, lists:reverse(Tails), []);
unzipflatten([Elem | Rest], [Head | Tail], Tails) ->
    unzipflatten(Rest, Tail, [[Elem | Head] | Tails]).

也可以以非尾递归方式执行“解压缩”阶段以避免列表：反向步骤，但这是一个更复杂的解决方案。像这样：

unzipflatten(NumberOfLists, List) when NumberOfLists > 0 ->
    unzipflatten({List, lists:duplicate(NumberOfLists, [])}).

unzipflatten({[], Heads}) ->
    [lists:reverse(L) || L <- Heads];
unzipflatten({L, Heads}) ->
    unzipflatten(unzipper({L, Heads})).

unzipper({[], Heads}) ->
    {[], Heads};
unzipper({L, []}) ->
    {L, []};
unzipper({[H | T], [Head | Tail]}) ->
    {T1, Tail1} = unzipper({T, Tail}),
    {T1, [[H | Head] | Tail1]}.

Answer 2

是的，性能会很糟糕（使用lists:nth的基本建议：永远不要在增长N时多次调用它！）。这样的事情应该更好（未经测试）：

unzipflatten(NumberOfLists, List) -> 
  unzipflatten(NumberOfLists, List, array:new(NumberOfLists, {default, []}), 0).

unzipflatten(_, [], Lists, _) -> 
  lists:map(fun lists:reverse/1, array:to_list(Lists));
unzipflatten(NumberOfLists, [H | T], Lists, CurrentIndex) ->
  NewLists = array:set(CurrentIndex, [H | array:get(CurrentIndex, Lists)], Lists),
  unzipflatten(NumberOfLists, T, NewLists, (CurrentIndex + 1) rem NumberOfLists).

Erlang un-zip-flatten

2 个答案: