Question

我正在尝试在VB.net中使用DWORD WINAPI GetMessagePos(void)函数。

该函数返回一个DWORD（32位），可以存储在VB.net整数变量中。来自MSDN doc的引用：

x坐标是返回值的低阶;该 y坐标是高阶短（均代表有符号值）因为他们可以在具有多个系统的系统上采用负值监视器）

如何使用vb.net检索x和y坐标？

我正在尝试

<System.Runtime.InteropServices.DllImport("user32.dll", ExactSpelling:=True)>
Private Shared Function GetMessagePos() As Integer
End Function
Sub test()
    Dim pos As Integer = GetMessagePos()

    Try
        Dim x As Short = CShort(pos And &HFFFF)
        Dim y As Short = CShort(pos >> 16)

        MessageBox.Show(x & ", " & y)
    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try
End Sub

但我不确定这是否是正确的方法。我正在尝试做一些测试，比如

    Try
        Dim x As Short = -1
        Dim y As Short = 1

        Dim i As Int32 = (y << 16) Or x

        Dim x2 As Short = CShort(i And &HFFFF)
        Dim y2 As Short = CShort(i >> 16)

        MessageBox.Show(x & ", " & y)
    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try

基本上我在Short（Int16）变量中编码x和y坐标，将它们放在Int32中，然后尝试解码。
但它似乎没有用，因为它会导致溢出。

有关如何解码GetMessagePos() WINAPI的x-y坐标的任何想法吗？

Answer 1

提取这些值时必须小心，以确保它们在多监视器系统上正常工作。根据您通常在GetMessagePos函数中使用的内容，“标准”方法是在Windows SDK标头中定义的GET_X_LPARAM和GET_Y_LPARAM宏。这些在GetMessagePos documentation中有具体提及，并且在返回打包坐标的函数的所有文档中应该有类似的引用。还有一个警告是不要使用经典的LOWORD或HIWORD宏，因为它们会将值视为无符号数量，正如您在问题中所提到的那样。

因此，该任务主要是将GET_X_LPARAM和GET_Y_LPARAM宏从C转换为VB.NET。将它们翻译为C＃相对简单，因为您可以利用unchecked关键字：

int GetXValue(UInt32 lParam)
{
    return unchecked((short)(long)lParam);
}

int GetYValue(UInt32 lParam)
{
    return unchecked((short)((long)lParam >> 16));
}

但是VB.NET没有C＃的unchecked关键字的等价物，所以你必须找到其他方法来避免溢出。就个人而言，我在C＃中编写这种互操作代码并将其粘贴在库中，这样我就可以做到我认为最具可读性的内容。

如果您更喜欢坚持使用VB.NET，有几种方法可以做到这一点。最简单的概念是将值操作为UInt32以避免溢出。对于低位的x坐标，您需要明确屏蔽高位以避免溢出。对于y坐标，您需要移动和遮罩。然后，您可以转换回Short：

Public Function GetXValue(lParam As UInt32) As Short
    Return CShort(lParam And &HFFFF)
End Function

Public Function GetYValue(lParam As UInt32) As Short
    Return CShort((lParam >> 16) And &HFFFF)
End Function

另一种选择是更聪明，也许太聪明，但可能更有效率。它涉及声明等效的C风格联合，在VB.NET术语中它只是一个字段重叠的结构：

<StructLayout(LayoutKind.Explicit)> _
Public Structure CoordUnion

    <FieldOffset(0)> Public LParam As UInt32
    <FieldOffset(0)> Public XCoord As Short
    <FieldOffset(2)> Public YCoord As Short

    Public Sub New(lParam As UInt32)
        LParam = lParam
    End Sub

End Structure

然后你可以像这样使用它：

Dim temp As CoordUnion = New CoordUnion(GetMessagePos())
Dim pt As Point = New Point(temp.XCoord, temp.YCoord)
' ...

另请注意，我已隐式更改GetMessagePos的P / Invoke签名，以便返回UInt32：

<System.Runtime.InteropServices.DllImport("user32.dll", ExactSpelling:=True)>
Private Shared Function GetMessagePos() As UInt32
End Function

您可以像IntPtr类型一样轻松地在所有这些辅助/转换函数中使用UInt32类型。实际上，这就是你通常会写它的方式，因为你通常将这些指针坐标打包成lParam值作为窗口消息的一部分（例如，当覆盖{{1}时控制方法）。

VB.net整数和短转换，GetMessagePos（）

1 个答案: