Question

有很多解决方案可以改变整个单词的大小写，但我想要的是以这样的方式改变案例：

从“生命的意义是什么？一个新的提议”我想要：“生命的意义是什么？一个新的提案”如果这太难了：“生命的意义是什么？一个新的提案”将够了。

Answer 1

这通常称为标题案例;有the Vim Tips Wiki

的可视模式映射解决方案

function! TwiddleCase(str)
    if a:str ==# toupper(a:str)
        let result = tolower(a:str)
    elseif a:str ==# tolower(a:str)
        let result = substitute(a:str,'\(\<\w\+\>\)', '\u\1', 'g')
    else
        let result = toupper(a:str)
    endif
    return result
endfunction
vnoremap ~ y:call setreg('', TwiddleCase(@"), getregtype(''))<CR>gv""Pgvl

替代

如果您想自己实施更强大的解决方案，我的TextTransform plugin可以帮助您设置x{motion}，xx和{Visual}x映射，因此您只需要编写实际的转换功能。

编辑：好吧，无法阻止自己，这是一个能够处理异常的实现：

if ! exists('g:TitleCase_ExceptionPattern')
    " Source:
    "   http://grammar.yourdictionary.com/capitalization/rules-for-capitalization-in-titles.html
    let g:TitleCase_ExceptionPattern = '^\%(amid\|a[nst]\?\|and\|are\|but\|by\|down\|for\|from\|i[ns]\|into\|like\|near\|new\|nor\|old\|o[fnr]\|off\|onto\|over\|past\|per\|plus\|than\|the\|to\|up\|upon\|via\|with\)$'
endif
function! TitleCase( text )
    return substitute(a:text, '\(^\<\w\+\>\)\|\<\w\+\>', '\=s:TitleCase(submatch(0), ! empty(submatch(1)))', 'g')
endfunction
function! s:TitleCase( word, isException )
    if ! a:isException && a:word =~# g:TitleCase_ExceptionPattern
        return tolower(a:word)
    endif

    return substitute(a:word, '\w', '\u&', '')
endfunction
call TextTransform#MakeMappings('', '<Leader>s~', 'TitleCase')

这是一个循环标题案例的变体，例外→标题案例全部（无例外）→小写：

function! subs#TitleCase#Do( text )
    let l:wordExpr =  '\(^\<\w\+\>\|\<\w\+\>$\)\|\<\w\+\>'
    let l:text = substitute(a:text, l:wordExpr, '\=s:TitleCase(submatch(0), ! empty(submatch(1)))', 'g')
    if l:text ==# a:text
        let l:text = substitute(a:text, l:wordExpr, '\=s:TitleCase(submatch(0), 1)', 'g')
        if l:text ==# a:text
            let l:text = substitute(a:text, l:wordExpr, '\L&', 'g')
        endif
    endif
    return l:text
endfunction

在Vim中更改标题案例（所有单词的首字母大写）

1 个答案:

替代