Question

我至少不是程序员。我先阅读了几篇文章，然后询问是否有任何内容适用于我看似简单的问题。不幸的是，我找不到任何解释我要找的东西。

我的问题是：我希望能够每个月都给我妈妈送一个USB记忆棒。她至少不懂电脑。我希望这个过程既简单又可以复制给我家里的其他成员。在我妈妈的电脑上，我创建了一个目录C：\ Family Pictures。这就是她可以轻松打开所有照片看到它们的地方。每个月我都想给她发更多照片（很多照片）。我想将它们全部放在USB上，当它插入时，它们会自动从usb转移到上面提到的驱动器C上的指定文件夹。

我们都使用Windows 10，这是我的理解，我的6兄弟＆amp;姐妹们也是如此。这样我的家人每个月都可以发送她的USB。

这甚至可能吗？我很想学习如何通过让妈妈变得简单来创造它:) 提前致谢，我

Answer 1

自Windows 7以来，自动运行不再可用，因此您可以将批处理文件放在桌面上并告诉她插入USB驱动器，然后依次运行桌面脚本。

代码将是这样的：

@echo off
setlocal
:=============================================================
:OPTIONS - you can change these values

set _SourcePath=C:\Family Pictures
set _DestPath=X:\Family Pictures\Mama

:=============================================================
set _LogPath=%_DestPath%\_log.txt

echo/
echo/This will copy the family files:
echo/ FROM: %_SourcePath% 
echo/ TO: %_DestPath%
echo/

:prompt1
  set /p msgbox=Continue? [Y/N]
  if /i "%msgbox%"=="n" (echo/"Aborted..." &goto:end)
  if /i "%msgbox%"=="y" goto:step1
goto:prompt1

:step1
  if exist "%_DestPath%\" goto:step2
  echo/
  echo Folder %_DestPath% does not exist.
  echo/
  :prompt2
    set /p msgbox=Create folder? [Y/N]
    if /i "%msgbox%"=="n" (echo/"Aborted..." &goto:end)
    if /i "%msgbox%"=="y" goto:CreateFolder
  goto:prompt2

:CreateFolder
  md "%_DestPath%"
  echo %errorlevel%
  if not %ERRORLEVEL%==0 (echo/Aborting: error while creating destination folder &goto:end)

:step2
  echo/
  echo/ Copying files...
  echo/
  xcopy "%_SourcePath%" "%_DestPath%" /Z /Y /E > "%_LogPath%"
  if %ERRORLEVEL%==0 goto:DeleteLog
  :prompt3
    set /p msgbox=There were errors copying the files. View log file? [Y/N]
    if /i "%msgbox%"=="n" goto:DeleteLog
    if /i "%msgbox%"=="y" (notepad "%_LogPath%" &goto:end)
  goto:prompt3

:DeleteLog
  del "%_LogPath%"

:end
endlocal

注意：

将路径下的路径更改为所需路径

批量传输的自动运行脚本

1 个答案: