Question

让我们看看STM32F103链接器脚本：

/* Entry Point */
ENTRY(Reset_Handler)

/* Highest address of the user mode stack */
_estack = 0x20005000;    /* End of 20K RAM */

/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0;      /* Required amount of heap  */
_Min_Stack_Size = 0x100; /* Required amount of stack */

/* Specify the memory areas */
MEMORY
{
  FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 128K
  RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 20K
  MEMORY_B1 (rx)  : ORIGIN = 0x60000000, LENGTH = 0K
}

/* Define output sections */
SECTIONS
{
  /* The startup code goes first into FLASH */
  .isr_vector :
  {
    . = ALIGN(4);
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH

  /* The program code and other data goes into FLASH */
  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    *(.glue_7)         /* Glue arm to thumb code */
    *(.glue_7t)        /* Glue thumb to arm code */

    KEEP (*(.init))
    KEEP (*(.fini))

    . = ALIGN(4);
    _etext = .;        /* Define a global symbols at end of code */
  } >FLASH


   .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
    .ARM : {
    __exidx_start = .;
      *(.ARM.exidx*)
      __exidx_end = .;
    } >FLASH

  .ARM.attributes : { *(.ARM.attributes) } > FLASH

  .preinit_array     :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } >FLASH
  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } >FLASH
  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(.fini_array*))
    KEEP (*(SORT(.fini_array.*)))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } >FLASH

  /* Used by the startup to initialize data */
  _sidata = .;

  /* Initialized data sections goes into RAM, load LMA copy after code */
  .data : AT ( _sidata )
  {
    . = ALIGN(4);
    _sdata = .;        /* Create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */

    . = ALIGN(4);
    _edata = .;        /* Define a global symbol at data end */
  } >RAM

  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* Define a global symbol at BSS start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* Define a global symbol at BSS end */
    __bss_end__ = _ebss;
  } >RAM

  PROVIDE ( end = _ebss );
  PROVIDE ( _end = _ebss );

  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(4);
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(4);
  } >RAM

  /* MEMORY_bank1 section, code must be located here explicitly            */
  /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
  .memory_b1_text :
  {
    *(.mb1text)        /* .mb1text sections (code) */
    *(.mb1text*)       /* .mb1text* sections (code)  */
    *(.mb1rodata)      /* read-only data (constants) */
    *(.mb1rodata*)
  } >MEMORY_B1

  /* Remove information from the standard libraries */
  /DISCARD/ :
  {
    libc.a ( * )
    libm.a ( * )
    libgcc.a ( * )
  }
}

我可以看到ISR向量被放置在flash中，所以如果程序需要调用存储在某个向量中的地址，它将从闪存中读取。

第一个问题：硬件如何在RAM和闪存之间进行区分？那么为什么我需要特殊的寄存器来代码写入闪存或从闪存读取代码，而不能只是明确地写入或读取它的地址？

第二个问题是关于从闪存读取比从RAM读取的速度慢多少？如果我知道在我的代码中使用了什么函数，那么我能够将它移动到RAM部分以至关重要地加速执行吗？我相信此脚本中的MEMORY_B1专门用于此目的。

第三个问题：如果长度为0，我们如何在MEMORY_B1中放置任何内容？

最后一个问题：如果我在闪存中创建一个额外的部分，那么我可以创建一些简单的虚拟内存模拟吗？我认为这个问题的答案取决于第一个问题。

Answer 1

硬件并不关心，因为两个存储器（实际上是其他任何东西）都映射在公共地址空间中。然而，这并不意味着您可以轻松编写闪存来将其视为RAM，因为这很慢并且可能会快速损坏内存（它具有100k周期的典型写入耐久性）。此外，它只能在整页中擦除（对于某些STM32芯片，它可能会大到128 kB），这实际上使用它作为RAM的替代品存在问题。
速度差异可以忽略不计。在ARM Cortex-M微控制器上从RAM运行代码将比预期慢，因为RAM连接到不同的总线（用于数据），并且使用它来执行代码需要使用较慢的“互连”。
< / LI>
你不能。如果你想在那里放置一些东西，就必须增加内存的大小（以及“普通RAM”的大小 - 减少）。
一般情况下你可以这样做，但它会非常慢，你会很快损坏闪光灯。

Answer 2

1/2。是否在STM32F1上。只有核心速度超过100 Mhz时，闪存预取和高速缓存未命中将花费您的成本。即使这个芯片也有缓存和预取。如果在某些特殊情况下将向量表放在RAM中，那么使用这个核心可能会有微不足道的小利润。

但是，可能存在适用于所使用的访问宽度的硬件限制。但是闪光灯不受此影响。

3。是的，你当然可以。您可以在其中放置文件系统。但是你可以可靠地写入闪光灯的温度范围是有限的。并且，由于只有一组闪存，所有活动都会停止，直到擦除/闪存成功为止。除非代码从RAM运行。另外两个注意事项是闪存编程/擦除可能需要几毫秒，而且您必须考虑每个2 kB的页面擦除，但所有闪存控制器都必须这样做。

如果您需要额外的RAM，请在主板上放置一些SPI FRAM。

STM32F1微控制器的链接和内存问题

2 个答案: