Question

我使用the Reflex.Dom library，它定义了一组用于创建HTML DOM元素的函数

el创建了一个元素
el'创建并返回一个元素
elAttr创建具有给定属性的元素
elAttr'创建并返回具有给定属性的元素
等

我正在创建自己的小部件库，我不想为每个小部件定义所有这些变体。所以我编写了一个使用相同名称的类型类，但是根据彼此的方式定义了所有函数，只留下其中一个在每个实例中定义：

{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE OverloadedStrings #-}

module ElMaker where

import Data.Map (Map)
import qualified Data.Map as Map
import qualified Reflex.Dom as D

-- el: type of element to create
-- input: input parameter
-- output: return value
class (D.MonadWidget t m) => ElMaker t m el input output where
  el :: el -> input -> m output
  el e = elAttr e Map.empty

  elAttr :: el -> Map Text Text -> input -> m output
  elAttr e attrs input = snd <$> elAttr' e attrs input

  el' :: el -> input -> m (D.El t, output)
  el' e = elAttr' e Map.empty

  -- This is the only one to implement, yay!
  elAttr' :: el -> Map Text Text -> input -> m (D.El t, output)

我创建了一个使用原始elAttr'来测试它的实例。它奏效了：

import Data.Text (Text)
import qualified Reflex.Dom as D

instance (D.MonadWidget t m) => ElMaker t m Text (m output) output where
  elAttr' = D.elAttr'

然后我创建了一个Button窗口小部件实例，它返回单击按钮时的事件。它奏效了：

data Button = Button
instance (MonadWidget t m) => ElMaker t m Button (m input) (Event t ()) where
  elAttr' _ attrs contents = do
    (e, _) <- D.el' "button" contents
    return $ (e, D.domEvent D.Click e)

我希望能够编写小部件，因此我尝试重写Button实例以使用Text ElMaker实例来创建元素。但它无法编译：

data Button = Button
instance (MonadWidget t m) => ElMaker t m Button (m input) (Event t ()) where
  elAttr' _ attrs contents = do
    (e, _) <- el' ("button" :: Text) contents
    return $ (e, D.domEvent D.Click e)

编译器输出：

MDL.hs:119:15: error:
    • Could not deduce (ElMaker t m Text (m input) output0)
        arising from a use of ‘el'’
      from the context: MonadWidget t m
        bound by the instance declaration at MDL.hs:116:10-71
      The type variable ‘output0’ is ambiguous
      Relevant bindings include
        contents :: m input (bound at MDL.hs:117:19)
        elAttr' :: Button
                   -> Map.Map Text Text -> m input -> m (D.El t, Event t ())
          (bound at MDL.hs:117:3)
      These potential instance exist:
        instance MonadWidget t m => ElMaker t m Text (m output) output
          -- Defined in ‘ElMaker’
    • In a stmt of a 'do' block:
        (e, _) <- el' ("button" :: Text) contents
      In the expression:
        do { (e, _) <- el' ("button" :: Text) contents;
             return $ (e, D.domEvent D.Click e) }
      In an equation for ‘elAttr'’:
          elAttr' _ attrs contents
            = do { (e, _) <- el' ("button" :: Text) contents;
                   return $ (e, D.domEvent D.Click e) }

我认为这是因为函数不会对限制其类型的值执行任何操作，编译器确实希望它具有具体类型。但是这个类型类并不关心该类型参数的值。有没有办法编译这个呢？

Answer 1

你可能想要做什么（这是你经常想要做的事情;它正在成为常见问题解答）是替换=>右侧的构造函数，左侧是等式约束

{-# LANGUAGE GADTs #-}

instance (D.MonadWidget t m, input ~ m output)
   => ElMaker t m Text input output where ...

instance (D.MonadWidget t m, input' ~ m input, output ~ Event t ())
   => ElMaker t m Button input' output where ...

一旦你知道你正在构建Text或Button，你想要提交一个特定的实例，然后提交给具有特定形状的某些类参数。将它们放在实例约束中可以让你这样做。

对于此处的特定情况，一旦您知道自己正在处理Text，就知道要使用哪个实例，并且可以通过{{1}上的匹配来计算output }。您希望GHC知道，而不是想知道其他input实例是否会有不同的输入/输出关系。

注意：通常最好使用关键类参数来确定其他参数 last 。所以我将Text作为el的最后一个参数。这对于newtype派生很有用，也是常规的。

如何定义具有无法推导的类型的Haskell类型类？

1 个答案: