Question

swap!函数是Clojure工具箱中最常用的工具之一，它会instance?进行检查。我们被告知在编程中避免实现类型检查的条件，更喜欢多态（协议）。奇怪的是，ClojureScript没有直接对原子实现ISwap协议，而是在公共swap! api中，只有在检查主题是否为原子后才会回到协议上。

我认为这种策略必须是出于性能原因而使用，因为原子是swap!和许多其他原子方法的主要用例。这是对的吗？

我本来希望实现一个atom的api作为实际协议的一部分，这样就不需要这样做了。

(defn swap!
  "Atomically swaps the value of atom to be:
  (apply f current-value-of-atom args). Note that f may be called
  multiple times, and thus should be free of side effects.  Returns
  the value that was swapped in."
  ([a f]
     (if (instance? Atom a)
       (reset! a (f (.-state a)))
       (-swap! a f)))
  ([a f x]
     (if (instance? Atom a)
       (reset! a (f (.-state a) x))
       (-swap! a f x)))
  ([a f x y]
     (if (instance? Atom a)
       (reset! a (f (.-state a) x y))
       (-swap! a f x y)))
  ([a f x y & more]
     (if (instance? Atom a)
       (reset! a (apply f (.-state a) x y more))
       (-swap! a f x y more))))

Answer 1

它看起来与性能相关：http://dev.clojure.org/jira/browse/CLJS-760

使用-reset添加IAtom协议！方法和cljs.core / reset中的Atom快速路径。

请在此处查看jsperf - http://jsperf.com/iatom-adv

最新的chrome和firefox版本减速约20-30％。较旧的Firefox版本受到高达60-70％的影响。

在票证的下方，决定将IAtom分成两个协议：IReset和ISwap。但这是大卫带来的实现，它进行了类型检查，我想是为了提高速度。

不幸的是，目前还不清楚为什么没有让Atom实现IReset（和ISwap），也不清楚为什么不寻找这些东西。目前还不清楚原始补丁是如何工作的。它基本上是reset!的实施，并将其置于instance检查之下，并为其添加了-reset!路径：

diff --git a/src/cljs/cljs/core.cljs b/src/cljs/cljs/core.cljs
index 9fed929..c6e41ab 100644
--- a/src/cljs/cljs/core.cljs
+++ b/src/cljs/cljs/core.cljs
@@ -7039,6 +7039,9 @@ reduces them without incurring seq initialization"

 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Reference Types ;;;;;;;;;;;;;;;;

+(defprotocol IAtom
+  (-reset! [o new-value]))
+
 (deftype Atom [state meta validator watches]
   IEquiv
   (-equiv [o other] (identical? o other))
@@ -7088,14 +7091,16 @@ reduces them without incurring seq initialization"
   "Sets the value of atom to newval without regard for the
   current value. Returns newval."
   [a new-value]
+  (if (instance? Atom a)
     (let [validate (.-validator a)]
       (when-not (nil? validate)
-      (assert (validate new-value) "Validator rejected reference state")))
+        (assert (validate new-value) "Validator rejected reference state"))
       (let [old-value (.-state a)]
         (set! (.-state a) new-value)
         (when-not (nil? (.-watches a))
-      (-notify-watches a old-value new-value)))
-  new-value)
+          (-notify-watches a old-value new-value))
+        new-value))
+    (-reset! a new-value)))

 (defn swap!
   "Atomically swaps the value of atom to be:

这是在33692b79a114faf4bedc6d9ab38d25ce6ea4b295（或至少非常接近它）中提交的。然后其他协议更改在3e6564a72dc5e175fc65c9767364d05af34e4968中完成：

commit 3e6564a72dc5e175fc65c9767364d05af34e4968
Author: David Nolen <david.nolen@gmail.com>
Date:   Mon Feb 17 14:46:10 2014 -0500

    CLJS-760: break apart IAtom protocol into IReset & ISwap

diff --git a/src/cljs/cljs/core.cljs b/src/cljs/cljs/core.cljs
index 25858084..e4df4420 100644
--- a/src/cljs/cljs/core.cljs
+++ b/src/cljs/cljs/core.cljs
@@ -7061,9 +7061,12 @@ reduces them without incurring seq initialization"

 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Reference Types ;;;;;;;;;;;;;;;;

-(defprotocol IAtom
+(defprotocol IReset
   (-reset! [o new-value]))

+(defprotocol ISwap
+  (-swap! [o f] [o f a] [o f a b] [o f a b xs]))
+
 (deftype Atom [state meta validator watches]
   IEquiv
   (-equiv [o other] (identical? o other))
@@ -7124,21 +7127,33 @@ reduces them without incurring seq initialization"
         new-value))
     (-reset! a new-value)))

+;; generic to all refs
+;; (but currently hard-coded to atom!)
+(defn deref
+  [o]
+  (-deref o))
+
 (defn swap!
   "Atomically swaps the value of atom to be:
   (apply f current-value-of-atom args). Note that f may be called
   multiple times, and thus should be free of side effects.  Returns
   the value that was swapped in."
   ([a f]
-     (reset! a (f (.-state a))))
+     (if (instance? Atom a)
+       (reset! a (f (.-state a)))
+       (-swap! a (deref a))))
   ([a f x]
-     (reset! a (f (.-state a) x)))
+     (if (instance? Atom a)
+       (reset! a (f (.-state a) x))
+       (-swap! a (f (deref a) x))))
   ([a f x y]
-     (reset! a (f (.-state a) x y)))
-  ([a f x y z]
-     (reset! a (f (.-state a) x y z)))
-  ([a f x y z & more]
-     (reset! a (apply f (.-state a) x y z more))))
+     (if (instance? Atom a)
+       (reset! a (f (.-state a) x y))
+       (-swap! a (f (deref a) x y))))
+  ([a f x y & more]
+     (if (instance? Atom a)
+       (reset! a (apply f (.-state a) x y more))
+       (-swap! a (f (deref a) x y more)))))

 (defn compare-and-set!
   "Atomically sets the value of atom to newval if and only if the
@@ -7149,13 +7164,6 @@ reduces them without incurring seq initialization"
     (do (reset! a newval) true)
     false))

-;; generic to all refs
-;; (but currently hard-coded to atom!)
-
-(defn deref
-  [o]
-  (-deref o))
-
 (defn set-validator!
   "Sets the validator-fn for an atom. validator-fn must be nil or a
   side-effect-free fn of one argument, which will be passed the intended

票证是双重性质没有帮助：性能是一个问题（虽然不清楚以什么方式：“原子运行速度不够快”，或“使用重置的其他东西！运行速度不够快” ？）和设计问题（“我们想要一个IAtom协议”）。我认为问题是其他实现必须经受验证并通知观察者成本，即使它们不是真正的原子。我希望它更清楚。

我不喜欢Clojure / Script中提交的一件事是它们不是很具描述性。我希望他们更像内核，并提供适当的背景信息，这样人们（比如我们）试图弄清楚事情是如何产生更多有用的信息。

为什么ClojureScript原子没有实现完整的协议？

1 个答案: