Question

我正在进行XML-to-XML转换（Windows 10，Oxygen XML Editor）并完成了这项任务：将<xref id="id1">text</xref>替换为id1。

我已经完成了一些工作，但无法理解为什么场景不会替换括号中的所有外部参照。有什么想法吗？

如果有人知道如何删除xref-s之外的括号，请告诉我。我正在尝试concat('(',$temp,')')，但它也会跳过parenteses而concat('(',$temp,';')甚至不起作用。

这里的示例（我保留标点符号以防万一）：

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (<xref id="id1">TEXT1, 2014</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id5">TEXT5., 2016</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    ...
</section>
...

结果：

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (id1) dolor.</p>
    <p>Lorem ipsum (id5) dolor.</p>
    <p>Lorem ipsum (id6; TEXT7., 2014; TEXT8., 2012), dolor.</p>
    <p>Lorem ipsum (TEXT6., 2004; id7; TEXT8., 2012), dolor.</p>
    ...
</section>
...

我希望：

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (id1) dolor.</p>
    <p>Lorem ipsum (id5) dolor.</p>
    <p>Lorem ipsum (id6; id7; id8), dolor.</p>
    <p>Lorem ipsum (id6; id7; id8), dolor.</p>
    ...
</section>
...

和这里的情景：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">
<xsl:output method="xml" encoding="UTF-8"/>
<xsl:template name="xrefs">
    <xsl:for-each select="section">
        <xsl:for-each select="p">
            <xsl:variable name="tempP">
                <xsl:value-of select="."/>
            </xsl:variable>
            <xsl:for-each select="xref">
                <xsl:variable name="temp">
                    <xsl:value-of select="."/>
                </xsl:variable>
                <xsl:value-of select="replace($tempP,$temp,./@id)"/>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:for-each>
</xsl:template>

<xsl:template match="/">
    <xsl:call-template name="xrefs"/>
</xsl:template>

Answer 1

完成了这项任务：将<xref id="id1">text</xref>替换为id1。

这可以通过以下方式轻松完成：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="xref">
    <xsl:value-of select="@id"/>
</xsl:template>

</xsl:stylesheet>

适用于以下格式正确（！）输入示例：

<强> XML

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (<xref id="id1">TEXT1, 2014</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id5">TEXT5., 2016</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    ...
</section>

结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<section>
   <somenode>Lorem ipsum</somenode>
   <p>Lorem ipsum (id1) dolor.</p>
   <p>Lorem ipsum (id5) dolor.</p>
   <p>Lorem ipsum (id6; id7; id8), dolor.</p>
   <p>Lorem ipsum (id6; id7; id8), dolor.</p>
    ...
</section>

以防万一有人知道如何删除括号以外的括号 xref-s，请告诉。

这可以通过添加这两个模板来实现（需要XSLT 2.0）：

<xsl:template match="text()[following-sibling::*[self::xref]][ends-with(., '(')]">
    <xsl:value-of select="substring(., 1, string-length() - 1) "/>
</xsl:template>

<xsl:template match="text()[preceding-sibling::*[self::xref]][starts-with(., ')')]">
    <xsl:value-of select="substring(., 2) "/>
</xsl:template>

然后结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<section>
   <somenode>Lorem ipsum</somenode>
   <p>Lorem ipsum id1 dolor.</p>
   <p>Lorem ipsum id5 dolor.</p>
   <p>Lorem ipsum id6; id7; id8, dolor.</p>
   <p>Lorem ipsum id6; id7; id8, dolor.</p>
    ...
</section>

替换文本中的xml节点时遇到问题

1 个答案: