Question

我有代码可以做两件事：首先，它从数据验证下拉列表中对项目进行排序，这些列表位于工作表2中，带有＆＃34;，＆＃34;位于工作表1中的所需单元格范围。此外，如果用户选择相同的项目，它将从选定的单元格中删除它。

代码的另一个选项是当用户选择下拉列表的单元格时（位于D2:F325，放大100％以查看列表中的项目（因为它）字体太小，无法看到）

在下面的代码中几乎完美无缺。因为，它仅在我从所需范围中选择单个单元格时进行缩放：

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Count > 1 Then GoTo exitHandler

    If Target.Address = Range("XYZ").Address Then
        ActiveWindow.Zoom = 100
        [A5000] = "zoomed"
        ElseIf [A5000] = "zoomed" Then
        'Otherwise set the zoom to original
        ActiveWindow.Zoom = 70
        [A5000].ClearContents
    End If

exitHandler:
    Application.EnableEvents = True
End Sub


Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngDV As Range
    Dim oldVal As String
    Dim newVal As String
    Dim strVal As String
    Dim i As Long
    Dim lCount As Long
    Dim Ar As Variant
    On Error Resume Next
    Dim lType As Long
    If Target.Count > 1 Then GoTo exitHandler

    lType = Target.Validation.Type
    If lType = 3 Then
        Application.EnableEvents = False
        newVal = Target.Value
        Application.Undo
        oldVal = Target.Value
        Target.Value = newVal

        If oldVal = "" Then
            'do nothing
        Else
            If newVal = "" Then
                'do nothing
            Else
                On Error Resume Next
                Ar = Split(oldVal, ", ")
                strVal = ""
                For i = LBound(Ar) To UBound(Ar)
                    Debug.Print strVal
                    Debug.Print CStr(Ar(i))
                    If newVal = CStr(Ar(i)) Then
                        'do not include this item
                        strVal = strVal
                        lCount = 1
                    Else
                        strVal = strVal & CStr(Ar(i)) & ", "
                    End If
                Next i
                If lCount > 0 Then
                    Target.Value = Left(strVal, Len(strVal) - 2)
                Else
                    Target.Value = strVal & newVal
                End If
            End If
        End If

    End If

exitHandler:
    Application.EnableEvents = True
End Sub

XYZ是单元格D2的名称，因为我试图将此范围命名为使用此功能进行选择，但它不起作用。

最后，Target.Address如何选择整个范围D2:F325

Answer 1

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Count > 1 Then GoTo exitHandler

 If Not Application.Intersect(Target, Range("D2:F325")) Is Nothing Then
   ActiveWindow.Zoom = 100
   [A5000] = "zoomed"
 ElseIf [A5000] = "zoomed" Then
 'Otherwise set the zoom to original
ActiveWindow.Zoom = 70
[A5000].ClearContents
End If

 exitHandler:
  Application.EnableEvents = True
End Sub

效果很好。

VBA excel Target.Address =单元格范围

1 个答案: