Question

有时我的系统调用会进入永无止境的状态。为了避免我希望能够在指定的时间后退出呼叫。

有没有办法指定system的超时限制？

system("command", "arg1", "arg2", "arg3");

我希望在Perl代码中实现超时以实现可移植性，而不是使用某些特定于操作系统的函数，如ulimit。

Answer 1

请参阅alarm功能。 pod中的示例：

eval {
    local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
    alarm $timeout;
    $nread = sysread SOCKET, $buffer, $size;
    alarm 0;
};
if ($@) {
    die unless $@ eq "alarm\n";   # propagate unexpected errors
    # timed out
}
else {
    # didn't
}

CPAN上有一些模块可以更好地包装它们，例如：Time::Out

use Time::Out qw(timeout) ;

timeout $nb_secs => sub {
  # your code goes were and will be interrupted if it runs
  # for more than $nb_secs seconds.
};

if ($@){
  # operation timed-out
}

Answer 2

您可以使用IPC::Run的run方法代替系统。并设置超时。

Answer 3

System::Timeout怎么样？

此模块扩展system以允许在指定秒数后超时。

timeout("3", "sleep 9"); # timeout exit after 3 seconds

Answer 4

我以前在Perl + Linux中使用过timeout命令，您可以像这样进行测试：

for(0..4){
  my $command="sleep $_";  #your command
  print "$command, ";
  system("timeout 1.1s $command");  # kill after 1.1 seconds
  if   ($? == -1  ){ printf "failed to execute: $!" }
  elsif($?&127    ){ printf "died, signal %d, %scoredump", $?&127, $?&128?'':'no '}
  elsif($?>>8==124){ printf "timed out" }
  else             { printf "child finished, exit value %d", $? >> 8 }
  print "\n";
}

4.317秒后的输出：

sleep 0, child finished, exit value 0
sleep 1, child finished, exit value 0
sleep 2, timed out
sleep 3, timed out
sleep 4, timed out

timeout命令是a.f.a.i.k所有主要的“正常” Linux发行版的一部分，它是coreutils的一部分。

如何为Perl系统调用指定超时限制？

4 个答案: