Question

我正在尝试根据几个标准将行复制到新工作表中。

我设法编写了一个可以找到一行并将其复制到新工作表的宏，但遗憾的是我正在覆盖之前的条目。

在stackoverflow上有一些解决方案 - 我搜索了诸如“将行复制到空行的新工作表中”之类的东西等等 - 但我只是复制这些答案中的一些代码而无法使它们工作（没有正确理解代码）。

如何将结果复制到新工作表中的下一个空行？

Sub FilterAndCopy()

Dim lastRow As Long
Dim criterion As String
Dim team1 As String
Dim team2 As String
Dim team3 As String

criterion = "done"
team1 = "source"
team2 = "refine"
team3 = "supply"


Sheets("Sheet3").UsedRange.Offset(0).ClearContents

With Worksheets("Actions")
    .range("$A:$F").AutoFilter
    'filter for actions that are not "done"
    .range("$A:$F").AutoFilter field:=3, Criteria1:="<>" & criterion
    'filter for actions where "due date" is in the past
    .range("$A:$F").AutoFilter field:=6, Criteria1:="<" & CLng(Date)

    'FIRST TEAM
    .range("$A:$F").AutoFilter field:=4, Criteria1:="=" & team1
    'iff overdue actions exist, copy them into "Sheet3"
    lastRow = .range("A" & .rows.Count).End(xlUp).row
    If (lastRow > 1) Then
        .range("A1:A" & lastRow).SpecialCells(xlCellTypeVisible).EntireRow.Copy _
            Destination:=Sheets("Sheet3").range("A1")
    End If

    'SECOND TEAM
    .range("$A:$F").AutoFilter field:=4, Criteria1:="=" & team2
    'iff overdue items exist, copy them into "Sheet3"
    lastRow = .range("A" & .rows.Count).End(xlUp).row
    If (lastRow > 1) Then
        'find last row with content and copy relevant rows
        .range("A1:A" & lastRow).SpecialCells(xlCellTypeVisible).EntireRow.Copy _
            Destination:=Sheets("Sheet3").range("A1")
    End If

    'THIRD STREAM
    .range("$A:$F").AutoFilter field:=4, Criteria1:="=" & team3
    'iff overdue items exist, copy them into "Sheet3"
    lastRow = .range("A" & .rows.Count).End(xlUp).row
    If (lastRow > 1) Then
        'find last row with content and copy relevant rows
        .range("A1:A" & lastRow).SpecialCells(xlCellTypeVisible).EntireRow.Copy _
            Destination:=Sheets("Sheet3").range("A1")
    End If

End With
End Sub

Answer 1

您只需在新工作表中再次使用LastRow代码。

所以试试

If (lastRow > 1) Then
    LastRow2 = worksheets("Sheet3").range("A" & rows.count).end(xlup).row + 1
    'find last row with content and copy relevant rows
    .range("A1:A" & lastRow).SpecialCells(xlCellTypeVisible).EntireRow.Copy _
        Destination:=Sheets("Sheet3").range("A" & LastRow2)
End If

这会找到工作表3的最后一行，并将其粘贴到其下方。

希望这有帮助。

将行复制到另一个工作表

1 个答案: