Question

我正在尝试通过添加默认属性值来自定义现有XSLT模板（如果缺少）。原始模板来自第三方，最好不要被触及。下面是代码来说明我想要实现的目标。任何帮助将不胜感激。

要转换的示例xml文件：

<?xml version="1.0" encoding="UTF-8"?>
<images>
   <image href="https://cityyearnh.files.wordpress.com/2011/02/boat.jpg" width="300" />
   <image href="https://cityyearnh.files.wordpress.com/2011/02/boat.jpg"/>
</images>

请注意，xml文件中有2个图像，一个带有@width属性，另一个没有。如果未定义@width，则下面的XLST文件不会在输出html文件中添加width属性。

现有的XSLT文件

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
    <html><body>
       <h2>My Images</h2>
       <xsl:apply-templates select="images/image" />
    </body></html>
</xsl:template>

<xsl:template name="img_template" match="images/image">
    <xsl:text>&#10;</xsl:text>
    <img>
    <xsl:apply-templates select="@href|@width" />
    </img>
    <br />
</xsl:template>

<xsl:template match="/images/image/@href">
    <xsl:attribute name="src"><xsl:value-of select="." /></xsl:attribute>
</xsl:template>

<xsl:template match="/images/image/@width">
    <xsl:attribute name="width"><xsl:value-of select="." /></xsl:attribute>
</xsl:template>

当未定义@width时，我想在输出html文件中添加50％的width属性。我可以修改原始的img_template来实现我想要的，例如，

<xsl:template name="img_template" match="images/image">
    <xsl:text>&#10;</xsl:text>
    <img>
       <xsl:apply-templates select="@href" />
       <xsl:if test="@width">
          <xsl:apply-templates select="@width" />
       </xsl:if>
       <xsl:if test="not(@width)">
          <xsl:attribute name="width">50%</xsl:attribute>
       </xsl:if>
    </img>
    <br />
</xsl:template>

但是，修改原始模板并不是一个好主意。有没有办法调用原始模板并添加一些额外的处理？

我试图添加一个调用原始的覆盖模板，并以某种方式添加默认的宽度属性（但我不知道如何）。到目前为止我的代码：

 <xsl:template match="images/image">
    <xsl:if test="@width">
       <xsl:call-template name="img_template" />
    </xsl:if>
    <xsl:if test="not(@width)">
       <p>Below image has no width attribute set. Add 50% width somehow ?</p>
       <xsl:call-template name="img_template" />
    </xsl:if>
 </xsl:template>

非常感谢任何帮助/建议。

Answer 1

修改原始模板不是一个好主意。

为什么不呢？我会将样式表重写为：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/images">
    <html>
        <body>
            <h2>My Images</h2>
            <xsl:apply-templates select="image" />
        </body>
    </html>
</xsl:template>

<xsl:template match="image">
    <img src="{@href}" width="50%">
        <xsl:apply-templates select="@width" />
    </img>
    <br/>
</xsl:template>

<xsl:template match="@width">
    <xsl:attribute name="width">
        <xsl:value-of select="." />
    </xsl:attribute>
</xsl:template>

</xsl:stylesheet>

这会为每个图像分配一个width属性，其默认值为50％。如果图像具有自己的width属性，则将使用它覆盖默认值。

或者，您可以这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/images">
    <html>
        <body>
            <h2>My Images</h2>
            <xsl:apply-templates select="image" />
        </body>
    </html>
</xsl:template>

<xsl:template match="image">
    <img src="{@href}">
        <xsl:attribute name="width">
            <xsl:choose>
                <xsl:when test="@width">
                    <xsl:value-of select="@width" />
                </xsl:when>
                <xsl:otherwise>50%</xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
    </img>
    <br/>
</xsl:template>

</xsl:stylesheet>

这可能更详细，但非常清楚。

加了：

不幸的是，原始的XSLT文件很复杂，并且是其中的一部分一个软件包。我们不打算修改那里的任何文件维修原因。有没有办法实现我想要的东西使用“覆盖”？

是的，您可以添加以下模板：

<xsl:template match="image[not(@width)]" priority="1">
    <img src="{@href}" width="50%"/>
    <br/>
</xsl:template>

Answer 2

我最近一直在处理一个类似的案例，我正在调用一个将其输出放在命名空间中的库样式表，我希望它不在命名空间中。这意味着要覆盖很多代码。因此，我在变量中捕获了现有样式表的输出，并对其进行了转换。

类似的东西：

<xsl:template match="image">
  <xsl:variable name="temp">
    <xsl:apply-imports/>
  </xsl:variable>
  .. now process $temp e.g. to add missing attributes
</xsl:template>

Answer 3

根据@MichaelKey的建议，我制定了以下解决方案：

XSLT 2.0

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:include href="original.xsl" />

<xsl:template match="images/image[not(@width)]">
    <xsl:variable name="old_content">
        <xsl:call-template name="img_template" />
    </xsl:variable>
    <xsl:call-template name="re-generate">
        <xsl:with-param name="oldcontent" select="$old_content"/>
    </xsl:call-template>
</xsl:template>
<xsl:template name="re-generate">
    <xsl:param name="oldcontent" />
    <img width="50%">
       <xsl:copy-of select="$oldcontent/img/@*" />
    </img>
    <xsl:copy-of select="$oldcontent/*[not(self::img)]" />
</xsl:template>
</xsl:stylesheet>

在上面，我假设原始模板在文件original.xsl中。此外，img_template生成的第一个节点被假定为img。对于更复杂的处理，传递给java函数是理想的。

XSLT如何在不更改现有模板的情况下将属性添加到现有模板中

3 个答案:

加了：