Question

无限懒惰列表真棒！

> my @fibo = 0, 1, *+* ... *;
> say @fibo[1000];
43466557686937456435688527675040625802564660517371780402481729089536555417949051890403879840079255169295922593080322634775209689623239873322471161642996440906533187938298969649928516003704476137795166849228875

他们会自动缓存他们的值，这在大多数情况下都很方便。但是当使用巨大的斐波纳契数（example）时，这可能会导致内存问题。

不幸的是，我无法弄清楚如何创建非缓存Fibonacci序列。任何人吗？

Answer 1

一个主要问题是你将它存储在一个数组中，这当然保留了它的所有值。

下一个问题有点微妙，dotty sequence generator syntax LIST, CODE ... END不知道 CODE 部分要求的先前值有多少，所以它保留所有这些（它可以查看 CODE 的arity / count，但目前似乎没有来自REPL的实验）

然后问题是&postcircumfix:<[ ]>调用Seq时使用.cache，假设您要在某个时刻要求其他值。
（从查看Seq.AT-POS的来源）

未来的实施可能会更好地解决这些缺点。

您可以使用不同的功能创建序列，以克服dotty序列生成器语法的当前限制。

sub fibonacci-seq (){
  gather {
    take my $a = 0;
    take my $b = 1;

    loop {
      take my $c = $a + $b;
      $a = $b;
      $b = $c;
    }
  }.lazy
}

如果你只是迭代这些值，你可以按原样使用它。

my $v;
for fibonacci-seq() {
  if $_ > 1000 {
    $v = $_;
    last;
  }
}
say $v;

my $count = 100000;
for fibonacci-seq() {
  if $count-- <= 0 {
    $v = $_;
    last;
  }
}
say chars $v; # 20899

您也可以直接使用Iterator。虽然在大多数情况下这不是必需的。

sub fibonacci ( UInt $n ) {
  # have to get a new iterator each time this is called
  my \iterator = fibonacci-seq().iterator;
  for ^$n {
    return Nil if iterator.pull-one =:= IterationEnd;
  }
  my \result = iterator.pull-one;
  result =:= IterationEnd ?? Nil !! result
}

如果您有最新版本的Rakudo，可以使用skip-at-least-pull-one。

sub fibonacci ( UInt $n ) {
  # have to get a new iterator each time this is called
  my \result = fibonacci-seq().iterator.skip-at-least-pull-one($n);
  result =:= IterationEnd ?? Nil !! result
}

您也可以直接实施Iterator课程，并将其包含在Seq中（这主要是返回序列的方法是如何在Rakudo核心中编写的）

sub fibonacci-seq2 () {
  Seq.new:

  class :: does Iterator {

    has Int $!a = 0;
    has Int $!b = 1;

    method pull-one {
      my $current = $!a;
      my $c = $!a + $!b;
      $!a = $!b;
      $!b = $c;
      $current;
    }

    # indicate that this should never be eagerly iterated
    # which is recommended on infinite generators
    method is-lazy ( --> True ) {}

  }.new
}

Answer 2

显然，一个菜鸟无法发表评论。

当定义一个惰性迭代器，例如sub fibonacci-seq2时，应该通过添加一个＆＃34; is-lazy＆＃34;来将迭代器标记为惰性。返回True的方法，例如：

method is-lazy(--> True) { }

这将允许系统更好地检测可能的infiniloops。

如何在Perl 6中使用非缓存无限延迟列表

2 个答案: