Question

我有以下XML。

<oai_dc:dc xmlns:oai_dc="http://www.openarchives.org/OAI/2.0/oai_dc/">
    <dc:title xmlns:dc="http://purl.org/dc/elements/1.1/" xml:lang="hrv">Naslov rada</dc:title>
    <dc:date xmlns:dc="http://purl.org/dc/elements/1.1/">2001-01-01</dc:date>
    <dc:creator xmlns:dc="http://purl.org/dc/elements/1.1/">Prezime, Ime</dc:creator>
    <dc:date xmlns:dc="http://purl.org/dc/elements/1.1/">2002-02-02</dc:date>
    <dc:relation xml:lang="eng">University of Zagreb. Academy of dramatic art. </dc:relation>
</oai_dc:dc>

我需要的输出是：

<dc>
    <creator>Prezime, Ime</creator>
    <date>2002-02-02</date> 
    <relation lang="eng">University of Zagreb. Academy of dramatic art.</relation>
    <title lang="hrv">Naslov rada</title>   
</dc>

所以，我需要做的是：从属性和元素中删除命名空间。我尝试使用此代码，但它确实有效。

<xsl:template match="*">
 <xsl:element name="{local-name()}">
  <xsl:apply-templates select="@*|node()"/>
 </xsl:element>
</xsl:template>
<xsl:template match="@*">
 <xsl:attribute name="{local-name()}">
  <xsl:value-of select="."/>
 </xsl:attribute>
</xsl:template>

接下来我需要按元素名称（可能是属性名称）对元素进行排序。我用这段代码做到了，它确实有用。

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="@*">
    <xsl:sort select="name()"/>
   </xsl:apply-templates>
   <xsl:apply-templates select="node()">
    <xsl:sort select="name()"/>
   </xsl:apply-templates>
  </xsl:copy>
 </xsl:template>

然后我需要删除所有以＆＃34; 2001＆＃34;开头的元素。我做到了这一点并且有效。

<xsl:template match="/dc/date[starts-with(text(), '2001')]" />

最后，我必须修剪元素中的所有文本值。注意：

<dc:relation xml:lang="eng">University of Zagreb. Academy of dramatic art. </dc:relation>

我应该从结束（开始）修剪空白区域，所以它是：

<dc:relation xml:lang="eng">University of Zagreb. Academy of dramatic art.</dc:relation>

所以我的问题是我无法在一个XSLT组合中使其工作。想法是：从定义名称空间的元素和属性中删除前缀（名称空间），然后对元素进行排序并删除一些特定元素（如我的情况），最后修剪所有剩余的文本值。

我做了所有这些，但有一个变换。有可能一次性完成吗？

我只能使用XSLT 1.0

Answer 1

使用

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  xmlns:oai_dc="http://www.openarchives.org/OAI/2.0/oai_dc/"
  xmlns:dc="http://purl.org/dc/elements/1.1/">

  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

<xsl:template match="*">
 <xsl:element name="{local-name()}">
  <xsl:apply-templates select="@*">
      <xsl:sort select="local-name()"/>
  </xsl:apply-templates>
  <xsl:apply-templates select="node()">
      <xsl:sort select="local-name()"/>
  </xsl:apply-templates>
 </xsl:element>
</xsl:template>

<xsl:template match="@*">
 <xsl:attribute name="{local-name()}">
  <xsl:value-of select="."/>
 </xsl:attribute>
</xsl:template>

<xsl:template match="/oai_dc:dc/dc:date[starts-with(text(), '2001')]" />

<xsl:template match="text()[normalize-space()]">
    <xsl:value-of select="normalize-space()"/>
</xsl:template>

</xsl:transform>

创建输出（http://xsltransform.net/3NSSEvB）

<dc>
   <creator>Prezime, Ime</creator>
   <date>2002-02-02</date>
   <relation lang="eng">University of Zagreb. Academy of dramatic art.</relation>
   <title lang="hrv">Naslov rada</title>
</dc>

请注意，normalize-space()的使用不仅会修剪前导和尾随空格，还会将其他字符之间的任何空白序列替换为单个空格。

在一个转换中进行XSLT复制，修剪，排序和删除

1 个答案: