Question

我在PL / SQL过程中将逗号分隔的列表作为字符串。我需要

删除重复项
将列表放入数组中。

我找到了多种方法，而不是两种方法。有什么帮助吗？

Answer 1

将逗号分隔列表转换为行有一个众所周知的SQL技巧。只需使用该技巧，将cmd关键字和DISTINCT结果添加到数组中（我假设您的意思是集合）。

BULK COLLECT

输出：

DECLARE
  p_test_string   VARCHAR2 (4000) := 'A,B,C,B,B,D';

  TYPE string_array_type IS TABLE OF VARCHAR2 (4000);

  l_array         string_array_type;
BEGIN
  SELECT DISTINCT REGEXP_SUBSTR (p_test_string,
                        '[^,]+',
                        1,
                        LEVEL)
  BULK   COLLECT INTO l_array
  FROM   DUAL
  CONNECT BY REGEXP_SUBSTR (p_test_string,
                            '[^,]+',
                            1,
                            LEVEL)
               IS NOT NULL
  ORDER BY 1;

  DBMS_OUTPUT.put_line ('l_array.count = ' || l_array.COUNT);
  DBMS_OUTPUT.put_line ('l_array(2) = ' || l_array (2));
END;

Answer 2

split a delimited string有多种方法。其中一个是使用简单的PL / SQL函数：

CREATE TYPE string_list IS TABLE OF VARCHAR2(4000);
/

CREATE OR REPLACE FUNCTION split_String(
  i_str    IN  VARCHAR2,
  i_delim  IN  VARCHAR2 DEFAULT ','
) RETURN STRING_LIST DETERMINISTIC
AS
  p_result       STRING_LIST := STRING_LIST();
  p_start        NUMBER(5) := 1;
  p_end          NUMBER(5);
  c_len CONSTANT NUMBER(5) := LENGTH( i_str );
  c_ld  CONSTANT NUMBER(5) := LENGTH( i_delim );
BEGIN
  IF c_len > 0 THEN
    p_end := INSTR( i_str, i_delim, p_start );
    WHILE p_end > 0 LOOP
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, p_end - p_start );
      p_start := p_end + c_ld;
      p_end := INSTR( i_str, i_delim, p_start );
    END LOOP;
    IF p_start <= c_len + 1 THEN
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, c_len - p_start + 1 );
    END IF;
  END IF;
  RETURN p_result;
END;
/

这是一个使用简单字符串函数的纯PL / SQL函数（而不是使用更昂贵的正则表达式和上下文切换到SQL作用域）。

还有一个非常简单的内置函数SET( collection_value )，用于从集合中删除重复项：

SET( STRING_LIST( 'A', 'B', 'A', 'C', 'B' ) )

将提供收藏：

STRING_LIST( 'A', 'B', 'C' )

所以，如果你想拆分一个分隔的字符串并重复删除它，你可以这样做：

SET( split_String( 'A,B,C,A,B,D,C,E' ) )

哪个会给你：

STRING_LIST( 'A', 'B', 'C', 'D', 'E' )

PL / SQL逗号分隔列表;删除重复并放入数组

2 个答案: