Question

我正在尝试根据订单日期（deliverydate等于订单日期后3天）找到计算交货日期的解决方案。但是，需要考虑周末。

<order>
   <orderdate>30/11/2016</orderdate>
</order>

因此，交货日期必须 05/12/2016 。

有没有人就此事提供任何帮助？

任何帮助总是受到赞赏！

Answer 1

将N个工作/工作日添加到纯XSLT 1.0中的日期

我犹豫是否要计算目标日期，还是使用递归。最后，我决定使用递归，因为这也是考虑假期的唯一方法。

输入XML

<orders>
    <order>
        <order-date>2016-11-21</order-date>
    </order>
    <order>
        <order-date>2016-11-22</order-date>
    </order>
    <order>
        <order-date>2016-11-23</order-date>
    </order>
    <order>
        <order-date>2016-11-24</order-date>
    </order>
    <order>
        <order-date>2016-11-25</order-date>
    </order>
    <order>
        <order-date>2016-11-26</order-date>
    </order>
    <order>
        <order-date>2016-11-27</order-date>
    </order>
</orders>

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="order">
    <xsl:copy>
        <xsl:copy-of select="order-date"/>
        <delivery-date>
            <xsl:call-template name="add-work-days">
                <xsl:with-param name="start-JDN">
                    <xsl:call-template name="JDN">
                        <xsl:with-param name="date" select="order-date" />
                    </xsl:call-template>
                </xsl:with-param>
                <xsl:with-param name="add-days" select="3" />
            </xsl:call-template>
        </delivery-date>
    </xsl:copy>
</xsl:template> 

<xsl:template name="add-work-days">
    <xsl:param name="start-JDN"/>
    <xsl:param name="add-days"/>

    <xsl:variable name="day-of-week" select="$start-JDN mod 7"/>
    <!--  Monday = 0 ... Saturday = 5, Sunday = 6 -->
    <xsl:choose>
        <xsl:when test="$day-of-week >= 5">
            <xsl:call-template name="add-work-days">
                <xsl:with-param name="start-JDN" select="$start-JDN + 1" />
                <xsl:with-param name="add-days" select="$add-days" />
            </xsl:call-template>
        </xsl:when>
        <xsl:when test="$add-days > 0">
            <xsl:call-template name="add-work-days">
                <xsl:with-param name="start-JDN" select="$start-JDN + 1" />
                <xsl:with-param name="add-days" select="$add-days - 1" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:call-template name="GD">
                <xsl:with-param name="JDN" select="$start-JDN" />
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template> 

<xsl:template name="JDN">
    <xsl:param name="date"/>
    <xsl:variable name="year" select="substring($date, 1, 4)"/>
    <xsl:variable name="month" select="substring($date, 6, 2)"/>
    <xsl:variable name="day" select="substring($date, 9, 2)"/>
    <xsl:variable name="a" select="floor((14 - $month) div 12)"/>
    <xsl:variable name="y" select="$year + 4800 - $a"/>
    <xsl:variable name="m" select="$month + 12*$a - 3"/>
    <xsl:value-of select="$day + floor((153*$m + 2) div 5) + 365*$y + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045" />
</xsl:template> 

<xsl:template name="GD">
    <xsl:param name="JDN"/>
    <xsl:variable name="f" select="$JDN + 1401 + floor((floor((4 * $JDN + 274277) div 146097) * 3) div 4) - 38"/>
    <xsl:variable name="e" select="4*$f + 3"/>
    <xsl:variable name="g" select="floor(($e mod 1461) div 4)"/>
    <xsl:variable name="h" select="5*$g + 2"/>
    <xsl:variable name="D" select="floor(($h mod 153) div 5 ) + 1"/>
    <xsl:variable name="M" select="(floor($h div 153) + 2) mod 12 + 1"/>
    <xsl:variable name="Y" select="floor($e div 1461) - 4716 + floor((14 - $M) div 12)"/>

    <xsl:value-of select="$Y" />    
    <xsl:value-of select="format-number($M, '-00')"/>
    <xsl:value-of select="format-number($D, '-00')"/>
</xsl:template>     

</xsl:stylesheet>

<强>结果

<?xml version="1.0" encoding="UTF-8"?>
<orders>
   <order>
      <order-date>2016-11-21</order-date>
      <delivery-date>2016-11-24</delivery-date>
   </order>
   <order>
      <order-date>2016-11-22</order-date>
      <delivery-date>2016-11-25</delivery-date>
   </order>
   <order>
      <order-date>2016-11-23</order-date>
      <delivery-date>2016-11-28</delivery-date>
   </order>
   <order>
      <order-date>2016-11-24</order-date>
      <delivery-date>2016-11-29</delivery-date>
   </order>
   <order>
      <order-date>2016-11-25</order-date>
      <delivery-date>2016-11-30</delivery-date>
   </order>
   <order>
      <order-date>2016-11-26</order-date>
      <delivery-date>2016-12-01</delivery-date>
   </order>
   <order>
      <order-date>2016-11-27</order-date>
      <delivery-date>2016-12-01</delivery-date>
   </order>
</orders>

注意：

为了使这个有用，我使用了标准的YYYY-MM-DD日期格式来输入和输出。如果您的输入使用其他格式，则必须调整JDN模板的开头，以便正确提取日期组件。如果您希望输出使用其他格式，则需要修改GD模板的末尾，以便按所需顺序组装最终日期。

根据订单日期计算交货日期，无需周末

1 个答案:

将N个工作/工作日添加到纯XSLT 1.0中的日期