Question

状况

我正在研究Nick Hodges撰写的“Delphi中的更多编码”，他正在使用TFraction记录来解释运算符重载。我自己写了这条记录：

type
  TFraction = record
  strict private
    aNumerator: integer;
    aDenominator: integer;
    function GCD(a, b: integer): integer;
  public
    constructor Create(aNumerator: integer; aDenominator: integer);
    procedure Reduce;
    class operator Add(fraction1, fraction2: TFraction): TFraction;
    class operator Subtract(fraction1, fraction2: TFraction): TFraction;
    //... implicit, explicit, multiply...
    property Numerator: integer read aNumerator;
    property Denominator: integer read aDenominator;
  end;

当然，我必须创建一个构造函数，因为在Q（有理数）中我必须有一个不等于零的分母。

constructor TFraction.Create(aNumerator, aDenominator: integer);
begin
  if (aDenominator = 0) then
  begin
    raise Exception.Create('Denominator cannot be zero in rationals!');
  end;

  if ( (aNumerator < 0) or (aDenominator < 0) ) then
  begin
    Self.aNumerator := -aNumerator;
    Self.aDenominator := -aDenominator;
  end
  else
  begin
    Self.aNumerator := aNumerator;
    Self.aDenominator := aDenominator;
  end;
end;

问题

由于运算符重载返回TFraction，我将定义一个这样的操作：

class operator TFraction.Add(fraction1, fraction2: TFraction): TFraction;
var
  tmp: TFraction;
begin
  //simple algorithm of the sum
  tmp := TFraction.Create(fraction1.Numerator*fraction2.Denominator+fraction1.Denominator*fraction2.Numerator, fraction1.Denominator*fraction2.Denominator);
  tmp.Reduce;

  //return the result
  Result := tmp;
end;

正如您在此处所见，我正在创建一个从函数返回的tmp。

当我阅读Marco Cantu的书时，他使用了另一种方法：

class operator TFraction.Add(fraction1, fraction2: TFraction): TFraction;
begin
  Result.aNumerator := (fraction1.Numerator*fraction2.Denominator+fraction1.Denominator*fraction2.Numerator);
  Result.aDenominator := fraction1.Denominator*fraction2.Denominator;
end;

我做了一些测试，我发现两者都给了我正确的结果，但有一些我无法理解的东西。在第一种方法中，我声明 tmp ，然后我调用构造函数，以便返回TFraction。在第二种方法中，我没有创建任何东西，因为记录具有自动构造函数。事实上，文档说：

使用默认的无参数自动构建记录构造函数，但必须显式构造类。因为记录有一个默认的无参数构造函数，任何用户定义的记录构造函数必须有一个或多个参数。

这里我有一个用户定义的记录构造函数。所以：

是否需要第一种方法的tmp上的构造函数调用？如果我想调用Reduce（这是一个过程），我需要创建一个变量。 Result只是在没有创建任何内容的情况下返回tmp的副本吗？
在第二种方法中，Result.aNumerator和Result.aDenominator是自动创建的构造函数的参数吗？

Answer 1

记录构造函数不是什么神奇的东西。它只是一个像其他任何实例一样的实例方法。你写道：

tmp := TFraction.Create(...);

但你也可以这样写：

tmp.Create(...);

我个人认为两者都没有特别有用，因为我习惯于为分配和默认初始化内存的类调用语义，然后调用构造函数方法。

尤其是第二个版本与我合作，因为这看起来是新手Delphi程序员在开始并尝试创建类的实例时所犯的经典错误。如果TFraction是一个类，那么代码就不好了，但是对于一个记录来说这很好。

如果是我，我将摆脱记录构造函数，而是使用一个静态类函数返回一个新记录的记录类型实例。我的惯例是命名New这样的东西。但这些都是个人偏好的问题。

如果您这样做，它将被声明为：

class function New(aNumerator, aDenominator: Integer): TFraction; static;

它将实现如下：

class function TFraction.New(aNumerator, aDenominator: Integer): TFraction;
begin
  Result.aNumerator := ...;
  Result.aDenominator := ...;
end;

然后你会这样称呼它：

frac := TFraction.New(num, denom);

但正如我所说，这是一个偏好问题。如果您喜欢记录构造函数，请随时坚持使用它们。

您问是否可以跳过构造函数。在记录分配方面，是的，你可以跳过它。在构造函数中运行代码方面，只有您可以确定。您是否希望执行该代码？

如果您希望执行该代码，但又不想使用临时变量，那么您可以编写如下代码：

class operator TFraction.Add(fraction1, fraction2: TFraction): TFraction;
begin
  Result.Create(
    fraction1.Numerator*fraction2.Denominator + fraction1.Denominator*fraction2.Numerator,
    fraction1.Denominator*fraction2.Denominator
  );
  Result.Reduce;
end;

或者，如果您更喜欢静态类函数，那么它将是：

class operator TFraction.Add(fraction1, fraction2: TFraction): TFraction;
begin
  Result := TFraction.New(
    fraction1.Numerator*fraction2.Denominator + fraction1.Denominator*fraction2.Numerator,
    fraction1.Denominator*fraction2.Denominator
  );
  Result.Reduce;
end;

是否真的需要Delphi记录构造函数？

1 个答案: