创建图表的技巧

Question

我想以编程方式创建这样的图表 http://yaroslavvb.com/upload/junction-tree-decomposition.png

我想我应该将GraphPlot与VertexCoordinateRules，VertexRenderingFunction和EdgeRenderingFunction一起用于图形。我应该使用什么彩色斜面背景？

修改的 主要使用Simon的想法，这是一个简化的“不太健壮”的版本，我最终使用

Needs["GraphUtilities`"];
GraphPlotHighlight[edges_, verts_, color_] := Module[{},
  vpos = Position[VertexList[edges], Alternatives @@ verts];
  coords = Extract[GraphCoordinates[edges], vpos];
  (* add .002 because end-cap disappears when segments are almost colinear *)  
  AppendTo[coords, First[coords] + .002];
  Show[Graphics[{color, CapForm["Round"], JoinForm["Round"], 
     Thickness[.2], Line[coords], Polygon[coords]}],
   GraphPlot[edges], ImageSize -> 150]
  ]

SetOptions[GraphPlot, 
  VertexRenderingFunction -> ({White, EdgeForm[Black], Disk[#, .15], 
      Black, Text[#2, #1]} &), 
  EdgeRenderingFunction -> ({Black, Line[#]} &)];
edges = GraphData[{"Grid", {3, 3}}, "EdgeRules"];
colors = {LightBlue, LightGreen, LightRed, LightMagenta};
vsets = {{8, 5, 2}, {7, 5, 8}, {9, 6, 3}, {8, 1, 2}};
MapThread[GraphPlotHighlight[edges, #1, #2] &, {vsets, colors}]

http://yaroslavvb.com/upload/mathematica-graphs.png

Answer 1

将Samsdram的答案概括一点，我得到了

GraphPlotHighlight[edges:{((_->_)|{_->_,_})..},hl:{___}:{},opts:OptionsPattern[]]:=Module[{verts,coords,g,sub},
  verts=Flatten[edges/.Rule->List]//.{a___,b_,c___,b_,d___}:>{a,b,c,d};
  g=GraphPlot[edges,FilterRules[{opts}, Options[GraphPlot]]];
  coords=VertexCoordinateRules/.Cases[g,HoldPattern[VertexCoordinateRules->_],2];
  sub=Flatten[Position[verts,_?(MemberQ[hl,#]&)]];
  coords=coords[[sub]];     
  Show[Graphics[{OptionValue[HighlightColor],CapForm["Round"],JoinForm["Round"],Thickness[OptionValue[HighlightThickness]],Line[AppendTo[coords,First[coords]]],Polygon[coords]}],g]
]
Protect[HighlightColor,HighlightThickness];
Options[GraphPlotHighlight]=Join[Options[GraphPlot],{HighlightColor->LightBlue,HighlightThickness->.15}];

上面的一些代码可以更加健壮，但它可以工作：

GraphPlotHighlight[{b->c,a->b,c->a,e->c},{b,c,e},VertexLabeling->True,HighlightColor->LightRed,HighlightThickness->.1,VertexRenderingFunction -> ({White, EdgeForm[Black], Disk[#, .06], 
Black, Text[#2, #1]} &)]

---

编辑＃1： 可以在http://gist.github.com/663438

找到此代码的已清理版本 编辑＃2：编辑＃2： 如下面的评论所述，我的edges必须匹配的模式是带有可选标签的边缘规则列表。这比GraphPlot函数（以及上面gist中的版本）使用的内容略逊一筹，其中边缘规则也允许包含在Tooltip。

要查找GraphPlot使用的确切模式，我重复使用Unprotect[fn];ClearAttributes[fn,ReadProtected];Information[fn]，其中fn是感兴趣的对象，直到我发现它使用了以下（已清理）函数：

Network`GraphPlot`RuleListGraphQ[x_] := 
  ListQ[x] && Length[x] > 0 && 
    And@@Map[Head[#1] === Rule 
         || (ListQ[#1] && Length[#1] == 2 && Head[#1[[1]]] === Rule) 
         || (Head[#1] === Tooltip && Length[#1] == 2 && Head[#1[[1]]] === Rule)&, 
      x, {1}]

我认为我的edges:{((_ -> _) | (List|Tooltip)[_ -> _, _])..}模式相同且更简洁......

Answer 2

对于仅连接两个节点的简单示例（如最右侧的示例），您可以像这样绘制带有上限端点的线。

vertices = {a, b};
Coordinates = {{0, 0}, {1, 1}};
GraphPlot[{a -> b}, VertexLabeling -> True, 
 VertexCoordinateRules -> 
  MapThread[#1 -> #2 &, {vertices, Coordinates}], 
 Prolog -> {Blue, CapForm["Round"], Thickness[.1], Line[Coordinates]}]

对于更复杂的例子（如右边的第二个），我建议使用顶点坐标绘制多边形，然后用带帽线跟踪多边形的边缘。我找不到直接向多边形添加斜边的方法。跟踪多边形的周长时，需要将第一个顶点的坐标添加到线段的末尾，该线条构成多边形的完整周长。另外，CapForm行有两个单独的图形指令，它们指示是否斜切线的末端，而JoinForm指示是否斜切线的中间点。

vertices = {a, b, c};
Coordinates = {{0, 0}, {1, 1}, {1, -1}};
GraphPlot[{a -> b, b -> c, c -> a}, VertexLabeling -> True, 
 VertexCoordinateRules -> 
  MapThread[#1 -> #2 &, {vertices, Coordinates}], 
 Prolog -> {Blue, CapForm["Round"], JoinForm["Round"], Thickness[.15],
    Line[AppendTo[Coordinates, First[Coordinates]]], 
   Polygon[Coordinates]}]

Answer 3

JoinForm [“Round”]将围绕线段的连接。

您需要在彩色区域中的顶点中心周围填充多边形，然后使用JoinForm["Round"], ..., Line[{...}]来获得圆角。

考虑

foo = GraphPlot[{a -> b, a -> c, b -> d, b -> e, b -> f, c -> e, e -> f}, 
    VertexRenderingFunction -> 
    ({White, EdgeForm[Black], Disk[#, .1], Black, Text[#2, #1]} &)]
Show[
    Graphics[{
      RGBColor[0.6, 0.8, 1, 1],
      Polygon[foo[[1, 1, 1, 1, 1, {2, 5, 6, 2}]]],
      JoinForm["Round"], Thickness[0.2],
      Line[foo[[1, 1, 1, 1, 1, {2, 5, 6, 2}]]]
    }],
    foo
]

其中foo [[1,1,1,1,1]]是顶点中心列表，{2,5,6}拉出{b，e，f}顶点。 （{2,5,6,2}在起点处关闭线。）

有充足的美化空间，但我认为这涵盖了你上面没有提到的成分。