光在POVRay中穿过玻璃？

Question

在此图像中，我将光源直接放在玻璃管的上方和左侧，指数为1.3。但是我没有看到任何预期的伪影（证据）表明光线穿过管子并从棋盘表面反射出来。

我已经看到很多POVRay图像，其中光被玻璃操纵。但我不知道哪个参数或参数组合会影响这一点。这是呈现上述图像的POV文件：

//EXAMPLE OF TRANSPARENT OBJECTS

//Files with predefined colors and textures
#include "colors.inc"
#include "glass.inc"
#include "golds.inc"
#include "metals.inc"
#include "stones.inc"
#include "woods.inc"

//Place the camera
camera {
  sky <0,0,1>          //Don't change this
  direction <-1,0,0>   //Don't change this  
  right <-4/3,0,0>     //Don't change this
  location  <100,0,50>  //Camera location
  look_at   <0,0,.5>    //Where camera is pointing
  angle 3       //Angle of the view--increase to see more, decrease to see less
}

//Ambient light to "brighten up" darker pictures
global_settings { ambient_light White*0.2

  assumed_gamma 1.0
  max_trace_level 10
  photons {
    spacing 0.05
    autostop 0
    jitter 0
  }
  adc_bailout 0
}

//Place a light--you can have more than one!
light_source { 
  <0,-2,2.2>   //Change this if you want to put the light at a different point
  color White*2        //Multiplying by 2 doubles the brightness
    spotlight
    radius 5
    falloff 20
    tightness 10 
    point_at <0, -2, 0>
}

//Place a light--you can have more than one!
light_source {
  <0,-.2,.1>
  color White * 2        //Multiplying by 2 doubles the brightness
    spotlight
    radius 5
    point_at <0, 0, 0>
}

//Set a background color
background { color White }

//Create a "floor"
plane {
  <0,0,1>, 0           //This represents the plane 0x+0y+z=0
  pigment {
    checker color White, color Gray
  }

photons{
  target
  reflection on
  refraction on
  }
}

 cylinder
 { <0,-2,.2>, <0,-2,2>,  .2
  texture{T_Glass1}
  interior { ior 1.3}
  photons
  {
   reflection on
   refraction on
  }
 }

cylinder
{ <-0,0,0.2>, <0,2,0.2>,  .2
 texture{T_Glass1}
 interior { ior 1.3}
 photons
 {
  reflection on
  refraction on
 }
}

任何提示或指示赞赏。

Answer 1

为了让光线穿过上述POVRay脚本中的圆柱体等物体，我需要添加“目标”。

即改变了这个：

 cylinder
 { <0,-2,.2>, <0,-2,2>,  .2
  pigment{Col_Glass_Clear}
  interior { ior 1.3}
  photons
  {
   reflection on
   refraction on
  }
 }

对此：

 cylinder
 { <0,-2,.2>, <0,-2,2>,  .2
  pigment{Col_Glass_Clear}
  interior { ior 1.3}
  photons
  {
   target
   reflection on
   refraction on
  }
 }

然后，当运行POVRay时，输出图像将更改为以下内容：