Question

我想从txt文件中读取和存储科学格式的数字，格式化的数字由制表符分隔。

这是我到目前为止所做的：

IMPLICIT NONE

REAL,ALLOCATABLE,DIMENSION(2)    :: data(:,:)       
INTEGER              :: row,column
INTEGER              :: j,i
CHARACTER(len=30)        :: filename
CHARACTER(len=30)        :: format

filename='data.txt'
open(86,file=filename,err=10)
write(*,*)'open data file'   
read(86, *) row
read(86, *) column

allocate(data(row,column))

format='(ES14.7)'   

do i=1,row
  read(86,format) data(i,:)
enddo

close(86)

这就是txt文件的样子：

200
35
2.9900E-35  2.8000E-35  2.6300E-35  2.4600E-35  2.3100E-35  2.1600E-35  ...

问题在于它不会从txt读取并存储正确的值到数据变量。这是导致问题的格式吗？

我还想知道在这种情况下如何计算列数。（我可以在for循环中使用read（86，*）来计算行数。）

Answer 1

是的，您的格式不适合您显示的数据。更好的一个应该是read(99,'(6(E11.4,X))') myData(i,:)。

但是，我不确定你是否真的需要在你的阅读中使用格式。

以下示例非常接近您要执行的操作，并且它正在使用带有和不带格式的机器人。

program readdata
  implicit none
  real, allocatable :: myData(:,:)
  real              :: myLine
  integer           :: i, j, myRow, myColumn
  character(len=30) :: myFileName
  character(len=30) :: myFormat

  myFileName='data.dat'

  open(99, file=myFileName)
  write(*,*)'open data file'
  read(99, *) myRow
  read(99, *) myColumn

  allocate(myData(myRow,myColumn))

  do i=1,myRow
    read(99,*) myData(i,:)
    !read(99,'(6(E11.4,X))') myData(i,:)
    print*, myData(i,:)
  enddo

  close(99)

end program readdata

为了测试，我假设你在文件中总是有行和列，所以我的测试数据正在跟随。

2
6
2.9900E-35  2.8000E-35  2.6300E-35  2.4600E-35  2.3100E-35  2.1600E-35
2.9900E-35  2.8000E-35  2.6300E-35  2.4600E-35  2.3100E-35  2.1600E-35

如果您真的有兴趣阅读格式的文件，如果列数不是常数，您可能需要一个取决于变量的格式，请参阅相关讨论here。

Answer 2

虽然没有直接命令来计算一行中的项目数，但我们可以使用scan命令计算句点数或（E | e | D | d）。例如，

program main
    implicit none
    character(100) str
    integer n  
    read( *, "(a)" ) str

    call countreal( str, n )
    print *, "number of items = ", n
contains

subroutine countreal( str, num )
    implicit none
    character(*), intent(in)  :: str
    integer,      intent(out) :: num
    integer pos, offset

    num = 0
    pos = 0
    do
        offset = scan( str( pos + 1 : ), "." )        !! (1) search for periods
        !! offset = scan( str( pos + 1 : ), "EeDd" )  !! (2) search for (E|e|D|d)

        if ( offset > 0 ) then
            pos = pos + offset
            num = num + 1
            print *, "pos=", pos, "num=", num   !! just for check
        else
            return
        endif
    enddo
endsubroutine
end

请注意，pattern（1）仅在所有项目都有句点时有效，而pattern（2）仅在所有项目都有指数时有效：

# When compiled with (1)

$ echo "2.9900  2.8000E-35  2.6300D-35  2.46  2.31" | ./a.out
 pos=           2 num=           1
 pos=          10 num=           2
 pos=          22 num=           3
 pos=          34 num=           4
 pos=          40 num=           5
 number of items =            5

# When compiled with (2)

$ echo "2.9900E-35  2.8000D-35  2.6300e-35  2.4600d-35" | ./a.out
 pos=           7 num=           1
 pos=          19 num=           2
 pos=          31 num=           3
 pos=          43 num=           4
 number of items =            4

为了更一般的目的，编写自定义＆＃34; split（）＆＃34;可能更方便。将项目与空格分隔的功能（或使用支持拆分功能的外部库）。

从txt读取科学格式的数字

2 个答案: