Question

我有这个代码，假设要添加两个数字，一个浮点数（3.25）和一个整数（2）。

编辑：

extern _printf, _scanf
global _main
section .bss
  num1: resb 4
section .data
  format_num: db "%f", 10, 0
section .text
_main:

  mov dword [num1], __float32__(3.25)
  add num1,  2

  sub esp, 8
  fld dword [num1]
  mov dword [num1], eax
  fstp qword [esp]
  push format_num
  call _printf
  add esp, 12

ret

我得到的输出是：

test.asm：11：错误：操作码和操作数的无效组合

我期望的输出是：

5.250000

Answer 1

x87 FPU的一个很好的教程超出了Stackoverflow的范围，但我可以推荐MASM forums上的那个。另一个好的来源是Intel Instruction Set Reference。特别是以F开头的大多数函数都是x87浮点单元（FPU）相关指令。

通常，您只能将浮点值添加到整数。它们是两种不同的表现形式。你可以做的是将整数转换为浮点值，然后用它进行浮点计算。特别是以FI开头的指令是浮点运算，涉及将整数存储器操作数转换为浮点。

有许多方法可以为猫提供皮肤，但如果您查看上面链接的FPU教程，您可能会发现一种简单的方法是：

sub esp, 8           ; Allocate space on stack to store integer
mov dword [esp], 2   ; Move the 32-bit integer value onto stack temporarily
fild dword [esp]     ; Load integer 2 from stack into top of FPU stack at st(0)
                     ;    Converting it to 2.0 in the process
mov dword [esp], __float32__(3.25)
                     ; Move 3.25 onto stack temporarily
fadd dword [esp]     ; Add 3.25 to st(0). Result in st(0). So st(0)=5.25
fstp qword [esp]     ; Store 64-bit double to stack for printf and pop FPU stack.

我没有使用全局变量临时在主内存中存储值，而是使用我们保留的堆栈空间作为临时暂存区来加载/操作x87 FPU。

如果您使用的是支持SSE2指令集的CPU（这包括32位模式下的任何X86-64处理器），那么您还有其他选择。一种是使用SIMD指令和寄存器来执行32位和64位浮点运算。使用指令集参考，您可以找到一些有用的指令，如：

cvtsi2sd：将双字整数转换为标量双精度FP值
cvtss2sd：将标量单精度FP值转换为标量双精度FP值
addsd：添加标量双精度浮点值
movsd：移动标量双精度浮点值

标量单精度FP值是32位浮点数。标量双精度是64位双精度。

sub esp, 8
mov dword [esp], 2      ; Load integer 2 (32-bit signed value) onto stack temporarily
cvtsi2sd xmm0, [esp]    ; Convert 2 on stack to 64-bit float and store in XMM0
mov dword [esp], __float32__(3.25)
                        ; Load 32-bit float value of 3.25 onto stack
cvtss2sd xmm1, [esp]    ; Load 32-bit single and convert it to 64-bit double. Store in XMM1
addsd xmm0, xmm1        ; Add 64-bit float in XMM0 and XMM1 store XMM0
movsd qword [esp], xmm0 ; Move 64-bit float back onto stack to be printed by printf

Answer 2

解决方案是：

extern _printf
global _main
section .bss
  num1: resb 4
  num2: resb 4
section .data
  format_float: db "The result is %f", 10, 0
_main:

  mov dword [num1], 2
  mov dword [num2], __float32__(3.25)

  sub esp, 8
  fild dword [num1]
  fadd dword [num2]
  fstp qword [esp]
  push format_float
  call _printf
  add esp, 12

ret

我得到的输出是：

5.250000

fild将2作为2.0000000推入ST0，然后fadd可以添加两个浮点数。结果是一个浮点数。 int + float = float。

对不起，我的英语很差。

如何在NASM中添加两个数字，整数和浮点数？

2 个答案: