Question

我有一个方案中的项目，我需要实现一个无限的数字序列。我不能使用任何方案内置的复杂函数，我只是不知道如何在没有程序崩溃的情况下使我的序列无限循环。我不必真正输出它，但我需要能够使用它。

(seq n)   ;;output: n,n+1,n+2,n+3.... to infinity (seq 5) ->5,6,7,8,9...

现在我做了一个序列，直到n + 7，但我需要这个到无限：

(define (seq n)
   (define (asc-order LIST counter)
     (cond ((= counter (+ n 7)) LIST)
           (else (asc-order (append LIST (cons (+ counter 1) '()))  
           (+ counter 1)))))
(asc-order '() (- n 1))
)

IO示例（它有效，但我需要无限序列）：

>(define s (seq 3)) 
>(car s)   
3

Answer 1

您可以将无限序列表示为一次生成一个元素的函数。然后，用户（消费者）可以调用该函数，每个元素都需要一个新元素。

一个例子：

(define (f x) (* x x))

(define seq
  (let ()
    (define n 0)        ; current index
    (lambda ()          ; the function that is to be called repeatedly
      (define a (f n))  ;   compute the new element
      (set! n (+ n 1))  ;   compute new index
      a)))              ;   return the new element

(seq)  ; compute element 0
(seq)  ; compute element 1
(seq)  ; ...
(seq)
(seq)
(seq)

评估结果为：

为了编写计算序列(sequence->list s n)的第一个n元素的s，请创建一个总共s次调用n的循环 - 并将结果收集在列表中。

Answer 2

关键是通过在其周围包装程序来延迟对列表的评估。

这是我能想到的最简单的实现。
它只是＆＃34;懒惰＆＃34;在尾巴。

(define (seq n)
  (cons n (lambda () (seq (+ n 1)))))

(define (seq-car s)
  (car s))

(define (seq-cdr s)
  ((cdr s)))

使用示例：

; Get the 'n' first elements of 's'.
(define (seq-take n s)
  (if (<= n 0)
      '()
      (cons (seq-car s) (seq-take (- n 1) (seq-cdr s)))))


> (define s (seq 10))
> s
'(10 . #<procedure>)
> (seq-take 5 s)
'(10 11 12 13 14)

Answer 3

以下是使用延迟评估的另一种解决方案：

(use-modules (ice-9 receive))


(define (seq f)
  (let loop ((n 0))
    (lambda ()
      (values (f n) (loop (1+ n))))))


(define squares (seq (lambda (x) (* x x))))

(receive (square next) (squares)
  (pk square) ;; => 0
  (receive (square next) (next)
    (pk square) ;; => 1
    (receive (square next) (next)
      (pk square) ;; => 4
      (receive (square next) (next)
        (pk square))))) ;; => 9

无限序列方案，使无限序列

3 个答案: