Question

我是创建Excel函数的新手，我需要创建一个占用一系列单元格的函数，并计算非删除单元格值的总和。

Function SUMNOTSTRIKE(rng As Range)
    Dim cell As Range
    For Each cell In rng
        If Not (cell.Font.StrikeThrough) Then
            SUMNOTSTRIKE = SUMNOTSTRIKE + cell.Value
        End If
    Next cell
End Function

此功能正常，但我不明白为什么在敲击或删除穿透时结果不会自动刷新。我必须再次执行该功能。

我读过有关Application.Volatile的内容，但这仅适用于价值变化。我需要在格式改变时触发该功能。

Answer 1

扩展我的评论。如果你添加

Application.Volatile

到你的函数定义（按惯例，作为第一行），然后在工作表的代码模块中有：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Application.Calculate
End Sub

然后，只要更改选择，就会重新计算所有易失性函数。如果您只是更改所选单元格的删除线并保持选中该单元格，则无法重新计算，但是当您移动到另一个单元格时，您的功能可能会更新。

作为警告，始终触发Application.Calculate可能会降低Excel的速度。根据您的具体情况，这可能不是一个合适的解决方案。

Answer 2

这是约翰优秀建议的变体。假设我们的数据在 A1 到 A100 。

我们可以使用双击事件：

敲击单元格的文字
强制重新计算

在工作表代码区域中输入以下事件宏：

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Range("A1:A100")) Is Nothing Then Exit Sub
    Cancel = True
    Target.Font.Strikethrough = True
    Application.CalculateFull
End Sub

双击感兴趣的细胞将同时击中它并强制重新计算。

因为它是工作表代码，所以很容易安装和自动使用：

右键单击Excel窗口底部附近的选项卡名称
选择查看代码 - 这会打开一个VBE窗口
粘贴内容并关闭VBE窗口

如果您有任何疑虑，请先在试用工作表上试用。

如果保存工作簿，宏将随之保存。如果您在2003年之后使用的是Excel版本，则必须保存该文件为.xlsm而不是.xlsx

删除宏：

按上述方式调出VBE窗口
清除代码
关闭VBE窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其正常工作！

创建在格式更改时运行的易失性Excel函数

2 个答案: