Question

对于我的研究项目，我在XML / TEI中有这个文件

<TEI xmlns="http://www.tei-c.org/ns/1.0" >
<body>
    <div>
        <p>
            <span target="#" type="passage" ana="Tag957 Tag874">
                <span target="#" ana=""/>
            </span>
            <seg><date when="1980-01-01" type="date_seg"/>blabla blabla
                 blabla blablablabla blablablabla blablablabla blablablabla bl
            </seg>
            <span target="#" type="passage" ana="Tag1657 ">
                <span target="#" ana=""/>
            </span>
            <seg><date from="1980-01-03" to="1980-01-05" type="date_seg"/>blabla
            </seg>
        </p>
    </div>
</body>
</TEI>

我需要提取span / @ ana中包含的每个标记：以下节点seg的日期和字符串长度。条件是如果我们输入日期属性@from或@to，我只需要@from的值。我需要的是：

Tag957;1980-01-01;88
Tag874;1980-01-01;88
Tag1657;1980-01-03;11

我尝试了这个，但我不知道如何表达for-each一次应用于一个属性的值

<xsl:template match="tei:p">
        <xsl:for-each select="tei:span">
                <xsl:value-of select="./@ana"/>
                <xsl:text>;</xsl:text>
            <xsl:if test="following-sibling::tei:seg/tei:date/@from or following-sibling::tei:seg/tei:date/@to">
                <xsl:value-of select="following-sibling::tei:seg/tei:date/@from"/>
            </xsl:if>
            <xsl:if test="following-sibling::tei:seg/tei:date/@when">
                <xsl:value-of select="following-sibling::tei:seg/tei:date/@when"/>
            </xsl:if>
                <xsl:text>;</xsl:text>
                <xsl:value-of select="string-length(following-sibling::tei:seg)"/>
                <xsl:text>;</xsl:text>
                <xsl:value-of select="$newLine"/>
        </xsl:for-each>
</xsl:template>

Answer 1

您只为span元素设置了单循环。这还不够。

实际上，对于每个span，您必须：

阅读ana属性。
使用空格对其进行Tokienize（如果可以，请使用XSLT 2.0，它具有此功能）。

对于每个结果标记（不是@ana的整个值），您必须执行内部for-each循环：

在seg兄弟及其子date元素后面找仅第一个： select="following-sibling::tei:seg[1]/tei:date"（请注意，我添加了 [1] ）。
检查其是否包含必需的属性（from，to或when）。

若是，那么：

打印从当前ana属性中提取的当前令牌。
根据您的需要（来自当前date元素）打印所需日期。
打印剩余的要打印的东西。

这只是一个草图，我省略了保留各个变量中两个循环的当前值的详细信息。

我希望它能帮助你达到最终结果。

Answer 2

使用XSLT 2.0，您可以使用tokenize来识别属性值中的不同值，然后您可以将代码重写为

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" xpath-default-namespace="http://www.tei-c.org/ns/1.0">
    <xsl:template match="p">
        <xsl:for-each select="span">
            <xsl:variable name="span" select="."/>
            <xsl:for-each select="tokenize(@ana, '\s+')[normalize-space()]">
              <xsl:value-of select="."/>
              <xsl:text>;</xsl:text>
              <xsl:if test="$span/following-sibling::seg[1]/date/@from or $span/following-sibling::seg[1]/date/@to">
                <xsl:value-of select="$span/following-sibling::seg[1]/date/@from"/>
              </xsl:if>
              <xsl:if test="$span/following-sibling::seg/date/@when">
                <xsl:value-of select="$span/following-sibling::seg/date/@when"/>
              </xsl:if>
              <xsl:text>;</xsl:text>
              <xsl:value-of select="string-length($span/following-sibling::seg[1])"/>
              <xsl:text>;</xsl:text>
              <xsl:value-of select="'&#10;'"/>
            </xsl:for-each>    
        </xsl:for-each>
    </xsl:template>
</xsl:transform>

在http://xsltransform.net/jz1PuPL在线。

Answer 3

<强> XSLT-1.0

我创建了一个递归模板来标记ana属性中的值，并为每个跨度调用它。我必须在第8行添加一个空格才能使模板正常工作： <xsl:with-param name="remaining-ana-val" select="substring-after(concat(./@ana,' '),' ')"/>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  xmlns:tei="http://www.tei-c.org/ns/1.0">
    <xsl:output method="text" omit-xml-declaration="yes" encoding="UTF-8"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="tei:p">
        <xsl:for-each select="tei:span">
            <xsl:call-template name="recurse_ana">
                <xsl:with-param name="ana_val" select="substring-before(./@ana,' ')"/>
                <xsl:with-param name="remaining-ana-val" select="substring-after(concat(./@ana,' '),' ')"/>
                <xsl:with-param name="seg" select="following-sibling::tei:seg[1]"/>
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>
    <xsl:template name="recurse_ana">
        <xsl:param name="ana_val"/>
        <xsl:param name="remaining-ana-val"/>
        <xsl:param name="seg"/>
        <xsl:if test="string-length($ana_val) > 0"><xsl:value-of select="$ana_val"/>
            <xsl:value-of select="';'"/>
            <xsl:value-of select="$seg/tei:date/(@when|@from)"/>
            <xsl:value-of select="';'"/>
            <xsl:value-of select="string-length($seg)"/>
            <xsl:value-of select="'&#x0D;'"/>
            <xsl:call-template name="recurse_ana">
                <xsl:with-param name="ana_val" select="substring-before($remaining-ana-val,' ')"/>
                <xsl:with-param name="remaining-ana-val" select="substring-after($remaining-ana-val,' ')"/>
                <xsl:with-param name="seg" select="$seg"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

<强>输出：

Tag957;1980-01-01;105 
Tag874;1980-01-01;105 
Tag1657;1980-01-03;19

在线链接：http://xsltransform.net/gWEamLJ/2

XSL for-each以空格分隔的属性值

3 个答案: