QT 5.7 QML快速半透明矩形，一面有圆角

Question

我想要一个使用Qt Quick QML的半透明矩形形状，但仅在一侧有圆角。

这是我想要的矩形的形状。如果它没有通过，我可能只是重叠2个矩形，一个圆角，一个没有。但是，这与透明度无关，因为重叠变得更暗。

     ----------|
   /           |
 /             | 
|              |
|              |
|              |
 \             | 
   \           |   
     ----------|

有人有什么想法吗？

Answer 1

您可以使用clipping（请参阅performance docs）剪切单个圆角矩形的角落：

import QtQuick 2.5
import QtQuick.Window 2.2

Window {
    width: 300
    height: 300
    visible: true

    Item {
        width: 100
        height: 100
        anchors.centerIn: parent
        clip: true

        Rectangle {
            anchors.fill: parent
            anchors.rightMargin: -radius
            radius: 10
            color: "navajowhite"
            opacity: 0.5
        }
    }
}

您还可以使用layers来避免重叠透明度问题：

import QtQuick 2.5
import QtQuick.Window 2.2

Window {
    width: 300
    height: 300
    visible: true

    Item {
        width: 100
        height: 100
        opacity: 0.5
        layer.enabled: true
        anchors.centerIn: parent

        Rectangle {
            color: "navajowhite"
            radius: 10
            anchors.fill: parent
        }
        Rectangle {
            color: "navajowhite"
            anchors.fill: parent
            anchors.leftMargin: 10
        }
    }
}

正如@folibis所提到的，您也可以使用Canvas，其中已有类似的answer。