Question

我有一个列表，其长度可被2整除，我正在寻找与this问题的答案类似的内容：

(loop for (a b) on lst while b
      collect (+ a b))

然而，元素之间存在重叠：

(1 2 3 4 5) -> (3 5 7 9)

添加1和2，然后添加2和3等。

我在哪里有(1 2 3 4)这样的列表，我正在寻找类似

的内容

((1 2) (3 4))

作为输出。有没有办法在列表上正确地循环步骤？另一个解决方案。

Answer 1

这样的事情应该有效：

(let ((list '(1 2 3 4)))
  (loop :for (a b) :on list :by #'cddr :while b 
        :collect (cons a b)))

也是一个更详细的变体：

(let ((list '(1 2 3 4)))
  (loop :for a :in list :by #'cddr
        :for b :in (cdr list) :by #'cddr
        :collect (cons a b)))

Answer 2

使用SERIES包的另一种方法。另见Richard C. Waters的user manual。

设置

(ql:quickload :series)
(defpackage :stackoverflow (:use :series :cl))
(in-package :stackoverflow)

代码

(defun pairs (list)
  (collect 'list
    (mapping (((odd even) (chunk 2 2 (scan 'list list))))
      (list odd even))))

scan list的内容为“系列”
chunk，M = 2且N = 2：

此功能具有分解输入系列项目的效果进入（可能重叠）长度为m的块。起始位置连续块的数量相差n。输入m和n必须都是正整数。

更准确地说，(chunk 2 2 (scan '(1 2 3 4)))会产生#Z(1 3)和#Z(2 4)
mapping在这些系列的每个odd和even元素上并行生成一系列情侣，由(list odd even)完成。
最后，collect结果，作为列表。

汇编

由于流融合机制，所有中间“系列”都被编译掉了。这是指向collect时的宏扩展：

(LET* ((#:OUT-1120 LIST))
  (LET (#:ELEMENTS-1117
        (#:LISTPTR-1118 #:OUT-1120)
        (#:COUNT-1113 0)
        #:CHUNK-1114
        #:CHUNK-1115
        #:ITEMS-1123
        (#:LASTCONS-1106 (LIST NIL))
        #:LST-1107)
    (DECLARE (TYPE LIST #:LISTPTR-1118)
             (TYPE FIXNUM #:COUNT-1113)
             (TYPE CONS #:LASTCONS-1106)
             (TYPE LIST #:LST-1107))
    (SETQ #:COUNT-1113 1)
    (SETQ #:LST-1107 #:LASTCONS-1106)
    (TAGBODY
     #:LL-1124
      (IF (ENDP #:LISTPTR-1118)
          (GO SERIES::END))
      (SETQ #:ELEMENTS-1117 (CAR #:LISTPTR-1118))
      (SETQ #:LISTPTR-1118 (CDR #:LISTPTR-1118))
      (SETQ #:CHUNK-1114 #:CHUNK-1115)
      (SETQ #:CHUNK-1115 #:ELEMENTS-1117)
      (COND ((PLUSP #:COUNT-1113) (DECF #:COUNT-1113) (GO #:LL-1124))
            (T (SETQ #:COUNT-1113 1)))
      (SETQ #:ITEMS-1123
              ((LAMBDA (ODD EVEN) (LIST ODD EVEN)) #:CHUNK-1114 #:CHUNK-1115))
      (SETQ #:LASTCONS-1106
              (SETF (CDR #:LASTCONS-1106) (CONS #:ITEMS-1123 NIL)))
      (GO #:LL-1124)
     SERIES::END)
    (CDR #:LST-1107)))

Answer 3

CL-USER 156 > (loop with list = '(1 2 3 4)
                    while list
                    collect (loop repeat 2
                                  while list
                                  collect (pop list)))
((1 2) (3 4))

或

CL-USER 166 > (loop with list = '(1 2 3 4 5 6)
                    while (and list (cdr list))
                    collect (loop repeat 2 collect (pop list)))
((1 2) (3 4) (5 6))

CL-USER 167 > (loop with list = '(1 2 3 4 5 6 7)
                    while (and list (cdr list))
                    collect (loop repeat 2 collect (pop list)))
((1 2) (3 4) (5 6))

常见的lisp：遍历列表对

3 个答案:

设置

代码

汇编