Question

按the manual，我应该可以使用以下代码获取文本控件的文本：

${NSD_GetText} $TextBox $0
MessageBox MB_OK "You typed:$\n$\n$0"

我总是从这个调用中获取空字符串。在下面的代码中，文本框显示“正确”，但详细信息始终显示为Contents:;如果我对${NSD_GetText}的来电发表评论，我会收到Contents: wrong。

!include nsDialogs.nsh
!include LogicLib.nsh

Var Dialog
Var TextBox

Page custom nsDialogsPage nsDialogsPageLeave
Page instfiles

Function nsDialogsPage
    StrCpy $0 "wrong"

    nsDialogs::Create 1018
    Pop $Dialog

    ${If} $Dialog == error
        Abort
    ${EndIf}

    ${NSD_CreateText} 0 12u 93% 12u "correct"
    Pop $TextBox

    nsDialogs::Show
FunctionEnd

Function nsDialogsPageLeave
FunctionEnd

Section
    ${NSD_GetText} $TextBox $0

    DetailPrint "Contents: $0"
SectionEnd

所以我想当我试图打印其内容时，控件可能不存在，并尝试更新文本，因为它被输入到控件中;这没有帮助。以这种方式破坏NSIS是不可信的，所以我做错了什么？

!include nsDialogs.nsh
!include LogicLib.nsh

Var Dialog
Var TextBox
Var Text

Page custom nsDialogsPage nsDialogsPageLeave
Page instfiles

Function nsDialogsPage
    StrCpy $0 "wrong"

    nsDialogs::Create 1018
    Pop $Dialog

    ${If} $Dialog == error
        Abort
    ${EndIf}

    ${NSD_CreateText} 0 12u 93% 12u "correct"
    Pop $TextBox
    ${NSD_OnChange} $TextBox UpdateText

    nsDialogs::Show
FunctionEnd

Function nsDialogsPageLeave
FunctionEnd

Function UpdateText
    ${NSD_GetText} $TextBox $Text
FunctionEnd

Section
    DetailPrint "Contents: $Text"
SectionEnd

Answer 1

您是对的，该部分中不存在该控件，因此您必须在自定义页面上获取内容。

如果用户更改文本，您的第二个示例应该可以正常工作，但如果他们没有，则不会，因为更改事件不会触发。

您通常只是阅读页面中的内容，留下回调：

Var Dialog
Var TextBox
Var Text

!include LogicLib.nsh
!include nsDialogs.nsh
Page custom nsDialogsPage nsDialogsPageLeave
Page instfiles

Function nsDialogsPage
    nsDialogs::Create 1018
    Pop $Dialog
    ${If} $Dialog == error
        Abort
    ${EndIf}

    ${NSD_CreateText} 0 12u 93% 12u "correct"
    Pop $TextBox

    nsDialogs::Show
FunctionEnd

Function nsDialogsPageLeave
${NSD_GetText} $TextBox $Text
FunctionEnd


Section
    DetailPrint "Contents: $Text"
SectionEnd

$ {NSD_GetText}始终返回空字符串

1 个答案: