创建新图层

Question

我需要在Yocto构建的目标操作系统上运行脚本。

此脚本需要作为安装的一部分运行，因此必须只运行一次（在整个操作系统安装之后或首次启动时）。它不能在主机系统上运行，因为它取决于仅存在于目标上的硬件IO。

另一个小的约束是rootfs是以只读方式挂载的，但我想这可以通过将脚本重新挂载为rw并在执行后再次重新挂载为r或沿着这些行的某些内容来避免。< / p>

感谢任何帮助。

Answer 1

我最终做了shibley所写的内容。这是一个详细的方法：

创建新图层

将所需图层放在其他图层所在的位置。我的目标位于stuff目录中，位于构建目录旁边。

制作以下文件/目录：

meta_mylayer
├── conf
│   └── layer.conf
└── recipes-core
    └── mylayer-initscript
        ├── initscript.bb
        └── files
            ├── initscript.service
            └── initscript.sh

meta_mylayer是新图层的名称。

让我们在conf/layer.conf中定义图层并告诉它在哪里搜索食谱：

BBPATH .= ":${LAYERDIR}"
BBFILES += "${LAYERDIR}/recipes-*/*/*.bb ${LAYERDIR}/recipes-*/*/*.bbappend"
BBFILE_COLLECTIONS += "meta-mylayer"
BBFILE_PATTERN_meta-mylayer := "^${LAYERDIR}/"
BBFILE_PRIORITY_meta-mylayer = "99"

配方由.bb文件的名称定义。该图层只有一个名为 initscript 的配方。

initscript.bb包含食谱信息。以下配方将添加我们的initscript服务，并将实际安装脚本initscript.sh放入/usr/sbin/

SUMMARY = "Initial boot script"
DESCRIPTION = "Script to do any first boot init, started as a systemd service which removes itself once finished"
LICENSE = "CLOSED"
PR = "r3"

SRC_URI =  " \
    file://initscript.sh \
    file://initscript.service \
"

do_compile () {
}

do_install () {
    install -d ${D}/${sbindir}
    install -m 0755 ${WORKDIR}/initscript.sh ${D}/${sbindir}

    install -d ${D}${systemd_unitdir}/system/
    install -m 0644 ${WORKDIR}/initscript.service ${D}${systemd_unitdir}/system
}

NATIVE_SYSTEMD_SUPPORT = "1"
SYSTEMD_PACKAGES = "${PN}"
SYSTEMD_SERVICE_${PN} = "initscript.service"

inherit allarch systemd

install -d将创建指定路径所需的任何目录，而install -m 0644将以644权限复制指定的文件。 ${D}是目标目录，默认情况下为${WORKDIR}/image

创建systemd服务定义

我不会详细介绍systemd的工作原理，而是粘贴服务定义：

[Unit]
Description=start initscript upon first boot

[Service]
Type=simple
ExecStart=/bin/sh -c 'sleep 5 ; /usr/sbin/initscript.sh'

请注意/usr/sbin/处的脚本位置 - 这是我们do_install函数的最后一行复制的位置。

最后，我们的initscript.sh脚本本身：

#!/bin/sh

logger "starting initscript"

# do some work here. Mount rootfs as rw if needed.

logger "initscript work done"

#job done, remove it from systemd services
systemctl disable initscript.service

logger "initscript disabled"

注册图层

我们需要注册我们的新图层，以便bitbake知道它在那里。编辑build/conf/bblayers.conf文件并将以下行添加到BASELAYERS变量：

  ${TOPDIR}/../stuff/meta-mylayer \

现在bitbake识别我们的图层，我们需要将我们的配方添加到图像中。编辑build/conf/local.conf并将initscript配方添加到IMAGE_INSTALL_append变量。以下是在python旁边添加时的样子。

IMAGE_INSTALL_append = " python initscript"

运行构建

像往常一样运行构建。例如：

bitbake angstrom-lxde-image

首次安装构建和启动后，您的initscript.sh将被执行。

Answer 2

基本方法是编写systemd服务。默认情况下，可以按照yocto recipe systemd配置中的定义启用该服务。服务引发的脚本或应用程序将在脚本/应用程序完成时禁用该服务 - 即。 systemctl disable foo。因此，该服务将来不会运行。

正如您所提到的，rootfs将需要安装为rw才能工作。

Answer 3

谢谢，这有所帮助。我需要添加

[Install] WantedBy=multi-user.target

到initscript.service以使其正常工作

Answer 4

一个简单的解决方案是使用一个包发布/安装脚本，该脚本在rootfs时停止运行（如果设置了$ D，则退出1）。这将导致它在首次启动时运行。是的，脚本需要重新安装root fs。

Answer 5

另外，我不知道如何解决rootfs挂载为只读的问题，你可以使用pkg_postinst_ontarget_${PN}

将此添加到您的食谱之一：

pkg_postinst_ontarget_${PN}() {
    #!/bin/bash
    // bash script you want to run
    echo Post Install Script Test > /dev/ttyS1
}

${PN} 将替换为配方对应的包名。
该脚本将只运行一次，在目标机器上第一次启动时作为包的安装后脚本。

在Yocto构建的Linux

5 个答案:

创建新图层

创建systemd服务定义

注册图层

运行构建