Question

我使用VB.NET中的以下语句将JSON反序列化为数据表。

Dim _dt As DataTable = JsonConvert.DeserializeObject(Of DataTable)(myRecords)

myRecords是一个JSON字符串。

它工作正常，但myRecords有一些数字属性，如{“PhoneNo”：“123456789”，“ID”：“46541”}，反序列化后，这些属性将转换为数据类型为字符串的列。

如何将它们反序列化为数字？ myRecords正在动态填充，因此我无法进行硬编码。

Answer 1

Json.NET为"PhoneNo" : "123456789"创建字符串类型列的原因是"123456789"实际上是根据JSON standard的字符串文字。数字文字看起来像这样，在值123456789周围没有双引号。您确定这些属性总是是数字字符串吗？并非所有电话号码都是数字的，例如，因此将它们硬编码似乎是不明智的。

话虽如此，如果你确定这些属性永远是数字字符串并希望Json.NET为它们创建数字DataTable列，你需要提前告诉它这些列的所需类型。一种选择是从适当的模式创建typed DataTable。在这种情况下，JsonConvert.DeserializeObject(Of TTypedDataTable)(myRecords)将创建一个具有所需列类型的DataTable子类。

另一种选择是使用适当的列集手动创建DataTable，然后从JSON填充表。很遗憾，JsonConvert.PopulateObject()无法在预先分配的DataTable上使用，因此您需要直接致电DataTableConverter.ReadJson()。这可以使用以下扩展方法完成：

Public Module JsonExtensions
    Public Sub PopulateDataTable(json As String, target As DataTable, Optional settings As JsonSerializerSettings = Nothing)
        Using reader = New JsonTextReader(New StringReader(json))
            Do
                If reader.TokenType = JsonToken.StartArray Then
                    ' Populate the table
                    Dim converter = New DataTableConverter()
                    converter.ReadJson(reader, target.GetType(), target, JsonSerializer.CreateDefault(settings))
                End If
            Loop While reader.Read()
        End Using
    End Sub
End Module

然后按如下方式使用：

        Dim _dt = New DataTable()
        _dt.Columns.Add("PhoneNo", GetType(Long))
        _dt.Columns.Add("ID", GetType(Long))
        JsonExtensions.PopulateDataTable(myRecords, _dt)

示例fiddle。

你还写道，我不能用硬编码。如果你真的不知道哪些列字符串值实际上应该被反序列化为数字类型，你可以做的是预先 - 通过将JSON加载到Jtoken中来处理JSON，按名称对所有属性值进行分组，对于每个组，检查 all 组中的值是可转换为数字的字符串。如果所有都是可兑换的，您可以进行转换。但是如果只有一些是可转换的，那么就不应该进行转换，因为这会破坏Json.NET的类型推理算法。可以使用以下扩展方法完成：

Public Module JsonExtensions
    Private ReadOnly NumberTypes = New JTokenType() {JTokenType.[Integer], JTokenType.Float, JTokenType.[String], JTokenType.Comment, JTokenType.Raw, JTokenType.[Boolean]}

    Private Function ValidateToken(o As JToken, validTypes As JTokenType(), nullable As Boolean) As Boolean
        Return (Array.IndexOf(validTypes, o.Type) <> -1) OrElse (nullable AndAlso (o.Type = JTokenType.Null OrElse o.Type = JTokenType.Undefined))
    End Function

    <System.Runtime.CompilerServices.Extension> _
    Public Function CanConvertToNullableLong(token As JToken) As Boolean
        ' Reverse engineered from 
        ' public static explicit operator long?(JToken value)
        ' https://github.com/JamesNK/Newtonsoft.Json/blob/master/Src/Newtonsoft.Json/Linq/JToken.cs#L1045
        If token Is Nothing OrElse token.Type = JTokenType.Null OrElse token.Type = JTokenType.Boolean Then
            Return True
        End If
        If Not ValidateToken(token, NumberTypes, True) Then
            Return False
        End If
        Dim jValue = TryCast(token, JValue)
        If jValue Is Nothing Then
            Return False
        End If
        If TypeOf jValue.Value Is BigInteger Then
            Dim i = CType(jValue.Value, BigInteger)
            Return i <= Long.MaxValue AndAlso i >= Long.MinValue
        End If
        Dim s = CType(jValue, String)
        Dim v As Long
        Return Long.TryParse(s, NumberStyles.Number, NumberFormatInfo.InvariantInfo, v)
    End Function

    Public Sub TryConvertColumnsToNullableLong(root As JToken)
        If TypeOf root Is JContainer Then
            ' If ALL columns values of a given name can be converted from string to long, then do so.
            ' Do not convert columns where some but not all are convertable.
            For Each group In DirectCast(root, JContainer) _
                .Descendants() _
                .OfType(Of JProperty)() _
                .GroupBy(Function(p) p.Name) _
                .Where(Function(g) g.All(Function(p) (p.Value.Type = JTokenType.String Or p.Value.Type = JTokenType.Null) AndAlso p.Value.CanConvertToNullableLong()))
                For Each p In group
                    p.Value = CType(p.Value, System.Nullable(Of Long))
                Next
            Next
        End If
    End Sub
End Module

然后按如下方式预处理和反序列化：

        Dim token = JToken.Parse(myRecords)
        JsonExtensions.TryConvertColumnsToNullableLong(token)
        Dim _dt = token.ToObject(Of DataTable)()

示例fiddle #2。

我不确定我会推荐这个。 JSON值是字符串这一事实表明，在生成JSON的数据库中，这些值可能是任意字符串。如果是这样，当非数字值开始输入数据库时，黑客转换为long可能会导致问题。

使用JsonConvert

1 个答案: