Question

是否可以在Delphi中调用名称存储在字符串中的函数？

Answer 1

请详细说明您想要达到的目标。

据我所知：

无法像这样调用随机函数。
对于类和对象函数（MyObject.Function），可以使用RTTI完成，但这需要做很多工作。
如果你只需要调用一种特定类型的函数（比如函数（整数，整数）：string），那就容易多了。

对于最后一个，声明一个函数类型，然后得到一个函数指针并像这样抛出它：

type
  TMyFuncType = function(a: integer; b: integer): string of object;

  TMyClass = class
  published
    function Func1(a: integer; b: integer): string;
    function Func2(a: integer; b: integer): string;
    function Func3(a: integer; b: integer): string;
  public
    function Call(MethodName: string; a, b: integer): string;
  end;

function TMyClass.Call(MethodName: string; a, b: integer): string;
var m: TMethod;
begin
  m.Code := Self.MethodAddress(MethodName); //find method code
  m.Data := pointer(Self); //store pointer to object instance
  Result := TMyFuncType(m)(a, b);
end;

{...}

//use it like this
var MyClass: TMyClass;
begin
  MyClass := TMyClass.Create;
  MyClass.Call('Func1', 3, 5);
  MyClass.Call('Func2', 6, 4);
  MyClass.Destroy;
end.

Answer 2

你没有指定你的Delphi版本，但是如果你有Delphi 2010（+）你可以使用增强的RTTI来做，我不是他们的专家，但我为你试了这个样本：

  TProcClass = class
    public
      procedure SayHi;
      function GetSum(X,Y:Integer): Integer;
  end;

uses
  Rtti;

{ TProcClass }

procedure TProcClass.SayHi;
begin
  ShowMessage('Hi');
end;

function TProcClass.GetSum(X, Y: Integer): Integer;
begin
  ShowMessage(IntToStr(X + Y));
end;

procedure ExecMethod(MethodName:string; const Args: array of TValue);
var
 R : TRttiContext;
 T : TRttiType;
 M : TRttiMethod;
begin
  T := R.GetType(TProcClass);
  for M in t.GetMethods do
    if (m.Parent = t) and (m.Name = MethodName)then
      M.Invoke(TProcClass.Create,Args)
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ExecMethod('SayHi',[]);
  ExecMethod('GetSum',[10,20]);
end;

好的东西，如果你有参数的程序或功能，它将无需更多的工作。

Answer 3

我很惊讶没有人建议dispatch table。这正是它的用途。

program RPS;

uses
  SysUtils,
  Generics.Collections;

type
  TDispatchTable = class(TDictionary<string, TProc>);

procedure Rock;
begin
end;

procedure Paper;
begin
end;

procedure Scissors;
begin
end;

var
  DispatchTable: TDispatchTable;

begin
  DispatchTable := TDispatchTable.Create;
  try
    DispatchTable.Add('Rock', Rock);
    DispatchTable.Add('Paper', Paper);
    DispatchTable.Add('Scissors', Scissors);

    DispatchTable['Rock'].Invoke; // or DispatchTable['Rock']();
  finally
    DispatchTable.Free;
  end;
end.

我编写的实现使用泛型，因此它只适用于Delphi 2009+。对于旧版本，使用TStringList和command pattern

实现可能最容易

Answer 4

使用Delphi 2010，您可以使用JSON和SuperObject来调用带参数的方法。

http://code.google.com/p/superobject/source/browse/#svn/trunk

如果需要，还有一个xml解析器可以将xml转换为json。

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure TestMethod(const value: string);
  end;

var
  Form1: TForm1;

implementation
uses superobject;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  SOInvoke(Self, 'TestMethod', SO('{value: "hello"}'));
end;

procedure TForm1.TestMethod(const value: string);
begin
  Caption := value;
end;

Answer 5

如果您在Delphi中询问是否有类似JavaScript eval()的内容，那么由于Delphi编译为本机代码，因此不能（轻松）实现。

如果您只需要支持某些字符串，您可以随时执行许多if或case ...类似的事情：

if myString = 'myFunction' then
    myFunction();

Answer 6

将每个函数放入Action中。然后你可以按名称找到Action并执行它

function ExecuteActionByName(const S: String);
var
  I: Integer;
begin
  for I := 0 to MainForm.ComponentCount-1 do
    if (MainForm.Components[I] is TAction)
    and SameText(TAction(MainForm.Components[I]).Name,S) then
    begin
      TAction(MainForm.Components[I]).Execute;
      Break;
    end;
end;

Answer 7

您可以通过制作一个或多个具有已发布属性的类来执行此类操作，这些属性使用函数来实现其读写功能。然后可以使用RTTI反射发现属性并引用它们，从而导致调用底层函数。

或者，您可以将函数指针存储在表中，甚至可以存储TStringList的Object属性，并通过字符串名称对它们进行有效索引。

在Delphi中无法按名称直接调用函数。

Answer 8

好的，我非常参加聚会，但你肯定可以通过这个代码按名称调用例程（考虑到一些限制）

type
    TExec = procedure of Object;
    // rest of section...

procedure TMainForm.ExecuteMethod(MethodName : String);
var
   Exec    : TExec;
   Routine : TMethod;
begin
     Routine.Data := Pointer(Form1);
     Routine.Code := Form1.MethodAddress(MethodName);
     if Not Assigned(Routine.Code) then
        Exit;

     Exec         := TExec(Routine);
     Exec;
end;

以防万一有人需要Delphi 7/2010

Answer 9

使用 exports 和 GetProcAddress 的以下简单解决方案也适用于旧的Delphi版本：

type
    TMyProc = procedure(const value: Integer);

    procedure Test(const value: Integer);

    exports Test;

implementation

procedure Test(const value: string);
begin
    ShowMessage('It works! '  + value);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
    p: TMyProc;
begin
    p := GetProcAddress(HInstance, 'Test'); 
    if Assigned(p) then P('Yes');
end;

Answer 10

function ExecuteMethod(AClass : TClass; AMethodName : String; const AArgs: Array of TValue) : TValue;
var
  RttiContext : TRttiContext;
  RttiMethod  : TRttiMethod;
  RttiType    : TRttiType;
  RttiObject  : TObject;
begin
  RttiObject := AClass.Create;
  try
    RttiContext := TRttiContext.Create;
    RttiType    := RttiContext.GetType(AClass);
    RttiMethod  := RttiType.GetMethod(AMethodName);
    Result      := RttiMethod.Invoke(RttiObject,AArgs);
  finally
    RttiObject.Free;
  end;
end;

Delphi：调用名称存储在字符串中的函数

10 个答案: