Question

当程序员在设计师时间中打开表单时，我想要显示通知（例如ShowMessage）。
有可能吗？怎么样？
谢谢。

PS：Delphi XE7 / VCL

我有一个包含700多个表单的项目，但是当程序员打开一个特定的表单时，我希望得到一个通知（例如ShowMessage），说明例如，在开头的时候有评论。 .pas文件。

这应该以任何形式发生。

Answer 1

如果您想为任何表单执行此操作，可以采用直接方式执行此操作。（根据David Heffernan的评论，你的用户是否会感谢你另一件事，但无论如何......）

它涉及在IDE中安装一个包，该包安装一个实现IDesignNotification接口的对象。

要使用，请创建一个新表单并向其添加TMemo，将表单重命名为DesignNotifierForm，将其保存到磁盘，然后将下面的代码复制到其中。然后创建一个新包并将单元添加到它。然后编译并安装包。在像D7这样的旧版Delphi中，包编辑器中有一个安装按钮，而在像D10 Seattle这样的最新版本中，你会看到在IDE中的项目经理，然后右键单击弹出窗口中的BPL文件，并从弹出的上下文菜单中选择“安装”。

正如您所看到的，除了表单之外，该单元还声明了一个通知程序对象TDesignNotification，它实现了一个接口，以便可以向IDE设计者注册并从中接收通知。您的pov中唯一感兴趣的是DesignerOpened，您可以在其中调用ShowMessage或执行任何操作。

TDesignNotifierForm主要是作为一种简单的实验方法。观察TDesignNotification收到的通知，TDesignNotification可以在没有表单的情况下正常运行。

顺便说一句，您可能需要查看ToolsAPI.Pas单元，其中包含一系列可用于与IDE交互的接口。

unit DesignNotifierFormu;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, TypInfo, ToolsApi, DesignIntf;

type
  TDesignNotifierForm = class(TForm)
    Memo1: TMemo;
    Panel1: TPanel;
  private
  public
    procedure Log(const Title, Msg : String);
  end;

  TDesignNotification = class(TInterfacedObject, IDesignNotification)
    F : TDesignNotifierForm;
    procedure ItemDeleted(const ADesigner: IDesigner; AItem: TPersistent);
    procedure ItemInserted(const ADesigner: IDesigner; AItem: TPersistent);
    procedure ItemsModified(const ADesigner: IDesigner);
    procedure SelectionChanged(const ADesigner: IDesigner;
      const ASelection: IDesignerSelections);
    procedure DesignerOpened(const ADesigner: IDesigner; AResurrecting: Boolean);
    procedure DesignerClosed(const ADesigner: IDesigner; AGoingDormant: Boolean);
    constructor Create;
    destructor Destroy; override;
  end;

var
  DesignNotification : TDesignNotification;

implementation

{$R *.dfm}

procedure SetUp;
begin
  DesignNotification := TDesignNotification.Create;
  RegisterDesignNotification(DesignNotification);
end;

procedure TDesignNotifierForm.Log(const Title, Msg: String);
begin
  Memo1.Lines.Add(Title + ': ' + Msg);
end;

constructor TDesignNotification.Create;
begin
  inherited Create;
  F := TDesignNotifierForm.Create(Nil);
  F.Show;
  F.Log('Event', 'Notifier created');
end;

procedure TDesignNotification.DesignerClosed(const ADesigner: IDesigner;
  AGoingDormant: Boolean);
begin

end;

procedure TDesignNotification.DesignerOpened(const ADesigner: IDesigner;
  AResurrecting: Boolean);
var
  C : TComponent;
  Msg : String;
begin
  C := ADesigner.Root;
  if C <> Nil then begin
    Msg := C.ClassName;
    //  At this point, you can call ShowMessage or whatever you like
    ShowMessage(Msg);
  end
  else
    Msg := 'no root';
  F.Log('Designed Opened', Msg);
end;

destructor TDesignNotification.Destroy;
begin
  F.Close;
  F.Free;
  inherited;
end;

procedure TDesignNotification.ItemDeleted(const ADesigner: IDesigner;
  AItem: TPersistent);
begin

end;

procedure TDesignNotification.ItemInserted(const ADesigner: IDesigner;
  AItem: TPersistent);
begin

end;

procedure TDesignNotification.ItemsModified(const ADesigner: IDesigner);
begin

end;

procedure TDesignNotification.SelectionChanged(const ADesigner: IDesigner;
  const ASelection: IDesignerSelections);
begin
end;


initialization
  SetUp;
finalization
  if DesignNotification <> Nil then begin
    UnRegisterDesignNotification(DesignNotification);
    //  Evidently the following is superfluous and results in a double-free  DesignNotification.Free;
  end;
end.

我希望收到一条通知（例如ShowMessage），说明在.pas文件的开头有例如评论。

嗯，上面的代码向您展示了在打开表单时如何提供某种事件。如何在文件开头提取注释之类的东西确实是一个不同的技术问题，如果你遇到困难，应该在一个新问题中提出。

顺便说一句，你的q上的一条评论指向了Bob博士的代码片段方向。就显示技术而言，这很好，但如果你要在一个软件包中安装自己的表单，它只会做你想要的。

打开表单时的ShowMessage（设计师时间）

1 个答案: