Question

我在Terraform中定义了AWS Auto-Scaling组，启动配置和Auto-Scaling组策略，如下所示：

resource "aws_autoscaling_group" "default" {
  name = "..."

  health_check_type = "EC2"
  vpc_zone_identifier = ["${...}"]

  min_size = "${var.asg_capacity}"
  max_size = "${var.asg_capacity * 2}"
  desired_capacity = "${var.asg_capacity}"

  launch_configuration = "${aws_launch_configuration.default.id}"

  termination_policies = ["OldestInstance"]
}

resource "aws_autoscaling_policy" "default" {
  name = "..."
  autoscaling_group_name = "${aws_autoscaling_group.default.name}"

  scaling_adjustment = "${var.asg_capacity}"
  adjustment_type = "ChangeInCapacity"
  cooldown = 300
}

resource "aws_launch_configuration" "default" {
  name_prefix = "..._"

  image_id = "${var.coreos_ami_id}"
  instance_type = "${var.ec2_instance_type}"
  iam_instance_profile = "${aws_iam_instance_profile.default.arn}"
  key_name = "..."

  security_groups = ["${aws_security_group.default.id}"]

  user_data = "${data.template_file.cloud_init.rendered}"

  lifecycle {
    create_before_destroy = true
  }
}

当我更改用户数据时，会创建一个新的启动配置，然后将其附加到自动缩放组。我认为这会导致自动缩放组按var.asg_capacity个实例向上扩展，等待300秒，然后按照OldestInstance拆除旧版本。

当我在CloudFormation中做过类似的事情时，我使用了the following configuration options：

ASG:
  Type: AWS::AutoScaling::AutoScalingGroup
  UpdatePolicy:
    AutoScaleRollingUpdate:
      # during a scale, 6 instances in service
      MaxBatchSize: 3
      MinInstancesInService: 3
      PauseTime: PT5M
  Properties:
    ...

Terraform中有这样的模拟吗？我真的希望在更改启动配置时更改自动缩放组。

Answer 1

我认为这会导致自动缩放组按var.asg_capacity实例扩展，等待300秒，然后根据OldestInstance拆除旧的。

遗憾的是，这种假设是不正确的。更改启动配置时，唯一发生的事情是在您的AWS账户中创建新的启动配置，并与Auto Scaling组（ASG）相关联。这意味着该ASG中的所有 future 实例将使用新的启动配置启动。但是，仅更改启动配置不会触发任何实例的启动，因此您将看不到您的更改。

要强制启动新实例，您必须执行以下操作：

配置ASG的name参数，使其直接依赖于启动配置的名称。这样，每次启动配置发生变化时（更新AMI或用户数据时），Terraform都会尝试更换ASG。
将ASG的create_before_destroy参数设置为true，因此每次Terraform尝试替换它时，都会在销毁原始文件之前创建替换。
将ASG的min_elb_capacity参数设置为群集的min_size，以便Terraform至少等待新ASG中的那么多服务器在ELB中注册，然后才会开始销毁最初的ASG。

以下是Terraform代码的粗略概念：

resource "aws_launch_configuration" "example" {
  image_id        = "${var.ami}"
  instance_type   = "${var.instance_type}"

  user_data = "${data.template_file.user_data.rendered}"

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_autoscaling_group" "example" {
  name                 = "${var.cluster_name}-${aws_launch_configuration.example.name}"
  launch_configuration = "${aws_launch_configuration.example.id}"
  availability_zones   = ["${data.aws_availability_zones.all.names}"]

  min_size         = "${var.min_size}"
  max_size         = "${var.max_size}"
  min_elb_capacity = "${var.min_size}"

  lifecycle {
    create_before_destroy = true
  }
}

要获得完整的示例，请查看书籍 zero-downtime deployment example code 中的Terraform: Up & Running。

Answer 2

从 AWS 配置程序 3.22.0 版开始，您可以向您的 aws_autoscaling_group 资源添加一个 instance_refresh 配置块。可能工作的最简单的配置是：

instance_refresh {
  strategy = "Rolling"
}

自动扩展组不会在启动配置更改时更新

2 个答案: