Question

我一直在编辑和看这个很长时间以来我找不到一个看似简单的解决方案。

元素（及其兄弟）将具有任意数量的不同（动态）结果，我想在HTML表格中显示，每个cd文件对一行。最初认为我可以避免每个循环（无论如何似乎返回相同的结果），我需要[更好]的方式来引用孩子们。下面的来源与我正在使用的结构相似。

例如，某些“cd”和“file”将包含更多元素，例如价格，有些可能没有信息。

XML

    <?xml version="1.0" encoding="UTF-8"?>
    <?xml-stylesheet type="text/xsl" href="cdcatalog.test2.xsl"?>
    <catalog>
      <rock>
        <album>
          <cd>
            <title>Empire Burlesque</title>
            <artist>Bob Dylan</artist>
          </cd>
          <file>
            <store>Apple</store>
            <size>3823</size>
          </file>
        </album>
        <album>
          <cd>
            <title>Hide your heart</title>
            <artist>Bonnie Tyler</artist>
          </cd>
          <file>
            <store>Amazon</store>
            <size>2123</size>
          </file>
        </album>
      </rock>
    </catalog>

XSLT

    <?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/">
    <html> 
    <body>
      <h2>My CD Collection</h2>
      <table border="1">
        <tr bgcolor="#cccccc">
          <th style="text-align:left">Title</th>
          <th style="text-align:left">Artist</th>
          <th style="text-align:left">Store</th>
          <th style="text-align:left">Size</th>
        </tr>
        <xsl:apply-templates/>
      </table>
    </body>
    </html>
    </xsl:template>

    <xsl:template match="album">
      <tr>
        <xsl:apply-templates select="cd"/>  
        <xsl:apply-templates select="file"/>
      </tr>
    </xsl:template>

    <xsl:template match="cd">
      <td>
        <xsl:value-of select="."/>
      </td>
    </xsl:template>

    <xsl:template match="file">
      <td>
        <xsl:value-of select="."/>
      </td>
    </xsl:template>

    </xsl:stylesheet>

结果

    <table border="1">
      <tbody>
        <tr bgcolor="#cccccc">
          <th style="text-align:left">Title</th>
          <th style="text-align:left">Artist</th>
          <th style="text-align:left">Store</th>
          <th style="text-align:left">Size</th>
        </tr>
        <tr>
          <td>
            Empire Burlesque
            Bob Dylan
            </td>
            <td>
              Apple
              3823
            </td>
        </tr>
        <tr>
          <td>
            Hide your heart
            Bonnie Tyler
          </td>
          <td>
            Amazon
            2123
          </td>
        </tr>
      </tbody>
    </table>

Result View

现在，我想我知道发生了什么。根据我的解释，在XSLT文件中，在“cd”和“file”模板下，select="."将返回<td>内的所有子项。我需要一种方法让每个人拥有<td>。我在“cd”和“file”模板中尝试过每个“cd”和“file”以及for-each的调用模板。请注意，我还需要动态构建<th>元素，现在它们是为了测试目的而手动创建的。有什么建议吗？

Answer 1

作为一个有根据的猜测（目前还不清楚你的预期输出是什么样的，输入文件的哪些方面是可变的），我想你想要以下内容。

无需以一般方式将模板明确应用于cd和title元素，只需apply-templates。此外，您的样式表目前缺少store，size等模板。据我所知，这些元素的内容应该放在HTML输出中的td元素内，因此您需要将它们与模板匹配，即使这些模板相当普遍。

如果您事先不知道表格标题th的名称，并且是否有可变数量的叶子元素是album的孙子元素，那么这里有更多＆＃34;动态＆＃ 34;溶液：

XSLT样式表

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="html" doctype-public="XSLT-compat" omit-xml-declaration="yes"
        encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
        <html>
            <body>
                <h2>My CD Collection</h2>
                <table border="1">
                    <tr bgcolor="#cccccc">
                        <xsl:for-each select="distinct-values(catalog/rock/album/*/*/name())">
                            <th style="text-align:left">
                                <xsl:value-of select="."/>
                            </th>
                        </xsl:for-each>
                    </tr>
                    <xsl:apply-templates/>
                </table>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="album">
        <tr>
            <xsl:apply-templates/>
        </tr>
    </xsl:template>

    <xsl:template match="album/*/*">
        <td>
            <xsl:value-of select="."/>
        </td>
    </xsl:template>

</xsl:stylesheet>

HTML输出

<!DOCTYPE html
  PUBLIC "XSLT-compat">
<html>
   <body>
      <h2>My CD Collection</h2>
      <table border="1">
         <tr bgcolor="#cccccc">
            <th style="text-align:left">title</th>
            <th style="text-align:left">artist</th>
            <th style="text-align:left">store</th>
            <th style="text-align:left">size</th>
         </tr>
         <tr>
            <td>Empire Burlesque</td>
            <td>Bob Dylan</td>
            <td>Apple</td>
            <td>3823</td>
         </tr>
         <tr>
            <td>Hide your heart</td>
            <td>Bonnie Tyler</td>
            <td>Amazon</td>
            <td>2123</td>
         </tr>
      </table>
   </body>
</html>

呈现HTML

在线试用此解决方案here。

Answer 2

如果我猜对了，你想做点什么：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:strip-space elements="*"/>

<xsl:template match="/catalog">
    <html> 
        <body>
            <h2>My CD Collection</h2>
            <table border="1">
                <tr>
                    <xsl:apply-templates select="*/album[1]" mode="header"/>
                </tr>
                <xsl:apply-templates/>
            </table>
        </body>
    </html>
</xsl:template>

<xsl:template match="album">
    <tr>
        <xsl:apply-templates/>  
    </tr>
</xsl:template>

<xsl:template match="*[text()]" mode="header">
    <th>
        <xsl:value-of select="name()"/>
    </th>
</xsl:template>

<xsl:template match="*[text()]">
    <td>
        <xsl:value-of select="."/>
    </td>
</xsl:template>

</xsl:stylesheet>

这为每个album创建一行，并为每个具有文本节点的叶节点创建一列。

请注意，这假设您的输入是常规的 - 即每个相册具有相同的属性，顺序相同，并且没有一个是空的。

处理动态创建的儿童和兄弟姐妹的孩子

2 个答案: