Question

我已经浏览了几个与此问题相关的链接，其中一个链接如下： https://github.com/jennybc/send-email-with-r

此链接非常有助于创建mimes，设置邮件和发送邮件。但是，我正在寻找更多的东西，所以我发布了这个问题。

我有一个带徽标（PNG）文件和一些JPEG文件的文件夹。我还有一个MS excel名单，电子邮件地址和一个叫收据号码的字段列表。 JPEG文件根据收据编号命名。如何使用'gmailr'包将徽标和电子邮件正文中的一些文本包含在内？此外，我想将JPEG图像与每个收据编号相匹配，并将文件附加到相应的邮件中。

我是Stack Overflow的新手，因此请原谅我在问题中的任何错误。任何帮助将不胜感激。

Answer 1

我不知道如何在R中执行此操作，但如果您使用的是Excel，并且听起来像是这样，那么您可以在Excel中完成所有这些操作。只需按照以下说明操作即可。

实施例

Make a list in Sheets("Sheet1") with :

In column A : Names of the people
In column B : E-mail addresses
In column C:Z : Filenames like this C:\Data\Book2.xls (don't have to be Excel files)

宏将遍历＆＃34; Sheet1＆＃34;中的每一行。如果B栏中有电子邮件地址和C列中的文件名：Z它将创建一个包含此信息的邮件并发送。

Sub Send_Files()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim OutApp As Object
    Dim OutMail As Object
    Dim sh As Worksheet
    Dim cell As Range
    Dim FileCell As Range
    Dim rng As Range

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set sh = Sheets("Sheet1")

    Set OutApp = CreateObject("Outlook.Application")

    For Each cell In sh.Columns("B").Cells.SpecialCells(xlCellTypeConstants)

        'Enter the path/file names in the C:Z column in each row
        Set rng = sh.Cells(cell.Row, 1).Range("C1:Z1")

        If cell.Value Like "?*@?*.?*" And _
           Application.WorksheetFunction.CountA(rng) > 0 Then
            Set OutMail = OutApp.CreateItem(0)

            With OutMail
                .to = cell.Value
                .Subject = "Testfile"
                .Body = "Hi " & cell.Offset(0, -1).Value

                For Each FileCell In rng.SpecialCells(xlCellTypeConstants)
                    If Trim(FileCell) <> "" Then
                        If Dir(FileCell.Value) <> "" Then
                            .Attachments.Add FileCell.Value
                        End If
                    End If
                Next FileCell

                .Send  'Or use .Display
            End With

            Set OutMail = Nothing
        End If
    Next cell

    Set OutApp = Nothing
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

如何使用gmailr将文件动态附加到电子邮件中？

1 个答案: