Question

标准snmp DateTime格式如下。

http://net-snmp.sourceforge.net/docs/mibs/host.html#DateAndTime

"2016-10-3,2:15:27.0,-4:0"

现在我尝试使用tcl＆＃39; s epoch

将此值转换为clock scan

here中用于扫描的格式选项不支持我认为的小数秒和时区。

% clock scan $value2 -format {%Y-%m-%d %H:%M:%S}
input string does not match supplied format

我设法将值分为日期，时间和时区。

% set value "2016-10-3,2:15:27.0,-4:0"
2016-10-3,2:15:27.0,-4:0
% set value [split $value ,]
2016-10-3 2:15:27.0 -4:0
% lassign $value date time timeZone
%

如何在此之后继续？

Answer 1

你可以这样做（检查每一步的扫描结果：这些当然都不是最终结果）：

clock scan $date -format %Y-%N-%e

lassign [split $time .] t d
clock scan $t -format %k:%M:%S

你必须决定如何处理deci-second部分（在d中）。

lassign [split $timeZone :] h m ; # or:
scan $timeZone %d:%d h m
clock scan [format {%+03d%02d} $h $m] -format %z

确切使用的clock字段说明符取决于基本格式：根据需要进行调整。 AFAICT这些说明符与格式匹配。

获取最终时间值：

clock scan "$date $t [format {%+03d%02d} $h $m]" -format "%Y-%N-%e %k:%M:%S %z"

文档： clock， format， lassign， scan， split

Answer 2

问题的第一部分是小数秒。此外，时区不是我们可以支持的形式（我们只能做很多事情;我们专注于使解析器能够处理ISO时间戳格式的公共部分）。

然而，这确实意味着我们可以相当容易地清理事物。我们需要执行几个步骤，我们将使用regexp，scan和format来提供帮助：

# Your example, in a variable for my convenience
set instant "2016-10-3,2:15:27.0,-4:0"

# Take apart the problem piece; REs are *great* for string parsing!
regexp {^(.+)\.(\d+),(.+)$} $instant -> timepart fraction timezone

# Fix the timezone format; we use [scan] for semantic parsing...
set timezone [format "%+03d%02d" {*}[scan $timezone "%d:%d"]]

# Parse the time properly now that we can understand all the pieces
set timestamp [clock scan "$timepart $timezone" -format "%Y-%m-%d,%k:%M:%S %z"]

让我们检查一下是否会产生正确的输出（这是在交互式会话中）：

% clock format $timestamp
Mon Oct 03 07:15:27 BST 2016

对我来说很好看。我想你可以在最后添加原始瞬间的小数部分，但是clock format不会喜欢它。

tcl时钟扫描snmp日期时间格式

2 个答案: