Question

我需要做一个批处理文件这个艰巨的任务，这对C来说并不是最难处理，但在DOS下是一个地狱（至少对我而言！）我需要将一个结构转换为单个var（字符串）能够在我的程序中再次将它们转换为该结构。不要担心卷土重来，已经完成了。

结构的大小会有所不同，并且[0]内的索引必须是我的var中的第一项。

这里是这些结构的例子（仅3）：

level.waypoints[0] = spawnstruct();
level.waypoints[0].origin = (1774.5,834.7,67.6);
level.waypoints[0].type = "stand";
level.waypoints[0].childCount = 2;
level.waypoints[0].children[0] = 1;
level.waypoints[0].children[1] = 6;
level.waypoints[1] = spawnstruct();
level.waypoints[1].origin = (1780.6,639.1,65.5);
level.waypoints[1].type = "stand";
level.waypoints[1].childCount = 2;
level.waypoints[1].children[0] = 7;
level.waypoints[1].children[1] = 0;
level.waypoints[2] = spawnstruct();
level.waypoints[2].origin = (1902.2,-345.2,74.2);
level.waypoints[2].type = "stand";
level.waypoints[2].childCount = 2;
level.waypoints[2].children[0] = 3;
level.waypoints[2].children[1] = 97;
level.waypoints[3] = spawnstruct();
level.waypoints[3].origin = ... (goes on...)

所以第一个结构：

level.waypoints[0] = spawnstruct();
level.waypoints[0].origin = (1774.5,834.7,67.6);
level.waypoints[0].type = "stand";
level.waypoints[0].childCount = 2;
level.waypoints[0].children[0] = 1;
level.waypoints[0].children[1] = 6;

我需要将此结构转换为此行：

set flwp_0 "0,1774.5,834.7,67.6,stand,2,1,6"

其中0（flwp_）是索引，也是“”内的第一项。

所以这个例子中的另外2个将是：

set flwp_1 "1,1780.6,639.1,65.5,3,7,0,30"
set flwp_2 "2,1902.2,-345.2,74.2,2,3,97"

childCount可以是任何值，但我认为不会超过9。那么，我们有多少个孩子，下一行会有更多的孩子。

但是我只需要在childCount值之后的值，所以我用这个值我知道该字符串中有多少项可用，所以没问题。

我正在考虑删除我不需要的所有内容（按顺序）：

level.waypoints[
] = spawnstruct();
].origin = (
);
].type = "
";
].childCount = 
].children[0] = 
].children[1] = 
].children[2] = 
].children[3] = 
].children[4] = 
].children[5] = 
].children[6] = 
].children[7] = 
].children[8] = 
].children[9] = 
;

这将在第一个结构中留下这样的东西：

0
01774.5,834.7,67.6
0stand
02
01
06

现在我需要阅读它并转换成我的单行字符串。但我知道正确的索引有问题，因为它可能是第一个值，但如果索引有2个或3个字符？

我还在考虑用一些信息替换来跟踪我，所以不会替换文件的“]”，所以我会知道之前的是索引，然后是值。

我也尝试了一个没有成功创建索引的循环：

level.waypoints[X]

X从0到1000（我不相信会传递那个数字）

它不起作用，也许我的第一个想法更好......：\

我需要一个批处理文件（或几个）来将几个具有类似内部结构的文件转换为新文件，其值为字符串，如上所述。

有什么想法吗？

谢谢！

@Squashman结果有点混乱，如你所见：

set flwp_0 "0,1774.5,834.7,67.6,stand,2,1,6"
set flwp_100 "100,1636.76,371.924,240.125,stand,2,101,99"
set flwp_101 "101,1861.45,437.846,240.125,stand,2,102,100"
set flwp_102 "102,1843.93,557.03,240.125,stand,2,103,101"
set flwp_103 "103,1504.58,553.357,64.125,stand,2,8,102"
set flwp_104 "104,653.17,1675.32,64.125,stand,2,26,105"
set flwp_105 "105,338.784,1680.49,232.125,stand,2,104,133"
set flwp_106 "106,-919.398,1537.7,80.125,stand,3,107,109,150"
set flwp_107 "107,-928.311,1111.47,80.125,stand,3,108,106,149"
set flwp_108 "108,-696.488,1095.93,80.125,stand,2,36,107"
set flwp_109 "109,-787.781,1566.87,80.125,stand,2,106,110"
set flwp_10 "10,1423.3,-403.8,64.3,stand,4,11,12,15,3"
set flwp_110 "110,-754.274,1716.71,80.125,stand,2,109,34"
set flwp_111 "111,-736.201,1887.87,64.125,stand,4,112,34,151,152"
set flwp_112 "112,-454.293,1879.4,64.125,stand,4,111,33,34,152"
set flwp_113 "113,125.395,-451.579,58.6958,stand,3,51,114,142"
set flwp_114 "114,282.593,-447.87,68.125,stand,2,115,113"
set flwp_115 "115,304.311,-271.206,68.125,stand,2,116,114"
set flwp_116 "116,447.128,-292.167,68.125,stand,3,118,115,117"
set flwp_117 "117,437.415,-443.822,68.125,stand,2,67,116"
set flwp_118 "118,582.932,-297.811,126.125,stand,2,119,116"
set flwp_119 "119,561.586,-485.701,204.125,stand,2,120,118"
set flwp_11 "11,1240.1,-249.7,74.1,stand,5,9,16,10,12,15"
set flwp_120 "120,423.422,-470.754,204.125,stand,2,119,135"
set flwp_121 "121,1164.82,-1203.64,72.125,stand,4,123,14,126,122"
set flwp_122 "122,1064.12,-1299.76,72.125,stand,3,123,125,121"
set flwp_123 "123,1117.59,-1476.49,72.125,stand,3,124,122,121"
set flwp_124 "124,861.878,-1497.7,72.125,stand,2,125,123"
set flwp_125 "125,878.58,-1294.38,72.125,stand,2,124,122"

可以按正确的顺序写入文件吗？

再次感谢你帮助@Squashman

欢呼声

好吧，顺序真的无关紧要，但是我很难把每个文件都用到一个新的文件中...我尝试了这个没有成功：

@echo off
 setlocal enabledelayedexpansion

for %%f in (*.gsc) do ( 

 FOR /F "tokens=1-2 delims==;^(^) " %%G IN (%%f) do set %%~G=%%~H
 FOR /F "tokens=2 delims=[]" %%G IN ('set level.waypoints ^|find /I "spawnstruct"') do (
    SET waypoints=!waypoints! %%G
 )

 FOR %%G IN (%waypoints%) do (
    set line=%%G,!level.waypoints[%%G].origin!,!level.waypoints[%%G].type!,!level.waypoints[%%G].childCount!
    FOR /F "tokens=2 delims==" %%H IN ('set level.waypoints[%%G].children') DO set line=!line!,%%H
    set line=set flwp_%%G "!line!"
    echo !line! >> %%f.cfg
 )

)
 pause

任何线索？

=======================================

好的，现在我们非常接近！需要仅处理level.waypoints[的行，其余的必须被忽略，并且还添加了我已经成功完成的最终close var：

@echo off
setlocal enableDelayedExpansion

set findtext="level.waypoints["
for %%F in (*.gsc) do (
  set "out="
  set "i=x"
  > "%%~nF.cfg" (
    for /f usebackq^ tokens^=2^,4^,5^ delims^=[]^=(^)^;^"^  %%A in ("%%F") do (
      if %%A neq !i! (
        if defined out echo !out!"
        set /a "i=%%A, j=0"
        set "out=set flwp_!i! "!i!"

      ) else (
        set /a j+=1
        if !j! leq 3 (set "out=!out!,%%B") else set "out=!out!,%%C"
      )

    )
    if defined out echo !out!"
    set /a "fim=i+1"
    echo set flwp_!fim! "eof"
  )
)

现在我如何将findstr %findtext%添加到这些循环中？我尝试了很多不同的方法，但语法错了......你能帮帮我吗？：d

非常感谢@Squashman和@dbenham所有的帮助，直到现在。

干杯

Answer 1

使用您的新请求编辑代码。

 @echo off

 FOR %%F IN (*.gsc) DO (
    setlocal enabledelayedexpansion
    FOR /F "usebackq tokens=1-2 delims==;^(^) " %%G IN (`find /I "level.waypoints["^<"%%F"`) do set %%~G=%%~H
    (FOR /F "tokens=2 delims=[]" %%G IN ('find /I "spawnstruct" ^<"%%F"') do (
        set line=%%G,!level.waypoints[%%G].origin!,!level.waypoints[%%G].type!,!level.waypoints[%%G].childCount!
        FOR /F "tokens=2 delims==" %%H IN ('set level.waypoints[%%G].children') DO set line=!line!,%%H
        set line=set flwp_%%G "!line!"
        echo !line!
    ))>"%%~nF.cfg"
    endlocal
 )
 pause

Answer 2

这是一个相对快速的纯批处理解决方案，它为每个文件使用单个FOR / F循环。它明显快于Squashman's solution。

