Java：运行Processing 3.2.1的Raspberry Pi上的不满意的链接错误

Question

每当我从OpenKinect Kinect v1示例PointCloud运行示例代码时，我都会收到此错误。

 Unsatisfied link error: Unable to load library 'freenect': Native library (linux-arm/libfreenect.so) not found in resource path. 
A library relies on native code that's not available.

OpenKinect库专为ARM Linux架构而设，可以找到here。基本问题是，即使库有它，我也不认为它正确找到了libfreenect.so库。我猜它不在路上。

请参阅下面的正在运行的示例代码（导入库freenect。*是我认为导致问题的原因）：

// Daniel Shiffman
// Kinect Point Cloud example

// https://github.com/shiffman/OpenKinect-for-Processing
// http://shiffman.net/p5/kinect/

import org.openkinect.freenect.*;
import org.openkinect.processing.*;

// Kinect Library object
Kinect kinect;

// Angle for rotation
float a = 0;

// We'll use a lookup table so that we don't have to repeat the math over and over
float[] depthLookUp = new float[2048];

void setup() {
  // Rendering in P3D
  size(800, 600, P3D);
  kinect = new Kinect(this);
  kinect.initDepth();

  // Lookup table for all possible depth values (0 - 2047)
  for (int i = 0; i < depthLookUp.length; i++) {
    depthLookUp[i] = rawDepthToMeters(i);
  }
}

void draw() {

  background(0);

  // Get the raw depth as array of integers
  int[] depth = kinect.getRawDepth();

  // We're just going to calculate and draw every 4th pixel (equivalent of 160x120)
  int skip = 4;

  // Translate and rotate
  translate(width/2, height/2, -50);
  rotateY(a);

  for (int x = 0; x < kinect.width; x += skip) {
    for (int y = 0; y < kinect.height; y += skip) {
      int offset = x + y*kinect.width;

      // Convert kinect data to world xyz coordinate
      int rawDepth = depth[offset];
      PVector v = depthToWorld(x, y, rawDepth);

      stroke(255);
      pushMatrix();
      // Scale up by 200
      float factor = 200;
      translate(v.x*factor, v.y*factor, factor-v.z*factor);
      // Draw a point
      point(0, 0);
      popMatrix();
    }
  }

  // Rotate
  a += 0.015f;
}

// These functions come from: http://graphics.stanford.edu/~mdfisher/Kinect.html
float rawDepthToMeters(int depthValue) {
  if (depthValue < 2047) {
    return (float)(1.0 / ((double)(depthValue) * -0.0030711016 + 3.3309495161));
  }
  return 0.0f;
}

PVector depthToWorld(int x, int y, int depthValue) {

  final double fx_d = 1.0 / 5.9421434211923247e+02;
  final double fy_d = 1.0 / 5.9104053696870778e+02;
  final double cx_d = 3.3930780975300314e+02;
  final double cy_d = 2.4273913761751615e+02;

  PVector result = new PVector();
  double depth =  depthLookUp[depthValue];//rawDepthToMeters(depthValue);
  result.x = (float)((x - cx_d) * depth * fx_d);
  result.y = (float)((y - cy_d) * depth * fy_d);
  result.z = (float)(depth);
  return result;
}

修改 这是我得到的图片：

Answer 1

所以这是一个比我想象的更简单的修复（不是总是吗？）所以我必须去我的/home/pi/sketchbook/libraries/并删除任何现有的openKinect库。然后下载专门为Raspberry Pi armv6hf板制作的openKinect库zip文件，并将其解压缩到/home/pi/sketchbook/libraries/。然后重新启动Processing并打开示例，然后找到该库。感谢George Profenza的意见。

Answer 2

我不知道Processing。但是以下应该有助于解决问题。

要获取当前的java.library.path设置，您可以使用

进行打印

System.out.println(System.getProperty("java.library.path"));

在命令行上指定

java -Djava.library.path=/your/additional/directory

该库必须位于目录

中

/your/additional/directory/linux-arm/libfreenect.so

如何在Processing中指定此属性我无法回答。但是你现在应该可以搜索它了。

编辑：如果输出为/usr/java/packages/lib/arm:/lib:/usr/lib，那么您可以将库存储为

/usr/lib/linux-arm/libfreenect.so