批处理 - EnableDelayedExpansion，感叹号和文件/文件夹名称

Question

我在文件和文件夹名称上遇到惊叹号（！）。 我创建的批处理读取.txt文件的内容，并将列出的文件从文件夹中排序到子文件夹中 例如：
source.txt内有：file_1.zip和file_2.zip 名为system的文件夹包含file_1.zip，file_2.zip，file_3.zip等。 批处理读取source.txt并将两个文件复制到system/source。

我试图避免启用DelayedExpansion，但是在添加文件夹浏览器后，我找不到比使用它更好的方法。我需要启用：listSources 和：listFolders 的方式 我现在的问题不是处理文件夹名称上的（！）（虽然允许它很好），但允许复制具有（！）<的文件/ strong>就其名字而言。

我想逃避^^！ setlocal和endlocal之间的角色或切换，但我还在学习如何正确使用它，因此不知道如何处理它。也许有更好的方法？ （我不是程序员！）

@echo off
setlocal EnableDelayedExpansion

rem Copy sorted files into destination folder? [Y/N]
set "copyMode=y"
if /i "%copyMode%"=="y" (set appendTitle=[Copy Mode]) else set appendTitle=[Log Mode]

rem Set prefix for output file (used only if copyMode=n)
set prefixMiss=missing_in_

rem Set defaults to launch directory
set rootSource=%~dp0
set rootFolder=%~dp0

:listSources
title Source file selection %appendTitle%
Show folder names in current directory
echo Available sources for sorting:
for %%a in (*.txt) do (
    set /a count+=1
    set mapArray[!count!]=%%a
    echo !count!: %%a
)

:checkSources
set type=source
if not exist !mapArray[1]! cls & echo No source file (.txt) found on current directory^^! & goto SUB_folderBrowser
if !count! gtr 1 set /a browser=!count!+1 & echo.!browser!: Open Folder Browser? & goto whichSource
if !count! equ 1 echo. & set /p "oneSource=Use !mapArray[1]! as source? [Y/N]: "
if /i "%oneSource%"=="y" (set "sourceFile=1" & echo. & goto listFolders) else goto SUB_folderBrowser

:whichSource
echo.
rem Select source file (.txt)
echo Which one is the source file you want to use? Choose !browser! to change directory.
set /p "sourceFile=#: "
if %sourceFile% equ !browser! goto SUB_folderBrowser
if exist !mapArray[%sourceFile%]! echo. & goto listFolders
echo Incorrect input^^! & goto whichSource

:listFolders
title System folder selection %appendTitle%
rem Show folder names in current directory
cd %~dp0
set count=0
echo Available folders for sorting:
for /d %%a in (*) do (
    set /a count+=1
    set mapArray2[!count!]=%%a
    echo !count!: %%a
)

:checkFolders
set type=root
if not exist !mapArray2[1]! cls & echo No folders found on current directory^^! & goto SUB_folderBrowser
if !count! gtr 1 set /a browser=!count!+1 & echo.!browser!: Open Folder Browser? & goto whichSystem
if !count! equ 1 echo. & set /p "oneFolder=Use !mapArray2[1]! as target? [Y/N]: "
if /i "%oneFolder%"=="y" (set "whichSystem=1" & goto whichFolder) else goto SUB_folderBrowser

:whichSystem
echo.
rem Select system folder
echo Which system do you want to sort? Choose !browser! to change directory.
set /p "whichSystem=#: "
if %whichSystem% equ !browser! goto SUB_folderBrowser
if exist !mapArray2[%whichSystem%]! echo. & goto createFolder
echo Incorrect input^^! & goto whichSystem

:createFolder
rem Create destination folder
if /i not "%copyMode%"=="y" goto sortFiles
set destFolder=!mapArray[%sourceFile%]:~0,-4!
if not exist ".\!mapArray2[%whichSystem%]!\%destFolder%" md ".\!mapArray2[%whichSystem%]!\%destFolder%"

:sortFiles
rem Look inside the source file and copy the files to the destination folder
title Sorting files in progress... %appendTitle%
for /f "delims=" %%a in ('type "%rootSource%\!mapArray[%sourceFile%]!"') do (
if exist ".\!mapArray2[%whichSystem%]!\%%a" (
    if /i "%copyMode%"=="y" copy ".\!mapArray2[%whichSystem%]!\%%a" ".\!mapArray2[%whichSystem%]!\%destFolder%\%%~nxa" >nul
    echo %%a
) else (
    echo.
    echo %%a missing & echo.
    if /i not "%copyMode%"=="y" echo %%a >> "%~dp0%prefixMiss%!mapArray2[%whichSystem%]!.txt"
    )
)

title Sorting files finished^^! %appendTitle%

popd & pause >nul & exit

:SUB_folderBrowser
if !count! lss 1 set /p "openBrowser=Open Folder Browser? [Y/N]: "
if !count! lss 1 (
    if not "%openBrowser%"=="y" exit
)
set count=0 & echo Opening Folder Browser... & echo.
if "%type%"=="root" echo Select the root system folder, not the system itself^^!

rem PowerShell-Subroutine to open a Folder Browser
set "psCommand="(new-object -COM 'Shell.Application')^
.BrowseForFolder(0,'Please choose a %type% folder.',0,0).self.path""
for /f "usebackq delims=" %%i in (`powershell %psCommand%`) do set "newRoot=%%i"

if "%type%"=="source" set rootSource=%newRoot%
if "%type%"=="root" set rootFolder=%newRoot%

rem Change working directory
if "%type%"=="source" cls & pushd %rootSource% & goto listSources
if "%type%"=="root" cls & pushd %rootFolder% & echo Selected source file: !mapArray[%sourceFile%]! & echo. & goto listFolders

非常感谢任何帮助！

Answer 1

当FOR变量包含!时，延迟扩展仅导致FOR循环内出现问题。

如果从循环内调出一个：子例程，通常可以避免FOR循环中的延迟扩展。子例程将针对每次迭代进行重新分析，因此您可以使用常规%var%变量扩展。但是CALL大大降低了速度，所以我想避免它。

有一个简单的解决方案可以避免延迟扩展并避免调用 - 使用DIR / B和FINDSTR / N将行号注入目录输出，FOR / F可以轻松解析。

例如，这是ListSources循环的解决方案：

for /f "delims=: tokens=1*" %%A in ('dir /b /a-d *.txt^|findstr /n "^"') do (
  set "mapArray[%%A]=%%B"
  set "count=%%A"
  echo %%A: %%B
)

您可以轻松地将相同的技术应用到第二个循环中。

您仍需要在其他非循环代码段中延迟扩展以扩展数组值。所以从禁用延迟扩展开始，然后启用它：whichSource，在第二个循环之前再次禁用它，然后在最后一个循环后再次启用它。请注意，您不能使用ENDLOCAL，否则您将丢失先前定义的数组值。因此，当您在禁用和启用延迟扩展之间切换时，您将创建一小堆SETLOCAL。