Question

首先，对于无法准确说出我的问题而道歉！

我面临的问题是我有一个包含4个类的数组列表完全相同的事情，只是需要在不同的时间调用它们（当第一个坐标超过某个值时）但我很难得到它完成了，并且无法在网上找到它（可能是因为我无法准确地说出我的问题：/）无论如何我会在下面发布我的代码，如果有人能说清楚，我将非常感激！

**通过将屏幕中心与每个角线连接起来，我所做的是隧道效应，现在我试图模拟通过从屏幕中间朝向边缘的起始线移动（从底部开始））**

    speedLines sline1, sline2, sline3, sline4;

// holds speedLines classes
ArrayList<speedLines> gameObject;

void setup() {
  background(0);
  size(750, 750);
  smooth();

  gameObject = new ArrayList<speedLines>();

  sline1 = new speedLines(height/2);
  sline2 = new speedLines(height/8);
  sline3 = new speedLines(height/4);
  sline4 = new speedLines((height/2)*3);

  gameObject.add(sline1);
  gameObject.add(sline2);
  gameObject.add(sline3);
  gameObject.add(sline4);
}

void draw() {
  background(0);
  for(int i=0; i< gameObject.size(); i++){

    // go through the different classes
    // 2 added so far
    gameObject.get(i).display();

  }
  Guidelines();
}
//GLOBAL VARIABLES
int line=0;
int linewidth=0;




void Guidelines() {
  stroke(255);
  //MAIN GUIDE
  line(0, 0, width/2, height/2);//top left guide
  line(width, 0, width/2, height/2);//top right guide
  line(0, height, width/2, height/2);//bottom left guide
  line(width, height, width/2, height/2);//bottom right guide
  //SUB GUIDE
  stroke(60, 60, 60);
  line(width/3, height, width/2, height/2);//sub guide left
  line((width/3)*2, height, width/2, height/2);//sub guide right
}
class speedLines {
  //Global variables
  int Y;

  speedLines(int y) {
  }

  void display() {
    stroke(60, 60, 60);
    line((width/2)-linewidth, (height/2)+line, (width/2)+linewidth, (height/2)+line);
    line++;
    linewidth++;
    if ((height/2)+line >= height)
    {
      line=0;
      linewidth=0;
    }
  }
}

Answer 1

如果我是你，我会尝试将其缩小到一个较小的示例草图。我还尝试稍微清理一下您的代码：当您将它们放入sline时，是否有原因导致草图级ArrayList变量？

话虽这么说，我会尽力帮忙。您将一个参数传递给speedLines类（实际上应该称为SpeedLine，因为类应该以大写字母开头，每个实例只代表一行）构造函数，但是你＆＃ 39;永远不要使用该参数。试着让它只使用一个实例，如下所示：

Line myLine;

void setup() {
  size(100, 500);
  myLine = new Line(height/2);
}

void draw() {
  background(200);
  myLine.move();
  myLine.render();
}

class Line {
  float lineY;

  public Line(float lineY) {
    this.lineY = lineY;
  }

  public void move() {
    lineY++;
    if (lineY > height) {
      lineY = 0;
    }
  }

  public void render() {
    line(0, lineY, width, lineY);
  }
}

注意我实际上是如何使用我传递到lineY构造函数中的Line变量。尝试在代码中使用这样的东西。然后，您可以更轻松地使用ArrayList绘制多行：

ArrayList<Line> myLines = new ArrayList<Line>();

void setup() {
  size(100, 500);
  for (float lineY = 0; lineY < height; lineY += 100) {
    myLines.add(new Line(lineY));
  }
}

void draw() {
  background(200);

  for (Line myLine : myLines) {
    myLine.move();
    myLine.render();
  }
}

class Line {
  float lineY;

  public Line(float lineY) {
    this.lineY = lineY;
  }

  public void move() {
    lineY++;
    if (lineY > height) {
      lineY = 0;
    }
  }

  public void render() {
    line(0, lineY, width, lineY);
  }
}

另请注意，您只能在班级中使用单个值（在我的示例中为lineY变量）。所以你可能真的不需要上课来做这件事。您可以使用仅包含float值的lineY值数组来执行此操作：

float[] lineY = new float[10];

void setup() {
  size(100, 500);
  for (int i = 0; i < lineY.length; i++) {
    lineY[i] = i * 10;
  }
}

void draw() {
  background(200);

  for (int i = 0; i < lineY.length; i++) {
    lineY[i]++;
    if (lineY[i] > height) {
      lineY[i] = 0;
    }
    line(0, lineY[i], width, lineY[i]);
  }
}

请注意，所有这些只是示例，您必须采用这些示例并了解他们正在做什么，然后在您的代码中执行类似的操作。祝你好运。

无法在不同时间调用课程

1 个答案: