Question

我正在尝试这个网址上的示例。 http://cython.readthedocs.io/en/latest/src/userguide/buffer.html

要测试它，我会执行以下操作。

import pyximport
pyximport.install(build_dir = 'build')
import ctest

m = ctest.Matrix(10)
m.add_row()
print(m)

当我调用m.add_row（）函数时，这给了我一个错误 TypeError: 'int' object is not iterable

在类中，add_row定义为

from cpython cimport Py_buffer
from libcpp.vector cimport vector

cdef class Matrix:
    cdef Py_ssize_t ncols
    cdef Py_ssize_t shape[2]
    cdef Py_ssize_t strides[2]
    cdef vector[float] v

    def __cinit__(self, Py_ssize_t ncols):
        self.ncols = ncols

    def add_row(self):
        """Adds a row, initially zero-filled."""
        self.v.extend(self.ncols)
    ...

这个错误对我来说是完全合理的，假设在cython中对vector进行扩展调用与在python列表上扩展完全相同。你不会传递一个数字，而是一个附加到列表中的可迭代对象。

我可以通过这样做来解决它......

def add_row(self):
    """Adds a row, initially zero-filled."""
    self.v.extend([0] * self.ncols)

我只是想知道示例中是否存在拼写错误，或者我是否遗漏了某些内容。扩展函数在哪里来自向量？在使用cython发布的vector.pxd文件中，它永远不会导入扩展函数，甚至在c ++标准库中也不存在。 cython是否对矢量类型做了一些特别的事情？

https://github.com/cython/cython/blob/master/Cython/Includes/libcpp/vector.pxd

Answer 1

cpp vector可以自动转换为python列表。通过检查行self.v.extend([0] * self.ncols)的c代码，创建了一个新的python列表：__pyx_t_2 = PyList_New(1 * ((__pyx_v_self->ncols<0) ? 0:__pyx_v_self->ncols))。因此extend实际上是python列表的extend方法。

这种自动转换也可以通过以下代码验证（在jupyter笔记本中）：

%%cython -+
from libcpp.vector cimport vector

def test_cpp_vector_to_pylist():
    cdef vector[int] cv
    for i in range(10):
        cv.push_back(i)
    return cv

a = test_cpp_vector_to_pylist()
print a       # [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
print type(a) # <type 'list'>

但是，在这种情况下cv被转换为临时python列表，原始cpp vertor将保持不变，如下面的代码所示：

%%cython -+
from libcpp.vector cimport vector

def test_cpp_vector_to_pylist_1():
    cdef vector[int] cv
    for i in range(10):
        cv.append(i)    # Note: the append method of python list 
    return cv

a = test_cpp_vector_to_pylist_1()
print a       # []
print type(a) # <type 'list'>

此外，c数组也可以自动转换为python列表：

%%cython

def test_c_array_to_pylist():
    cdef int i
    cdef int[10] ca
    for i in range(10):
        ca[i] = i
    return ca

a = test_c_array_to_pylist()
print a       # [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
print type(a) # <type 'list'>

Cython缓冲区协议示例错误

1 个答案: