Question

我正在为ANTLR4中的编程语言编写解析器。大多数情况下，我想忽略空格，但在某些情况下，使用它来表示标记之间的边界至关重要。

例如，在解析运算符应用程序myvar = this + that时，我的当前解析器将this+that作为一个长标识符。这将导致解析器失败，因为名称中不允许使用符号。我目前正在跳过所有空白，这导致了这个问题，但我找不到一个允许我将空白作为可选项的解决方案，但也使用它来指定这些边界。

我的解析器下面是我试图解析的测试代码。

分析器：

grammar archie;
// Parser Rules

program:  line* EOF;

line: (element | COMMENT)  (';' | '\n' | ';\n')+;

//assignment: identifier  EQ  element;

element:
    //Function Call
    element  elementList  |

    //Function Literal
    nameList  FARROW  element  |

    //Identifier
    identifier  |

    //CombinedID
    element  (DOT name)+ |

    //assignment
    identifier EQ element |

    O_C_BRACK (element (';' | '\n' | ';\n'))* C_C_BRACK |

    element name element
;


elementList: O_R_BRACK  element?  (COMMA  element )* C_R_BRACK;

identifier: (name (DOT name)*);

nameList: O_R_BRACK name? (COMMA name)* C_R_BRACK;
name: (ALPHABET | SYMBOL+) (ALPHABET | NUMERIC)*;

NUMERIC: [0-9];
ALPHABET: [a-zA-Z];
SYMBOL : [~!$^*&+#<>?|];
FARROW: '=>';
WS: [ \t]+ -> skip;
SKP: [\r]+ -> skip;
COMMENT: '//' (ALPHABET | SYMBOL | NUMERIC | WS)*;

DOT: '.';
COMMA: ',';

EQ: '=';

O_R_BRACK: '(';
C_R_BRACK: ')';
O_C_BRACK: '{';
C_C_BRACK: '}';

测试代码：

this.that = that.this;
this.this = that.other;
that = this;
that = () => that;
a();
this + that;

Answer 1

据我所知，你的主要问题是你的语法试图单独lex每个字符，然后解析那些。这是行不通的，词法分析者应该说出语言中的单个“单词”，而这正是使你的语法如此奇怪的原因。

你的另一个问题是“test + test”正在解析为“test”“+ test”。相反，我建议使用以下语法，它允许使用符号名称，但它们不能与字母数字符号混合。

grammar archie;
// Parser Rules

programme:  line* EOF;

line
 : element (';' | '\n')+
 | COMMENT
 ;

//assignment: identifier  EQ  element;

element
 : element  elementList         //Function Call
 | nameList  FARROW  element    //Function Literal
 | identifier                   //Identifier
 | element  (DOT NAME)+         //CombinedID
 | identifier EQ element        //assignment
 | O_C_BRACK (element (';' | '\n' | ';\n'))* C_C_BRACK
 | element NAME element
 ;


elementList: O_R_BRACK  element?  (COMMA  element)* C_R_BRACK;

identifier: NAME (DOT NAME)*;

nameList: O_R_BRACK (NAME COMMA)* (NAME COMMA?)? C_R_BRACK;

NAME
 : [A-Za-z_][A-Za-z0-9_]*
 | [~!$^*&+#<>?|]+
 ;

FARROW: '=>';
WS: [ \t]+ -> skip;
SKP: [\r]+ -> skip;
COMMENT: '//' ~[\n]* '\n'+;

DOT: '.';
COMMA: ',';

EQ: '=';

O_R_BRACK: '(';
C_R_BRACK: ')';
O_C_BRACK: '{';
C_C_BRACK: '}';

这确实会改变允许的标识符，但会实现您的总体目标。

之前：

this + that // (element (element (name this)) (name +) (element (name that)))
++that // (element (name ++that))
this+that // (element (element (name this)) (name +that) (element) and ERROR ERROR

后：

this + that // (element (element this) + (element that))
++that // ERROR ERROR
that+that // (element (element this) + (element that))

很抱歉，我知道@thst首先回答，但我正在研究语法解决方案，当我去测试它时，我的antlr4设置已经坏了，我正在修复

Answer 2

问题是，你的术语解析没有明确定义。

myvar = this + that

被解析为

element -> identifier EQ element  <- identifier = myvar, 
                                     element = "this + that"

this + that -> element name element

这是不明确的：

element可以缩减为标识符，其最小长度为（1）：

element(t) name(his) element(+that)

element可能会尽可能地解析所有字符：

element(this) name(+that) element() <- error
element(this) name(+tha) element(t)

我认为问题在于，您允许名称将运算符作为其字母表的一部分。

ANTLR4 - 我语言中的可选空格

2 个答案: