Question

在previous question我的this code of FsCheck Kurt指出here关于设置Arbitrary类型。

我有以下Arbitrary（免责声明：我不知道我在做什么......，仍然发现很难理解FsCheck，但我已经死定了它的工作），这本身就是是我之前创建的简化版本：

type MyArb() =
    inherit Arbitrary<DoNotSize<int64>>()
        override x.Generator = Arb.Default.DoNotSizeInt64().Generator

我按照指示使用它：

[<Property(Verbose = true, Arbitrary= [| typeof<MyArb> |])>]
static member  MultiplyIdentity (x: int64) = x * 1L = x

这给了我一个（有点希望的）错误消息，我错过了一些东西：

 System.Reflection.TargetInvocationException : Exception has been thrown by the target of an invocation.
  ----> System.Exception : No instances found on type Tests.Arithmetic.MyArb. Check that the type is public and has public static members with the right signature.
   at System.RuntimeMethodHandle.InvokeMethod(Object target, Object[] arguments, Signature sig, Boolean constructor)
   at System.Reflection.RuntimeMethodInfo.UnsafeInvokeInternal(Object obj, Object[] parameters, Object[] arguments)
   at System.Reflection.RuntimeMethodInfo.Invoke(Object obj, BindingFlags invokeAttr, Binder binder, Object[] parameters, CultureInfo culture)
   at FsCheck.Runner.checkMethod(Config config, MethodInfo m, FSharpOption`1 target) in C:\Users\Kurt\Projects\FsCheck\FsCheck\src\FsCheck\Runner.fs:line 318
   at FsCheck.NUnit.Addin.FsCheckTestMethod.runTestMethod(TestResult testResult) in C:\Users\Kurt\Projects\FsCheck\FsCheck\src\FsCheck.NUnit.Addin\FsCheckTestMethod.fs:line 100

回顾那个Github代码，我看到两个Atrbitrary类，但没有任何继承，它们都有不同的静态成员。

如何创建随机数生成器并将其作为静态任意分配给我的NUnit测试？

Answer 1

您在Property.Arbitrary参数中提供的类型应该包含类型为Arb的静态成员（可能是几个）。与您链接的代码一样：

type TestArbitrary2 =
   static member NegativeDouble() =
       Arb.Default.Float()
       |> Arb.mapFilter (abs >> ((-) 0.0)) (fun t -> t <= 0.0)

将此应用于您的代码，它应如下所示：

 type MyArb() =
    static member m() = Arb.Default.DoNotSizeInt64()

Property.Arbitrary参数的含义不是“任意实现”，而是“一堆类型类实现”。

你知道，QuickCheck的原始Haskell实现依赖于类型类来提供不同类型的值。为了使特定类型“可快速检查”，需要为该类型定义“任意”类的实例（例如，here are instances for all basic types）。

由于F＃不支持类型类，因此FsCheck必须伪造它，这是在那里使用的方案：每个类型类实例由返回函数表的静态成员表示。例如，如果我们想模拟Eq typeclass，我们将其定义为：

type Eq<'a> = { eq: 'a -> 'a -> bool; neq: 'a -> 'a -> bool }

type EqInstances() =
   static member ForInt() : Eq<int> = 
      { eq = (=); neq = (<>) }

   static member ForMyCustomType() : Eq<MyCustomType> = 
      { eq = fun a b -> a.CompareTo(b) = 0
        neq = fun a b -> a.CompareTo(b) <> 0 }

但是因为你不能只扫描所有加载的程序集中的所有静态成员（这会非常昂贵），所以显然提供类型有一点不便（作为奖励，它允许控制“实例”的可见性“）。

Answer 2

这个问题清楚地表明，IMO，为什么基于反射的FsCheck API不太理想。我倾向于完全避免使用该API，所以我改为编写OP属性，如下所示：

open FsCheck
open FsCheck.Xunit

[<Property>]
let MultiplyIdentity () =
    Arb.Default.DoNotSizeInt64 () |> Prop.forAll <| fun (DoNotSize x) -> x * 1L = x

正如open指令建议的那样，它使用FsCheck.Xunit而不是FsCheck.NUnit，但使用AFAIK，API的工作方式没有区别。

这种方法的优点在于它的类型安全并且更轻量级，因为每次需要调整FsCheck时都不必实现静态类。 / p>

Answer 3

如果您更喜欢the approach described by Mark Seemann，那么您也可以考虑使用plain-FsCheck并完全摆脱FsCheck.Xunit：

module Tests

open FsCheck

let [<Xunit.Fact>] ``Multiply Identity (passing)`` () = 
    Arb.Default.DoNotSizeInt64 ()
    |> Prop.forAll
    <| fun (DoNotSize x) ->
        x * 1L = x
    |> Check.QuickThrowOnFailure

let [<Xunit.Fact>] ``Multiply Identity (failing)`` () = 
    Arb.Default.DoNotSizeInt64 ()
    |> Prop.forAll
    <| fun (DoNotSize x) ->
        x * 1L = -1L |@ sprintf "(%A should equal %A)" (x * 1L) x
    |> Check.QuickThrowOnFailure

xUnit.net testrunner输出：

------ Test started: Assembly: Library1.dll ------

Test 'Tests.Multiply Identity (failing)' failed: System.Exception:
    Falsifiable, after 1 test (2 shrinks) (StdGen (2100552947,296238694)):

Label of failing property: (0L should equal 0L)
Original:
DoNotSize -23143L
Shrunk:
DoNotSize 0L

    at <StartupCode$FsCheck>.$Runner.get_throwingRunner@365-1.Invoke(String me..
    at <StartupCode$FsCheck>.$Runner.get_throwingRunner@355.FsCheck-IRunner-On..
    at FsCheck.Runner.check[a](Config config, a p)
    at FsCheck.Check.QuickThrowOnFailure[Testable](Testable property)
    C:\Users\Nikos\Desktop\Library1\Library1\Library1.fs(15,0): at Tests.Multi..

1 passed, 1 failed, 0 skipped, took 0.82 seconds (xUnit.net 2.1.0 build 3179).

将FsCheck与NUnit一起使用：使用任意类型接收异常（或：如何使用具有属性的任意类型）

3 个答案: