Question

我正在编写一个Prolog谓词，它从编号列表中删除前三个元素并打印结果。编号列表的示例：

[e(f,1),e(o,2),e(o,3),e(b,4),e(a,5),e(r,6)].

普通列表的原始谓词如下所示：

strim([H|T],R) :-   
   append(P,R,[H|T]),  
   length(P,3).

因此，由于长度谓词也适用于编号列表，我只需编写谓词，将一个编号列表附加到另一个：

compose([],L,[L]).
compose([e(F,C)|T],e(A,_),[e(F,C)|L]) :-
   N is C+1,
   compose(T,e(A,N),L).

napp(X,[],X).
napp(L,[e(X,Y)|T],M):-
   compose(L,e(X,Y),L1),
   napp(L1,T,M).

我希望编号列表的谓词是普通列表的谓词的略微修改版本，所以我写了这个：

numstrim([e(X,Y)|T],R) :-
   napp(P,R,[e(X,Y)|T]),
   length(P,3).

但是，我收到了这个错误：

ERROR: compose/3: Arguments are not sufficiently instantiated

有人可以解释导致错误的原因以及如何避免错误吗？我是Prolog的新手。

Answer 1

实例化错误是使用模式谓词的Prolog程序中的常见现象：这些谓词只能用于特殊的情况，例如需要一些参数完全实例化等。

作为初学者，我认为您建议使用更一般的谓词，以便您可以自由地交换目标顺序，而不必考虑程序限制，至少不是那么早，没有能力自由地试验你的代码。

例如，在您的情况下，以下普通更改为compose/3会为您提供一个适用于所有方向的谓词：

compose([], L, [L]).
compose([e(F,C)|T], e(A,_), [e(F,C)|L]) :-
        N #= C+1,
        compose(T, e(A,N), L).

在这里，我只是将模式谓词(is)/2替换为 CLP（FD）约束 (#=)/2，其中completeley包含更低的值 - 整数谓词。

经过这个小改动（取决于你的Prolog系统，你可能需要导入一个库来使用更通用的算术谓词），我们得到：

?- numstrim([e(f,1),e(o,2),e(o,3),e(b,4),e(a,5),e(r,6)], Es).
nontermination

因此，我们发现实例化错误实际上掩盖了一个只能在程序上理解的不同问题，现在已经浮出水面。

为了改善这一点，我现在转过numstrim/2的两个目标：

numstrim([e(X,Y)|T], R) :-
        length(P, 3),
        napp(P, R, [e(X,Y)|T]).

这是因为length(P, 3) 始终终止，并且放置始终首先的目标最多可以改进，从不会恶化，纯粹单调逻辑程序的终止属性。

现在我们得到：

?- numstrim([e(f,1),e(o,2),e(o,3),e(b,4),e(a,5),e(r,6)], Es).
Es = [e(b, _1442), e(a, _2678), e(r, _4286)] .

也就是说，至少我们现在得到一个答案！

但是，谓词仍然不会终止 普遍，因为我们得到：

?- numstrim([e(f,1),e(o,2),e(o,3),e(b,4),e(a,5),e(r,6)], Es), false.
nontermination

我将此作为练习。

简单的Prolog程序：“参数没有充分实例化”错误

1 个答案: