Question

我对gnuplot很新，所以我很感谢你的每一个建议。

现在，我正在尝试使用logscale命令绘制一些数据。但是我不知道为什么当我使用logscale时所有的xtics都消失了。这是我使用的脚本：

#creates a plot of all the four different loops with a logscale. Fits the functions as well and saves the fitting data
#in a file named fitting.dat

set size 1,1
# set logscale
set logscale y 10
set logscale x 10
#set xlabel and y label
set xlabel "Dimension of Matrix"
set ylabel "time [s]"
#scale plot
set xrange [450:850]
set yrange[0.01:5]
#nothing displayed from fitting
set fit quiet
#position of legend
set key  top right
set key horizontal
# guessing the parameters, the fit will be better and we know that the exponent should be \approx 3
b=3
d=3
f=3
h=3
#Define all th four different data fitting functions, asuming f(x) ~  a*x^b
f(x)= a*x**b
g(x)=c*x**d
h(x)=e*x**f
j(x)=g*x**h

#fit the different functions
fit f(x) 'matmul.txt' using 1:2 via a,b
fit g(x) 'matmul.txt' using 1:3 via c,d
fit h(x) 'matmul.txt' using 1:4 via e,f
fit j(x) 'matmul.txt' using 1:5 via g,h
# save the fitting parameters in an extra file
set print 'fitting.dat'
    print 'function'
    print a,'*x', '**', b , '       rows'
    print c,'*x', '**', d , '       cols'
    print e,'*x', '**', f , '       intrinsic function'
    print g,'*x', '**', h , '       lapack routine'

# plot everything
plot    "matmul.txt" u 1:2 t "rows" ,\
    "matmul.txt"  u 1:3 t "cols" ,\
    "matmul.txt"  u 1:4 t "intrinsic" ,\
    "matmul.txt" u 1:5 t "lapack" ,\
    f(x) t sprintf("row:%.2e*x^(%.2f)", a,b),\
    g(x) t sprintf("col:%.2e*x^(%.2f)",c,d),\
    h(x) t sprintf("int:%.2e*x^(%.2f)",e,f),\
    j(x) t sprintf("lap:%.2e*x^(%.2f)",g,h)
 #choose output format
 set terminal png
 set output "time.png"
 replot
#now, non-logarithmic plot
#unset logscale
set yrange[0.01:1]
unset logscale
#plot again
plot    "matmul.txt" u 1:2 t "rows" ,\
    "matmul.txt"  u 1:3 t "cols" ,\
    "matmul.txt"  u 1:4 t "intrinsic" ,\
    "matmul.txt" u 1:5 t "lapack" ,\
    f(x) t sprintf("col:%.2e*x^(%.2f)", a,b),\
    g(x) t sprintf("row:%.2e*x^(%.2f)",c,d),\
    h(x) t sprintf("int:%.2e*x^(%.2f)",e,f),\
    j(x) t sprintf("lap%.2e*x^(%.2f)",g,h)

我的输入文件'matmul.txt'如下所示：

#Dim   rows       cols     intrinsic  lapack
500 0.1320E+00 0.1040E+00 0.6800E-01 0.2000E-01
520 0.1400E+00 0.1320E+00 0.5600E-01 0.2000E-01
540 0.1480E+00 0.1400E+00 0.6000E-01 0.3200E-01
560 0.1680E+00 0.1480E+00 0.7200E-01 0.2400E-01
580 0.1800E+00 0.1680E+00 0.6800E-01 0.3200E-01
600 0.1920E+00 0.1960E+00 0.7200E-01 0.3600E-01
620 0.2080E+00 0.2040E+00 0.9600E-01 0.2000E-01
640 0.4000E+00 0.3520E+00 0.8400E-01 0.3200E-01
...

现在，如果我运行此文件，我将获得以下输出plot

我不知道为什么，但是yscale的范围不正确，并且不显示xtics。如果我没有“logscale”绘制它，那么情节就是我想要的。为什么这不起作用？

Answer 1

您的x轴跨度不到十年，默认主要抽动频率为十年。如果您想在此范围内使用标记的抽搐，请使用set xtics (400,500,600,700,800)或任何您想要的颜色。

全部在documentation，只搜索“logscale”

Answer 2

对数图中的抽搐不是由常数加数分隔，如1,2,3，......，它们用常数因子分隔，如1,10,100，......

这意味着在您的情况下为y轴：您已经给出范围[0.01:5]，导致抽搐在0.01,0.1,1，如图所示。大于1，您在2,3,4和5处有次要抽搐.5是范围中指定的图形的上边界。要在此tic上添加标签，只需添加：

set ytics add (5)

或将yrange更改为

之一

set yrange [0.01:1]
set yrange [0.01:10]

对于你的xtics：标签将是1,10,100,1000，......但你的范围是450到850：里面没有标记的xtic。

同样，您可以手动设置它们：

set xtics (450, 550, 650, 750, 850)

使用logscale时gnuplot xtics消失

2 个答案: