Question

我正在尝试弄清楚如何在Delphi中的多个应用程序之间共享对象。我知道这样做的方法是通过IPC / windows共享内存调用（即CreateFileMapping等），但是在所有示例代码中我发现它们使用类似字符串的简单类型，而我需要共享一个对象。

我想知道它是否可能，因为我一直在用一个只分享对象的指针引用而不是对象内存本身的应用程序。当我尝试检索然后从我的其他应用程序访问该对象时，我得到访问冲突。我认为这是因为指针指的是来自其他应用程序的受保护内存。

这是我到目前为止尝试过的代码（正如您所看到的，我正在尝试在多个应用程序之间共享一个TADOConnection对象，以便在应用程序之间只使用/共享一个数据库连接）。如果有更好/更简单的方法（共享ADO连接），我很想知道如何做到这一点。

  TSharedData = record
    Connection: TAdoConnection;
  end;

  PSharedData = ^TSharedData;

var
  SharedData: PSharedData;
  hFileMapping: THandle;  
  Form1: TForm1;

implementation

{$R *.dfm}

function CreateNamedFileMapping(const Name: String): THandle;
begin
  Result := CreateFileMapping(INVALID_HANDLE_VALUE, nil, PAGE_READWRITE, 0,
    SizeOf(TSharedData)*8, PChar(Name));

  if Result > 0 then
    SharedData := MapViewOfFile(Result, FILE_MAP_ALL_ACCESS, 0, 0, 0);
end;

function GetSharedData: PSharedData;
begin
  result := nil;
  hFileMapping := OpenFileMapping(FILE_MAP_ALL_ACCESS, False, 'MySharedMemory');
  if (hFileMapping > 0) then
    Result := MapViewOfFile(hFileMapping, FILE_MAP_ALL_ACCESS, 0, 0, 0);
end;

procedure TForm1.createClick(Sender: TObject);
begin
   hFileMapping := CreateNamedFileMapping('MySharedMemory');
   if (hFileMapping > 0) and Assigned(SharedData) then
   begin
     SharedData^.Connection := TAdoConnection.Create(nil);
     // can't use Assign as it is not supported by _Connection
     SharedData^.Connection.ConnectionObject := AdoConnection1.ConnectionObject;
   end;
end;

procedure TForm1.retrieveClick(Sender: TObject);
begin
   SharedData := GetSharedData;
  if assigned(SharedData) then
    // should be set to true if everything was ok
    ShowMessage(BoolToStr( SharedData.Connection.Connected, true));
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
   AdoConnection1.Connected := False;

  if assigned(SharedData) then
    UnmapViewOfFile(SharedData);
  if hFileMapping > 0 then
    CloseHandle(hFileMapping);
end;


procedure TForm1.FormCreate(Sender: TObject);
begin
  AdoConnection1.Connected := true;
end;

end.

ADOConnection1是我表单上的一个对象。我知道我需要使用类似“分配”的东西来复制整个对象内存，但这在ADO ConnectionObject上不存在。为了确保它不仅仅是ConnectionObject的问题，我还尝试传递一个简单的对象，如TStringlist，然后使用assign来复制内存，但它仍然在app＃2中获取AV。

如果我在同一个应用程序中运行create and retrieve，它可以正常工作。当我获取此应用程序的副本并在应用程序＃1中运行“创建”功能并在应用程序＃2中“检索”时，我得到访问冲突。

Answer 1

在评论中已经确定不可能在不同进程之间共享对象。我稍微简化了你的测试用例，以便能够清楚为什么会这样。

在这个版本中，无法共享的对象比ADOConnection简单得多，ADOConnection只有一个整数字段。应用程序的第一个实例创建映射并写入具有整数，对象和字符串字段的记录。应用程序的任何后续实例都会尝试检索并显示该信息。

unit Unit1;

interface

uses
  Winapi.Windows, System.SysUtils, System.Classes,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

type
  TSimpleObject = class(TObject)
  private
    FInt: Integer;
  end;

  TSharedData = record
    Int: Integer;
    SimpleObject: TSimpleObject;
    Str: string;
  end;
  PSharedData = ^TSharedData;

var
  SharedData: PSharedData;
  hFileMapping: THandle;

const
  MapName = 'MySharedMemory';

procedure TForm1.FormCreate(Sender: TObject);
var
  MapExists: Boolean;
begin
  hFileMapping := CreateFileMapping(INVALID_HANDLE_VALUE, nil, PAGE_READWRITE,
      0, SizeOf(TSharedData), MapName);
  Win32Check(hFileMapping <> 0);
  MapExists := GetLastError = ERROR_ALREADY_EXISTS;

  SharedData := MapViewOfFile(hFileMapping, FILE_MAP_ALL_ACCESS, 0, 0, 0);
  Win32Check(SharedData <> nil);

  if MapExists then begin
    ShowMessage(IntToStr(SharedData.Int));
    ShowMessage(IntToStr(SharedData.SimpleObject.FInt));
    ShowMessage(SharedData.Str);
  end else begin
    SharedData.Int := 555;
    SharedData.SimpleObject := TSimpleObject.Create;
    SharedData.SimpleObject.FInt := 666;
    SharedData.Str := 'test string';
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Win32Check(CloseHandle(hFileMapping));
  Win32Check(UnmapViewOfFile(SharedData));
end;

应用程序的第二个实例将能够正确显示第一个值，即记录的整数字段。但是，它将失败，对象的整数字段或记录的字符串字段。它会引发访问冲突或显示不正确的值。

我在表格上放了一份备忘录并转储了一些内存地址，以便能够看到发生了什么。

procedure TForm1.FormCreate(Sender: TObject);
var
  MapExists: Boolean;
begin
  Memo1.Clear;
  hFileMapping := CreateFileMapping(INVALID_HANDLE_VALUE, nil, PAGE_READWRITE,
      0, SizeOf(TSharedData), MapName);
  Win32Check(hFileMapping <> 0);
  MapExists := GetLastError = ERROR_ALREADY_EXISTS;

  SharedData := MapViewOfFile(hFileMapping, FILE_MAP_ALL_ACCESS, 0, 0, 0);
  Win32Check(SharedData <> nil);

  if MapExists then begin
    Memo1.Lines.Add(Format('Found at %p', [SharedData]));
//    ShowMessage(IntToStr(SharedData.Int));
//    ShowMessage(IntToStr(SharedData.SimpleObject.FInt));
//    ShowMessage(SharedData.Str);
  end else begin
    Memo1.Lines.Add(Format('Created at %p', [SharedData]));
    SharedData.Int := 555;
    SharedData.SimpleObject := TSimpleObject.Create;
    SharedData.SimpleObject.FInt := 666;
    SharedData.Str := 'test string';
  end;
  Memo1.Lines.Add('');
  Memo1.Lines.Add(Format('@SharedData.Int: %p', [@SharedData.Int]));
  Memo1.Lines.Add(Format('PInteger(@SharedData.Int)^: %d', [PInteger(@SharedData.Int)^]));
  Memo1.Lines.Add('');
  Memo1.Lines.Add(Format('@SharedData.SimpleObject: %p', [@SharedData.SimpleObject]));
  Memo1.Lines.Add(Format('@SharedData.SimpleObject.FInt: %p', [@SharedData.SimpleObject.FInt]));
  Memo1.Lines.Add(Format('PInteger(@SharedData.SimpleObject.FInt)^: %d', [PInteger(@SharedData.SimpleObject.FInt)^]));
  Memo1.Lines.Add('');
  Memo1.Lines.Add(Format('Pointer(@SharedData.Str)^: %p', [Pointer(Pointer(@SharedData.Str)^)]));
  Memo1.Lines.Add('character payload');
  Memo1.Lines.Add('PChar(Pointer(SharedData.Str)): ' + PChar(Pointer(SharedData.Str)));
end;

下面，左边是应用程序的第一个实例，右边是第二个实例。请注意，第二个实例可能需要几次尝试才能显示没有访问冲突。

第一行是地图的起始地址。注意它们在两种情况下都不相同（但它们可能是相同的）。这对我们的案例没有任何顾虑，但是documentation of MapViewOfFile警告的原因是：

不要将指针存储在内存映射文件中;存储偏移量文件映射的基础，以便可以在任何地方使用映射地址。

第二行是共享记录的整数字段的地址。在这两种情况下，这等于映射内存的起始地址。这是预期的，因为它是记录的第一个字段。以下行将该地址中保存的值转储为整数，它们看起来很好。

第四行转储记录中包含的对象的地址。对于这两个实例，这是从地图开头偏移的四个字节。看起来对吗？继续使用以下行转储对象中包含的整数字段的地址。

类的整数字段的地址有两个令人担忧的事情。首先，它们在两种情况下都是相同的。这不应该是这种情况，因为地图文件根本不在相同的地址开始。其次，它们远离地图文件的地址。毕竟我们保留了12个字节，而不是34兆字节。

这样做的原因是，对象引用（具有在前一行中转储的地址）实际上是指向居住在其他地方的对象实例的指针，并且该指针指向映射的内存段之外的位置。这对于第一个实例来说不是问题，因为它是分配内存的进程。然而，对于第二个实例，该地址具有完全不同的含义。不管那个地址中没有对象，地址有可能甚至不可读。毫不奇怪，作为整数的转储值与预期值不同。

对于最后一段中转储的记录的字符串字段也是如此。字符串有效负载应该具有的地址与第二个进程具有完全不同的含义。

Assign无法帮助对象字段，它将指定源对象的属性和其他属性复制到当前对象，它不会重定位或复制一个对象的实例。但有人可能想知道是否可以创建具有在已知地址上定义的实例内存的对象，例如通过覆盖NewInstance。不幸的是，对于比这个例子中的对象稍微复杂一点的东西，这也是不可能的。不可能包含对象在单个内存块中运行所需的所有内存。例如，对于您尝试共享的ADOConnection，ConnectionObject是另一个指针。

在Delphi中共享多个应用程序之间的对象

1 个答案: