Stata事件研究图表代码

Question

我正在尝试为Stata中的事件研究编写代码，但我无法得到我想要的东西。 Jacobson，LaLonde和Sullivan（1993），第698页图3（http://www.princeton.edu/~davidlee/wp/0.pdf），有一个与我想要的非常相似的情节，除了我还想增加置信区间。

根据本教程http://www.stata.com/meeting/germany14/abstracts/materials/de14_jann.pdf，我编写了以下代码：

sysuse auto, clear
egen t = fill(1,2,3,4,1,2,3,4)
quietly regress price ib2.t trunk weight if foreign==0
estimates store domestic
quietly regress price ib2.t trunk weight if foreign==1
estimates store foreign
coefplot (domestic, label(Domestic Cars)) (foreign, label(Foreign Cars)), drop(_cons) xline(0) vertical omitted baselevels

这会产生我想要的东西，但存在以下问题：

1. 积分估计和置信区间是并排的，而不是彼此叠加（如果这是唯一的问题，这可能会很好）。
2. 我的时间变量t出现在每个x标签中（t = 1，t = 2等），但我只想说（1,2等）没有t =。
3. 我必须在这个玩具示例中以1开始编号，因为与i运算符组合的因子变量需要是非负数。我想让我的时间变量能够承担负数。
4. 我不希望trunk和weight出现在情节中。将它们放在drop(...)？
中可以
5. 我也希望能够在回归残差中完成所有这些，而不是我上面所做的。
6. 我想用点线连接点估计值。

我完全不和coefplot命令结婚。其他技术，特别是使用内置的Stata命令也是完全可以接受的。

Answer 1

希望我已经正确回答了你的问题，也许我误解了一些问题，但这是我的回答：

（我没有解决5，因为我不确定你正在寻找那个问题，但也许在看到我的解决方案后会很清楚）

代码：

// load data same as before
sysuse auto, clear
egen t = fill(1,2,3,4,1,2,3,4)

// get coefficients and standard errors of regressions over foreign
statsby _b _se , clear by(foreign): regress price ib2.t trunk weight

// there are some extra variables we don't need/want
drop *_trunk *_weight *_cons

// generate confidence intervals and rename coefficient variables
forvalues i = 1/4 {
    local j = `i'+7
    gen ci_low`i' = _stat_`i' - 1.96*_stat_`j'
    gen ci_high`i' = _stat_`i' + 1.96*_stat_`j'
    rename _stat_`i' coef`i'

}
// no longer in need of standard error variables
drop  _stat_8 _stat_9 _stat_10 _stat_11

// now, we want our data in long format so we can do a twoway graph
reshape long coef ci_low ci_high, i(foreign) j(t)

// we can label the t values so that they start below 1
lab def timeseries 1 "-1" 2 "0" 3 "1" 4 "2"
lab values t timeseries

// now graph, note each factor has two  pieces, a scatter (with connecting lines) 
// and an rcap for the confidence intervals
twoway (sc coef t if foreign == 1, mcolor(navy) lcolor(navy) connect(direct)) ///
        (rcap ci_low ci_high t if foreign == 1, lcolor(navy)) ///
    (sc coef t if foreign == 0, mcolor(maroon) lcolor(maroon) connect(direct)) ///
        (rcap ci_low ci_high t if foreign == 0, lcolor(maroon)), ///
    legend(lab(1 "Foreign") lab(2 "Foreign CI") lab(3 "Domestic") lab(4 "Domestic CI")) ///
    xlab(,val)

人们可能希望改善这种情况的一些方法是：

• 使用标签定义，可以使用for循环来获取比此更长的时间序列，因此不是全部手动完成

• 我不是关于statsby的专家，所以也许有一种更简单的方法来获得置信区间并省去树干，体重和常数

对于残差，这个答案的基本直觉是你想要一个包含系数和置信区间的数据集。因此，如果您可以计算残差及其CI的值并将其放入数据集中，那么您可以使用相同类型的双向图。