我设置DELIMS和TOKENS来解析所有需要的数据元素，无论我解析哪一行。我不担心childCount的价值。相反，我只是检测航路点索引的变化以发信号通知新记录的开始，并且使用递增的航路点线路编号（j变量）来识别每条线路需要哪些令牌。每行都为out变量添加新文本。

@echo off
setlocal enableDelayedExpansion
for %%F in (*.gsc) do (
  set "out="
  set "i=x"
  > "%%~nF.cfg" (
    for /f usebackq^ tokens^=2^,4^,5^ delims^=[]^=(^)^;^"^  %%A in ("%%F") do (
      if %%A neq !i! (
        if defined out echo !out!"
        set /a "i=%%A, j=0"
        set "out=set flwp_!i! "!i!"
      ) else (
        set /a j+=1
        if !j! leq 3 (set "out=!out!,%%B") else set "out=!out!,%%C"
      )
    )
    if defined out echo !out!"
  )
)

以上功能可以在70秒内处理我机器上的23 MB文件。

但如果你允许自己超出纯批次的范围，我可以做得更好。这是一个高效的JREPL.BAT解决方案，它利用了刚刚发布的新版本6.0功能。

JREPL.BAT is a regular expression text processing utility for Windows。它是纯脚本（混合批处理/ Jscript），可以在任何Windows机器上从XP开始本地运行。不需要第三方exe文件。

可以从命令行通过jrepl /?或jrepl /??获取大量文档以获取分页帮助。

此解决方案应该能够处理大小接近1 GB的文件。通过一次调用JREPL.BAT完全处理每个文件。它应该非常高效，因为需要的回溯很少。对于小文件，由于CSCRIPT引擎的启动时间，它将比纯批处理方法慢。但对于大型文件，它比纯批次快得多。

以下代码仅在11秒内处理相同的23 MB文件： - ）

第一个版本将复杂的正则表达式术语的构造分解为步骤，并在每个捕获的组上方包含注释数字，以便您有机会了解它的工作原理。特别是，请阅读/ T和/ P选项的文档。并且还提高了你的正则表达能力！

@echo off
setlocal

set "filter=(.*?\[\d+])[\s\S]*?(?:\n(?!\1)|(?![\s\S]))"

::   1           2                3                  4
set "find1=l.*?\[(\d+)\][\s\S]*?\((\d.*?)\)[\s\S]*?\q(.*?)\q"
set "repl1=set flwp_$2 \q$2,$3,$4"

::   5                 6
set "find2=;[\s\S]*? = (\d+)"
set "repl2=,$6"

::   7
set "find3=[\s\S]+"
set "repl3=\q\n"

set "find=%find1%|%find2%|%find3%"
set "repl=%repl1%|%repl2%|%repl3%"

for %%F in (*.gsc) do (
  call jrepl.bat "%find%" "%repl%" /t "|" /p "%filter%" /x /m /f "%%F" /o "%%~nF.cfg"
)

这是完全相同的解决方案，但没有显示任何中间步骤。我确实包括了行继续以提高可读性。

@echo off
for %%F in (*.gsc) do (
  call jrepl.bat "l.*?\[(\d+)\][\s\S]*?\((\d.*?)\)[\s\S]*?\q(.*?)\q|;[\s\S]*? = (\d+)|[\s\S]+"^
                 "set flwp_$2 \q$2,$3,$4|,$6|\q\n"^
                 /p "(.*?\[\d+])[\s\S]*?(?:\n(?!\1)|(?![\s\S]))"^
                 /t "|" /x /m /f "%%F" /o "%%~nF.cfg"
)

我认为最快的脚本解决方案是自定义构建的JScript或VBS脚本。但我喜欢与JREPL合作： - ）

更新：这是一个小小的奖励 - 一个将* .cfg转换回* .gsc的JREPL脚本

@echo off
setlocal

set "beg=var pre,i,q='\x22',n='\r\n'"

::        1     2     3             4     5     67
set "find=^.*?\q(\d+),(.*?,.*?,.*?),(.*?),(.*?),|(.*?)[,\q]"

set "repl=i=0;pre='level.waypoints['+$2+']';$txt=pre+' = spawnstruct();'"
set "repl=%repl%+n+pre+'.origin = ('+$3+');'"
set "repl=%repl%+n+pre+'.type = '+q+$4+q+';'"
set "repl=%repl%+n+pre+'.childCount = '+$5+';'"
set "repl=%repl%|$txt=n+pre+'.children['+(i++)+'] = '+$7+';'"

for %%F in (*.cfg) do (
  call jrepl.bat "%find%" "%repl%" /x /t "|" /jq /jbeg "%beg%" /f "%%F" /o "%%~nF.gsc"
)

Windows批处理文件：将结构转换为单行字符串

2 个答案: