Question

有没有办法可以显示所有解决方案和/或找到SICSTus prolog中有多少？例如，下面的代码可能用于解决地图着色问题。

:- use_module(library(clpfd)). 
solve_AUSTRALIA(WA,NT,Q,SA,NSW,V):-
   domain([WA,NT,Q,SA,NSW,V], 1, 4),%colours represented by integers from 1 to 4
   WA #\= NT, 
   WA #\= SA, 
   NT #\= SA, 
   NT #\= Q, 
   SA #\= Q, 
   SA #\= NSW, 
   SA #\= V, 
   Q #\= NSW,
   NSW #\= V,
   labeling([],[WA,NT,Q,SA,NSW,V]).

目前，我每次都要输入{{1}}以查看进一步的解决方案，直到Prolog说不。有没有办法告诉prolog一次显示所有解决方案，或者更好，我可以找到有多少解决方案。就像prolog告诉我这个问题有五个解决方案。

Answer 1

以下是计算答案数量。当您询问查询或执行谓词时，您从Prolog获得的内容就是答案。有时这些答案是解决方案，可能包含多个解决方案，无限多个解决方案，有时甚至根本没有解决方案。

最简单的方法是说findall(t, Goal_0, Ts), length(Ts, N)。唯一的缺点是，这需要的空间与计算的答案数量成正比。

如果你想更进一步，你需要某种柜台。目前在SICStus 4.3.3中你可以这样做：

:- meta_predicate count_answers(0, ?).
:- meta_predicate count_answers1(0, +, ?). % internal

:- use_module(library(types),[must_be/4]).

:- use_module(library(structs),
         [new/2,
          dispose/1,
          get_contents/3,
          put_contents/3]).

count_answers(G_0, N) :-
   (  nonvar(N)
   -> must_be(N, integer, count_answers(G_0, N), 2)
   ;  true
   ),
   new(unsigned_64, Ref),
   call_cleanup(count_answers1(G_0, Ref, N), dispose(Ref) ).

count_answers1(G_0, Ref, N) :-
   (  call(G_0),
      get_contents(Ref, contents, N0),
      N1 is N0+1,
      put_contents(Ref, contents, N1),
      fail
   ;  get_contents(Ref, contents, N)
   ).

请参阅this answer如何在其他系统中实施计数器。使用示例：

| ?- count_answers(member(_,"abcde"),Ans).
Ans = 5 ? ;
no

SICStus Prolog：查找所有解决方案

1 个答案: