Question

（这是我的第一篇文章，对不起，如果我做错了什么......）

我正在Vala写一个可以设计课堂的程序。我决定使用GTK作为GUI（Vala与此集成很好），和开罗画教室图（默认情况下GTK附带）。

我创建了一个教室＆＃39; class（Gtk.DrawingArea的子类），目前应该只显示一个正方形：

public class Classroom : DrawingArea
{
    private delegate void DrawMethod();

    public Classroom()
    {
        this.draw.connect((widget, context) => {
            return draw_class(widget, context, context.stroke);
            });
    }

    bool draw_class(Widget widget, Context context, DrawMethod draw_method)
    {
        context.set_source_rgb(0, 0, 0);
        context.set_line_width(8);
        context.set_line_join (LineJoin.ROUND);

        context.save();

        context.new_path();
        context.move_to(10, 10);
        context.line_to(30, 10);
        context.line_to(30, 30);
        context.line_to(10, 30);
        context.line_to(10, 10);
        context.close_path();

        draw_method();  // Actually draw the lines in the buffer to the widget

        context.restore();

        return true;
    }
}

我还为我的应用程序创建了一个类：

public class SeatingPlanApp : Gtk.Application
{
    protected override void activate ()
    {
        var root = new Gtk.ApplicationWindow(this);
        root.title = "Seating Plan";
        root.set_border_width(12);
        root.destroy.connect(Gtk.main_quit);

        var grid = new Gtk.Grid();
        root.add(grid);

        /* Make our classroom area */
        var classroom = new Classroom();
        grid.attach(classroom, 0, 0, 1, 1);
        //root.add(classroom);

        root.show_all();
    }

    public SeatingPlanApp()
    {
        Object(application_id : "com.github.albert-tomanek.SeatingPlan");
    }
}

这是我的主要功能：

int main (string[] args)
{
    return new SeatingPlanApp().run(args);
}

我将classroom窗口小部件放入Gtk.Grid，我选择的布局窗口小部件。当我编译代码并运行它时，我得到一个空白窗口：

但是，如果我不使用Gtk.Grid，只使用classroom（我已注释掉）添加root.add()，则classroom窗口小部件会正确显示：

为什么我的小部件在使用Gtk.Grid添加时不显示？

我该怎么做才能解决这个问题？

Answer 1

问题是单元格大小为0x0像素，因为网格不知道绘图区域实际需要多少空间。

一个简单的解决方案就是请求一些固定大小，试试这个：

var classroom = new Classroom();
classroom.set_size_request (40, 40);

PS：我通过查看关于SO的其他类似问题得到了这个想法，尤其是this one。

附加到Gtk.Grid时，Gtk.DrawingArea为空

1 个答案: