Question

我有这种表，如果看起来它代表产品的规格

其中第1列是SKU并且作为ID和第2列我们的规格说明书标题，值和0或1作为可选参数（如果错过，则默认为1）由＆＃34;〜＆＃34;和ech选项由^

分开

我想将其拆分为带SKU的表格，每个规格标题为列标题和值，因为它的值

我设法编写此代码，将其拆分为具有潜水规格的记录，并将每个规格和记录的标题与值分开，以及如何寻求帮助

    let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    Type = Table.TransformColumnTypes(Source,{{"Part Number", type text}, {"Specifications", type text}}),
    #"Replaced Value" = Table.ReplaceValue(Type,"Specification##","",Replacer.ReplaceText,{"Specifications"}),
    SplitByDelimiter = (table, column, delimiter) => 
        let 
            Count = List.Count(List.Select(Text.ToList(Table.Column(table, column){0}), each _ = delimiter)) + 1, 
            Names = List.Transform(List.Numbers(1, Count), each column & "." & Text.From(_)), 
            Types = List.Transform(Names, each {_, type text}), 
            Split = Table.SplitColumn(table, column, Splitter.SplitTextByDelimiter(delimiter), Names), 
            Typed = Table.TransformColumnTypes(Split, Types) 
        in 
            Typed, 
    Split = SplitByDelimiter(#"Replaced Value","Specifications","^"),
    Record = Table.ToRecords(Split)
in
    Record

Answer 1

好的，我希望你还需要这个，就像整个晚上一样。 :)）我必须说，这是一项非常有趣的任务！

我认为“~1”总是与“^”组合，所以“~1 ^”总是结束字段的值。我还假设值中没有“：”，因为所有冒号都被移除。

IMO，你根本不需要使用Table.SplitColumn函数。

let 
    //replace it with your Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    Source = #table(type table [Part Number = Int64.Type, Specifications = text], {{104, "Model:~104~1^Type:~Watch~1^Metal Type~Steel~1"}, {105, "Model:~105~1^Type:~Watch~1^Metal Type~Titanium~1^Gem Type~Ruby~1"}}),

    //I don't know why do you replace these values, do you really need this?
    ReplacedValue = Table.ReplaceValue(Source,"Specification##","",Replacer.ReplaceText,{"Specifications"}),
    TransformToLists = Table.TransformColumns(Source, {"Specifications", each List.Transform(List.Select(Text.Split(_ & "^", "~1^"), each _ <> "") , each Text.Split(Text.Replace(_, ":", ""), "~"))  } ),
    ConvertToTable = Table.TransformColumns(TransformToLists, {"Specifications", each Table.PromoteHeaders(Table.FromColumns(_))}),
    ExpandedSpecs = Table.TransformRows(ConvertToTable, (x) => Table.ExpandTableColumn(Table.FromRecords({x}), "Specifications", Table.ColumnNames(x[Specifications])) ),
    UnionTables = Table.Combine(ExpandedSpecs),
    Output = UnionTables
in
    Output

<强>更新

工作原理（跳过明显的步骤）：

TransformToLists ：TransformColumns获取表格，以及应用于此列值的列名称和函数列表。所以它将几个嵌套函数应用于每行“规范”字段的值。这些函数执行以下操作：List.Select返回非空值的列表，按顺序通过将Text.Split函数应用于已移除“：”的“规范”字段的值获得：

   Text.Split(
              Text.Replace(_, ":", "")
              , "~")

每个关键字表示以下函数应用于每个已处理的值（可以是字段，列，行/记录，列表项，文本，函数等），用下划线符号表示。这个下划线可以用函数替换：

  each _ equals (x) => some_function_that_returns_corresponding_value(x)

所以，

  each Text.Replace(_, ":", "") 
      equals 
  (x) => Text.Replace(x, ":", "") //where x is any variable name. 

  //You can go further and make it typed, although generally it is not needed:
  (x as text) => Text.Replace(x, ":", "") 

  //You can also write a custom function and use it:
  (x as text) => CustomFunctionName(x)

说完， TransformToLists 步骤返回一个包含两列的表：“部件号”和“规格”，包含列表列表。每个列表都有两个值：列名称及其值。发生这种情况是因为“规格”字段中的初始值必须拆分两次：首先将它拆分为“~1 ^”对，然后将每对拆分为“〜”。所以现在我们在每个嵌套列表中都有列名及其值，现在我们必须将它们全部转换为单个表。

ConvertToTable ：我们再次应用TransformColumns，为每行的“规格”字段使用一个函数（请记住，列表列表）。我们使用Table.FromColumns，因为它将列表列表作为参数，并返回一个表，其中第一行是列标题，第二行是它们的值。然后我们将第1行提升为标题。现在我们有一个表，“Specifications”字段包含具有可变列数的嵌套表。我们必须把它们放在一起。

ExpandedSpecs ：Table.TransformRows将转换函数应用于表中的每一行（作为记录）（在代码中它被签名为 x ）。您可以像我一样编写自定义函数：

= Table.ExpandTableColumn( //this function expands nested table. It needs a table, but "x" that we have is a record. So we do the conversion:
    Table.FromRecords({x}) //function takes a list of records, so {x} means a list with single value of x
    , "Specifications" //Column to expand
    , Table.ColumnNames(x[Specifications]) //3rd argument is a list of resulting columns. It takes table as an argument, and table is contained within "Specifications" field.
 )

它返回一个表列表（每行有一行），我们使用Table.Combine在 UnionTables 步骤中将它们组合在一起。这会产生一个包含组合表中所有列的表，如果某些列中没有这样的列，则为空。

希望它有所帮助。：）

Answer 2

如果我理解您的要求MSDN for Range.TextToColumns

，则TextToColumns VBA解决方案会简单得多

表格列按值拆分为其他列及其值

2 个答案: